在结构体上使用"new"关键字会将其分配到堆还是栈上？

Question

当你使用new操作符创建一个类的实例时，内存会在堆上分配。如果你使用new操作符创建一个结构体的实例，内存会分配在哪里？是在堆上还是在栈上？

当你使用new操作符创建一个结构体的实例时，内存会被分配在堆上。

- kedar kamthe

Answer 1

好的，让我们看看能否更清晰地解释一下。

首先，Ash是对的：问题不在于值类型“变量”分配在哪里。那是一个不同的问题，答案不仅仅是“在栈上”。它比那更复杂（而且由C# 2更加复杂）。我有一篇关于这个主题的文章，如果需要，我会进一步扩展它，但现在只处理new运算符。

其次，所有这些都取决于你所讨论的级别。我正在研究编译器如何处理源代码，以及它创建的中间语言（IL）。很有可能JIT编译器会通过优化掉相当多的“逻辑”分配来做出聪明的事情。

第三，我忽略了泛型，主要是因为我实际上不知道答案，并且部分原因是它会使事情变得太复杂。

最后，所有这些都只是当前实现。C#规范没有指定大部分内容-它实际上是实现细节。有人认为托管代码开发人员真的不应该关心这些。我不确定我会走得那么远，但值得想象一个世界，在这个世界里，实际上所有本地变量都存储在堆上-这仍然符合规范。

---

使用值类型的new运算符有两种不同情况：您可以调用无参数构造函数（例如new Guid()）或带参数的构造函数（例如new Guid(someString)）。它们生成显着不同的IL。要理解原因，您需要比较C#和CLI规范：根据C#，所有值类型都有无参数构造函数。根据CLI规范，没有值类型有无参数构造函数（尝试使用反射获取值类型的构造函数-您找不到无参数构造函数）。

对于C#来说，将“使用零初始化值”视为构造函数是有意义的，因为它保持了语言的一致性-您可以将new(...)视为始终调用构造函数。对于CLI来说，将其视为不同的东西也是有意义的，因为没有真正的代码可供调用-当然也没有类型特定的代码。

你打算在初始化之后做什么也很重要。用于它的IL取决于您是否将其传递给方法，或者是否将其存储在本地变量中以备稍后使用。因为值类型通常很小，所以不必担心大对象堆（LOH）的问题。

Guid localVariable = new Guid(someString);

与用于以下的IL不同:

myInstanceOrStaticVariable = new Guid(someString);

此外，如果该值用作中间值，例如方法调用的参数，则情况又略有不同。为了展示所有这些差异，这里有一个简短的测试程序。它没有显示静态变量和实例变量之间的区别：IL 将在 stfld 和 stsfld 之间不同，但仅此而已。

using System;

public class Test
{
    static Guid field;

    static void Main() {}
    static void MethodTakingGuid(Guid guid) {}


    static void ParameterisedCtorAssignToField()
    {
        field = new Guid("");
    }

    static void ParameterisedCtorAssignToLocal()
    {
        Guid local = new Guid("");
        // Force the value to be used
        local.ToString();
    }

    static void ParameterisedCtorCallMethod()
    {
        MethodTakingGuid(new Guid(""));
    }

    static void ParameterlessCtorAssignToField()
    {
        field = new Guid();
    }

    static void ParameterlessCtorAssignToLocal()
    {
        Guid local = new Guid();
        // Force the value to be used
        local.ToString();
    }

    static void ParameterlessCtorCallMethod()
    {
        MethodTakingGuid(new Guid());
    }
}

这是该类的IL代码，不包括不相关的部分（如nops）：

.class public auto ansi beforefieldinit Test extends [mscorlib]System.Object    
{
    // Removed Test's constructor, Main, and MethodTakingGuid.

    .method private hidebysig static void ParameterisedCtorAssignToField() cil managed
    {
        .maxstack 8
        L_0001: ldstr ""
        L_0006: newobj instance void [mscorlib]System.Guid::.ctor(string)
        L_000b: stsfld valuetype [mscorlib]System.Guid Test::field
        L_0010: ret     
    }

    .method private hidebysig static void ParameterisedCtorAssignToLocal() cil managed
    {
        .maxstack 2
        .locals init ([0] valuetype [mscorlib]System.Guid guid)    
        L_0001: ldloca.s guid    
        L_0003: ldstr ""    
        L_0008: call instance void [mscorlib]System.Guid::.ctor(string)    
        // Removed ToString() call
        L_001c: ret
    }

    .method private hidebysig static void ParameterisedCtorCallMethod() cil  managed    
    {   
        .maxstack 8
        L_0001: ldstr ""
        L_0006: newobj instance void [mscorlib]System.Guid::.ctor(string)
        L_000b: call void Test::MethodTakingGuid(valuetype [mscorlib]System.Guid)
        L_0011: ret     
    }

    .method private hidebysig static void ParameterlessCtorAssignToField() cil managed
    {
        .maxstack 8
        L_0001: ldsflda valuetype [mscorlib]System.Guid Test::field
        L_0006: initobj [mscorlib]System.Guid
        L_000c: ret 
    }

    .method private hidebysig static void ParameterlessCtorAssignToLocal() cil managed
    {
        .maxstack 1
        .locals init ([0] valuetype [mscorlib]System.Guid guid)
        L_0001: ldloca.s guid
        L_0003: initobj [mscorlib]System.Guid
        // Removed ToString() call
        L_0017: ret 
    }

    .method private hidebysig static void ParameterlessCtorCallMethod() cil managed
    {
        .maxstack 1
        .locals init ([0] valuetype [mscorlib]System.Guid guid)    
        L_0001: ldloca.s guid
        L_0003: initobj [mscorlib]System.Guid
        L_0009: ldloc.0 
        L_000a: call void Test::MethodTakingGuid(valuetype [mscorlib]System.Guid)
        L_0010: ret 
    }

    .field private static valuetype [mscorlib]System.Guid field
}

