VBA vlookup公式错误

Question

我是Excel宏VBA的新手。我的vlookup代码存在问题，它引用了用户选择的另一个工作簿。

以下是我的代码：

Private Sub vlookups()

Dim data_file_new As String
Dim i As Integer
Dim a As String, b As String, path As String

data_file_new = CStr(Application.GetOpenFilename(FileFilter:="Excel Workbooks (*.xls*),*.xls*", Title:="Select new data file for VLOOKUP"))

path = data_file_new

a = "=VLOOKUP(A:A,'[" & path & "]Source'!$A:$AB,28,0)"
b = "=VLOOKUP(A:A,'[" & path & "]Source'!$A:$AJ,36,0)"
i = 7

Do Until Sheets("Macro Template").Cells(i, 1) = ""

    Sheets("Macro Template").Cells(i, 37) = a
    Sheets("Macro Template").Cells(i, 38) = b

    i = i + 1
Loop

End Sub

我的问题是，我的代码没有给出正确的vlookup公式，而是给出了这个公式：

=VLOOKUP(A:A,'[E:\AP NO APPROVAL\[No Approval Monitoring Log_June 2015 xlsx.xlsx]Source]No Approval Monitoring Log_June'!$A:$AB,28,0)

正确的公式是这样的：

=VLOOKUP(A:A,'E:\AP NO APPROVAL\[No Approval Monitoring Log_June 2015 xlsx.xlsx]Source'!$A:$AB,28,0)

任何帮助都将不胜感激。

谢谢！

- John F

---

当您尝试粘贴正确的公式时会发生什么？ - Martin

你看过 path 实际上的值了吗？试着在给 path 赋值的那一行打一个断点，看看它的值是多少。听起来它的值是不正确的。 - Martin

它包含所选文件的路径，包括文件名。但我不知道为什么它显示错误的公式。 - John F

请尝试我发布的代码。您可能需要刷新页面。 - Siddharth Rout

代码显示运行时错误1004。 - John F

Answer 1

尝试这个（未经测试）

Private Sub vlookups()
    Dim ws As Worksheet
    Dim lRow As Long
    Dim sPath As String, sFile As String, sTemp As String
    Dim Ret

    Set ws = ThisWorkbook.Sheets("Macro Template")

    Ret = Application.GetOpenFilename(FileFilter:="Excel Workbooks (*.xls*),*.xls*", _
                                      Title:="Select new data file for VLOOKUP")

    If Ret = False Then Exit Sub

    sFile = GetFilenameFromPath(Ret)
    sPath = Split(Ret, sFile)(0)
    sTemp = "=VLOOKUP(A:A,'" & sPath & "[" & sFile

    With ws
        lRow = .Range("A" & .Rows.Count).End(xlUp).Row

        .Range("AK7:AK" & lRow).Formula = sTemp & "]Source'!$A:$AB,28,0)"
        .Range("AL7:AL" & lRow).Formula = sTemp & "]Source'!$A:$AJ,36,0)"
    End With
End Sub

Public Function GetFilenameFromPath(ByVal strPath As String) As String
    If Right$(strPath, 1) <> "\" And Len(strPath) > 0 Then
        GetFilenameFromPath = _
        GetFilenameFromPath(Left$(strPath, Len(strPath) - 1)) + Right$(strPath, 1)
    End If
End Function

说明:

1. Application.GetOpenFilename() 返回一个 Variant。请按照上面的代码处理它。

2. 你要查找的公式是 =VLOOKUP(A:A,'E:\AP NO APPROVAL\[No Approval Monitoring Log_June 2015 xlsx.xlsx]Source'!$A:$AB,28,0)，而 Ret 将给出一个文件路径和名称 E:\AP NO APPROVAL\No Approval Monitoring Log_June 2015 xlsx.xlsx。 Vlookup 在文件名周围放置了一个 []。你需要先从文件路径中提取文件名并重新构建整个字符串。我们使用上面的代码中的 Function GetFilenameFromPath 来检索它。

3. 你不需要循环单元格来输入公式。你可以在整个范围内一次性输入公式。

- Siddharth Rout

Answer 2

你没有指定公式所引用的工作表，这就是问题所在。

- dasg7