MASM32中令人困惑的括号

Question

MASM32中令人困惑的括号

12

我正在努力学习MASM32，并对以下内容感到困惑：

我以为括号是用于间接引用的，所以如果我有一个预定义变量

 .data
   item dd 42

然后

 mov ebx, item

将'item'的内容，即数字42，存放到ebx寄存器中

 mov ebx, [item]

将“item”的地址，也就是存储42的位置，放入ebx中。

但下面的代码在控制台应用程序中：

 mov ebx, item
 invoke dwtoa, ebx, ADDR valuestr 
 invoke StdOut, ADDR valuestr
 mov ebx, [item]
 invoke dwtoa, ebx, ADDR valuestr 
 invoke StdOut, ADDR valuestr

打印两次42。为了获取“item”的地址，我似乎需要

 mov ebx, [OFFSET item]
 invoke dwtoa, ebx, ADDR valuestr 
 invoke StdOut, ADDR valuestr

有人能解释一下MASM中方括号的作用，或者给我推荐一个好的参考资料吗。

- Penguino

这个问题的副本也指出了var2 dword var1会组合成var1的地址。这是唯一明智的行为，因为var1可能是extern，使得它在编译时不可用。幸运的是，在这种情况下允许使用offset var1，所以您总是可以使用明确的标记。 - Peter Cordes

1个回答

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- Ross Ridge · Accepted Answer

MASM在汇编语言中非常不同，因为它具有类型。由于您定义了符号item的方式，MASM知道它是类型为DWORD的内存位置。当您将其用作操作数时，它知道您(可能)意味着您希望获取存储在地址处的值，而不是地址的值。因此，使用item或[item]都可以，MASM假定您指的是后一个。如果您真的想要项目的地址，那么您需要使用OFFSET item。

另一方面，如果您使用item = 42定义item为常量，则mov ebx，item将加载立即值。由于存在歧义，您需要知道item是如何定义的，以确定它是立即操作数还是内存操作数。最好避免使用裸符号作为操作数。

我应该补充说明的是，当您只是使用符号或数字时，方括号[]对于MASM几乎没有任何意义。它们只在您与寄存器一起使用它们时才有意义。以下是一些例子:

item    DD  42
const   =   43

    mov eax, item             ; memory operand (the value stored at item)
    mov eax, [item]           ; memory operand
    mov eax, OFFSET item      ; immediate operand (the address of item)
    mov eax, [OFFSET item]    ; immediate operand

    mov eax, const            ; immediate operand (43)
    mov eax, [const]          ; immediate operand
    mov eax, ds:[const]       ; memory operand (the value at address 43)
    mov eax, fs:30h           ; memory operand (the value at address 30h + fs base)
    mov eax, OFFSET const     ; immediate operand
    mov eax, [OFFSET const]   ; immediate operand

    mov eax, 42               ; immediate operand
    mov eax, ebx              ; register operand (the value of EBX)
    mov eax, [ebx]            ; indirect operand (the value pointed to by EBX)

如果没有寄存器，方括号只能表达您的意图。如果您打算将符号用作内存操作数，则应在符号周围放置方括号，并在打算将符号用作立即值时使用OFFSET。