正如您所看到的，有许多不同的指令用于调用构造函数：

• newobj：在堆栈上分配值，并调用参数化构造函数。用于中间值，例如赋值给字段或用作方法参数。
• call instance：使用已分配的存储位置（无论是否在堆栈上）。在上面的代码中用于分配给局部变量。如果使用几个new调用多次分配相同的局部变量，则它只是在旧值的顶部初始化数据-每次都不会分配更多的堆栈空间。
• initobj：使用已分配的存储位置，只是擦除数据。这用于我们所有的无参数构造函数调用，包括那些分配给局部变量的调用。对于方法调用，实际上引入了一个中间局部变量，并通过initobj清除其值。

我希望这说明了这个主题是多么复杂，同时也使它变得更加容易理解。在某些概念意义上，每次对new的调用都会在堆栈上分配空间-但正如我们所看到的，在IL级别上并不是这样发生的。我想强调一种特殊情况。看这个方法：

void HowManyStackAllocations()
{
    Guid guid = new Guid();
    // [...] Use guid
    guid = new Guid(someBytes);
    // [...] Use guid
    guid = new Guid(someString);
    // [...] Use guid
}

这个“逻辑上”有4个堆栈分配——一个用于变量，另外三个用于每个new调用——但实际上（对于特定的代码）堆栈只分配一次，然后重复使用相同的存储位置。

编辑：为了明确起见，这只在某些情况下成立……特别是，如果Guid构造函数引发异常，则guid的值不可见，这就是为什么C#编译器能够重用相同的堆栈插槽。有关详细信息和不能应用的情况，请参阅Eric Lippert关于值类型构造的博客文章。

在编写本答案时，我学到了很多东西——如果有不清楚的地方，请要求澄清！

- Jon Skeet

---

Jon，HowManyStackAllocations示例代码很好。但是你能否将其更改为使用结构体而不是Guid，或者添加一个新的结构体示例。我认为这将直接回答@kedar最初的问题。 - Ash

Guid已经是一个结构体。请参阅http://msdn.microsoft.com/en-us/library/system.guid.aspx。我不会选择引用类型作为这个问题的类型 :) - Jon Skeet

@Ani：你忽略了Eric的示例中有一个try/catch块——因此，如果在结构体的构造函数期间抛出异常，你需要能够在构造函数之前看到该值。我的示例没有这种情况——如果构造函数因异常而失败，那么guid的值只被部分覆盖也无所谓，因为它不会被显示出来。 - Jon Skeet

@Ani：实际上，Eric在他的帖子底部提到了这一点：“那么，Wesner的观点呢？是的，事实上，如果它是一个堆栈分配的本地变量（而不是闭包中的字段），并且在与构造函数调用相同的“try”嵌套级别上声明，则我们不需要进行这个繁琐的过程，即创建一个新的临时变量，初始化临时变量，并将其复制到本地变量中。在那种特定的（常见的）情况下，我们可以优化掉创建临时变量和复制的过程，因为C#程序无法观察到差异！” - Jon Skeet

C# 6.0的早期预览版本中存在用于结构体的无参数构造函数。但是后来被移除了。https://github.com/dotnet/roslyn/issues/1029 - Eldar

Answer 2

根据情况，结构体字段所在的内存可以分配在堆栈或堆上。如果结构体类型的变量是本地变量或参数，并且不被某些匿名委托或迭代器类所捕获，则它将在堆栈上分配。如果变量是某个类的一部分，则将在堆上的类中分配。

如果结构体在堆上分配，则实际上不需要调用 new 运算符来分配内存。唯一的目的是根据构造函数中的值设置字段值。如果未调用构造函数，则所有字段都将获取其默认值（0 或 null）。

对于在堆栈上分配的结构体也是同样的，除了C#要求先设置局部变量的值后再使用，因此您必须调用自定义构造函数或默认构造函数（始终为结构体提供不带参数的构造函数）。

