使用SPARQL查询进行UNION和intersection

Question

我正在将用户定义的查询转换成SPARQL。例如，当用户说“abc”时，它意味着给我所有具有名为“abc”的某些属性的给定类型的节点。作为此的扩展，如果用户说“abc或（pqr和lmn）”，我需要查找所有给定类型的节点，其中某个属性为“abc或（pqr和lmn）”。以下是我想出来的查询：

SELECT DISTINCT ?node, ?type                                                 
WHERE                                                                          
{
  {                                                                              
    ?node a ?type .                                                          
    FILTER ( ?type != <sometype>)
  }
{           
  {                                                                              
    ?node ?reln0 ?obj0 .                                                     
    FILTER ( regex(str(?obj0), 'abc', "i") )                           
  }                                                                              
  UNION                                                                          
  {                                                                              
    {                                                                              
      ?node ?reln1 ?obj1 .                                                     
      FILTER ( regex(str(?obj1), 'pqr', "i") )                                
    }
    {                                                                             
      ?node ?reln2 ?obj2 .                                                     
      FILTER ( regex(str(?obj2), 'lmn', "i") )                               
    }                                                                              
  }
}                                                                              
}                                                                              
ORDER BY ?node

但它没有返回正确的结果。上述查询有什么问题吗？我不想使用下面的查询，因为我需要动态生成条件，并且每个子句都需要单独处理。

FILTER (regex(str(?obj2), 'abc', "i") || regex(str(?obj2), 'pqr', "i") && regex(str(?obj2), 'lmn', "i"))

- Ksh Padalkar

---

我不明白为什么你不使用第二种方法，即一个大的“FILTER”。它更简单且有效。 - cygri

这些基本情况的{}主体可能更加复杂，并且将与它们混合。FILTER仅适用于此情况。 - Ksh Padalkar

另外，我发现上面的查询在Redland上无法工作。然后我尝试安装ARQ并在其上运行，结果成功了。因此，这可能与特定的实现有关。 - Ksh Padalkar

“doesn't return proper results” 是什么意思？ - Ben Companjen

你使用的Redland库（和ARQ）版本是什么？我得到的结果似乎是“正确”的。你能展示一下你正在处理的数据吗？ - Joshua Taylor

Answer 1

我将您的查询具体化如下（为第一个过滤器设置明确的类型）：

PREFIX : <http://example.org/>

SELECT DISTINCT ?node ?type                                                 
WHERE                                                                          
{
    {                                                                              
        ?node a ?type .                                                          
        FILTER ( ?type != :Type1 )
    }
    {           
        {                                                                              
            ?node ?reln0 ?obj0 .                                                     
            FILTER ( regex(str(?obj0), 'abc', "i") )                           
        }                                                                              
        UNION                                                                          
        {                                                                              
            {                                                                              
                ?node ?reln1 ?obj1 .                                                     
                FILTER ( regex(str(?obj1), 'pqr', "i") )                                
            }
            {                                                                             
                ?node ?reln2 ?obj2 .                                                     
                FILTER ( regex(str(?obj2), 'lmn', "i") )                               
            }                                                                              
        }
    }                                                                              
}                                                                              
ORDER BY ?node

我随后生成了以下数据：

@prefix : <http://example.org/> .

:n1 a :Type2 ;    # keep
    :r0 :NodeABC .

:n2 a :Type2 ;
    :r0 :NodeBCD .

:n3 a :Type2 ;     # keep
    :r1 :NodePQR ;
    :r2 :NodeLMN .

:n4 a :Type2 ;
    :r1 :NodeQRS ;
    :r2 :NodeLMN .

:n5 a :Type2 ;
    :r1 :NodePQR ;
    :r2 :NodeMNO .

:n6 a :Type2 ;
    :r1 :NodeQRS ;
    :r2 :NodeMNO .

只有:n1和:n3应该被保留。我可以通过Jena的命令行ARQ或基于Redland的roqet运行此代码，并在两种情况下得到这些规则。

使用ARQ：

$ arq --data data.n3 --query query.sparql
-----------------
| node | type   |
=================
| :n1  | :Type2 |
| :n3  | :Type2 |
-----------------

$ arq --version
Jena:       VERSION: 2.10.0
Jena:       BUILD_DATE: 2013-02-20T12:04:26+0000
ARQ:        VERSION: 2.10.0
ARQ:        BUILD_DATE: 2013-02-20T12:04:26+0000

使用roqet:

$ roqet query.sparql -D data.n3 -r table
roqet: Querying from file query.sparql
--------------------------------------------------------------
| node                       | type                          |
==============================================================
| uri<http://example.org/n1> | uri<http://example.org/Type2> |
| uri<http://example.org/n3> | uri<http://example.org/Type2> |
--------------------------------------------------------------

$ roqet -v
0.9.28

- Joshua Taylor