DOS批处理脚本将字符串转换为十六进制

Question

如何在DOS批处理脚本中将字符串转换为十六进制？ 例如，将“abcd”转换为“61626364”。 因为，'a'是0x61...

我尝试从网上寻找解决方案，一整天都没有找到答案。

- Mannsik Chung

---

我怀疑只有批处理文件是没有解决方案的。如果可以使用PowerShell，那将会很容易。 - Eric J.

Answer 1

@echo off
setlocal EnableDelayedExpansion

rem Store the string in chr.tmp file
set /P "=%~1" < NUL > chr.tmp

rem Create zero.tmp file with the same number of Ascii zero characters
for %%a in (chr.tmp) do fsutil file createnew zero.tmp %%~Za > NUL

rem Compare both files with FC /B and get the differences
set "hex="
for /F "skip=1 tokens=2" %%a in ('fc /B chr.tmp zero.tmp') do set "hex=!hex!%%a"

del chr.tmp zero.tmp
echo %hex%

输出示例：

C:\> test.bat abcd
61626364

- Aacini

Answer 2

:stringToHex
@echo off
del tmp.hex >nul 2>nul
del tmp.str >nul 2>nul
if "%~1" equ "" (
  echo no string passed
  exit /b 1
)  
echo|set /p=%~1 >tmp.str
::(echo(%~1)>tmp.str
rem certutil -dump tmp.str
certutil -encodehex tmp.str tmp.hex >nul
setlocal enableDelayedExpansion
set "hex_str="
for /f "usebackq tokens=2 delims=   " %%A in ("tmp.hex") do (
    set "line=%%A"
    set hex_str=!hex_str!!line:~0,48!
    set hex_str=!hex_str: =!

)
set hex_str=%hex_str:~0,-2%
echo !hex_str!

请注意，stackoverflow编辑器可能会破坏制表符。tokens=2 delims= " 在delims后应该只有一个单独的TAB。

需要将字符串作为参数传递。还可以查看debnham的:hexDump函数，您可以使用它来代替certutil。

- npocmaka