- Jeffrey L Whitledge

Answer 3

简单来说，对于struct而言，“new”是一个错误的术语，调用“new”实际上只是调用了构造函数。结构体唯一的存储位置就是它的定义位置。

如果它是一个成员变量，它将直接存储在定义它的对象中，如果它是一个局部变量或参数，它将存储在堆栈中。

与之相比，类在其整体存储在应该存储结构体的地方有一个引用，而这个引用指向堆中某个位置。（成员变量在类内，局部变量/参数在堆栈中）

可能需要深入研究C++，因为在C++中，class和struct之间没有真正的区别。（语言中有类似的名称，但它们只是指事物的默认可访问性）当您调用“new”时，会得到指向堆位置的指针，而如果您有一个非指针引用，则它将直接存储在堆栈中或在其他对象中，如C＃中的结构体。

- Guvante

Answer 4

与所有值类型一样，结构体始终在它们被声明的位置。
有关何时使用结构体的更多详细信息，请参见此处的问题。
以及有关结构体的一些更多信息，请参见此处的问题。
编辑：我错误地回答了它们总是在堆栈中。这是不正确的。

- Esteban Araya

---

不，我认为这是完全正确的 - 即使它与引用类型不同。变量的值存在于它声明的位置。引用类型变量的值是一个引用而不是实际数据，仅此而已。 - Jon Skeet

总之，无论何时您在方法中创建（声明）值类型，它都会始终在堆栈上创建。 - Ash

@Ash（最近）：false；如果变量被“捕获”（进入lambda/匿名方法），那么它实际上是编译器生成类的字段，即在堆上。 - Marc Gravell

Jon，你没有理解我的观点。这个问题首先被提出的原因是许多开发人员（包括我在内，直到我读了CLR Via C#）不清楚如果使用new运算符创建结构体，它会被分配到哪里。说“结构体总是去它们声明的地方”并不是一个清晰的答案。 - Ash

@Ash：如果我有时间，到了工作地点我会尝试写一篇答案。不过这个话题太大了，在火车上讨论不太方便:) - Jon Skeet

Answer 5

我可能在这里漏掉了什么，但我们为什么关心分配？

值类型是按值传递的 ;) 因此不能在定义它们的范围之外的不同范围中进行变异。要能够变异该值，必须添加 [ref] 关键字。

引用类型是按引用传递的，可以进行变异。

当然也有不可变的引用类型，其中字符串是最受欢迎的一种。

数组布局/初始化： 值类型 -> 零内存 [name,zip][name,zip] 引用类型 -> 零内存 -> 空 [ref][ref]

- user18579

---

引用类型并不是通过引用传递的，而是通过值传递的。这是非常不同的。 - Jon Skeet

引用是按值传递的，这里指的是一个引用（但这与通过引用传递 ref 类型不同）。 - user1234567

Answer 6

一个 class 或 struct 声明就像一个蓝图，用于在运行时创建实例或对象。如果你定义了一个名为 Person 的 class 或 struct，Person 就是该类型的名称。如果你声明并初始化一个类型为 Person 的变量 p，那么 p 就被称为 Person 的对象或实例。可以创建多个相同 Person 类型的实例，每个实例的 properties 和 fields 可以有不同的值。 class 是引用类型。当创建 class 的对象时，分配给对象的变量只保存对该内存的引用。当对象引用分配给新变量时，新变量引用原始对象。通过一个变量所做的更改会反映在另一个变量中，因为它们都引用相同的数据。 struct 是值类型。创建 struct 时，分配给 struct 的变量保存结构的实际数据。当 struct 分配给新变量时，它会被复制。因此，新变量和原变量包含两个单独的相同数据的副本。对一个副本所做的更改不会影响另一个副本。

一般来说，classes 用于模拟更复杂的行为或在创建 class 对象后打算修改的数据。Structs 最适合包含主要不打算在创建 struct 后修改的数据的小型数据结构。 更多信息...

- Sujit

Answer 7

结构体被分配到堆栈中。这里有一个有用的解释：

结构体

此外，在.NET中实例化的类会在堆或.NET保留的内存空间上分配内存。而结构体由于在堆栈上分配，因此在实例化时产生更高的效率。此外，应注意通过值传递结构体中的参数。

- DaveK

---

这并不包括结构体是类的一部分的情况 - 这时它与对象的其他数据一起存在于堆上。 - Jon Skeet

是的，但它实际上关注并回答了被问的问题。被投票赞同。 - Ash

尽管仍然不正确和具有误导性，但这个问题没有简短的答案 - Jeffrey的回答是唯一完整的答案。 - Marc Gravell

Answer 8

基本上，被视为值类型的结构体会分配在堆栈上，而对象则分配在堆上，而对象引用（指针）则分配在堆栈上。

- bashmohandes