我在VBA中使用WorksheetFunction.Transpose
将一个混合日期/字符串的1D数组转换为2D数组以便写入工作表。
设置了Windows区域设置为DMY
后,写回的日期被交换了月份/日期。
我在VBA中使用WorksheetFunction.Transpose
将一个混合日期/字符串的1D数组转换为2D数组以便写入工作表。
设置了Windows区域设置为DMY
后,写回的日期被交换了月份/日期。
在本论坛中提到了这个问题,涉及到将Dates
转换为Strings
,这是通过WorksheetFunction.Transpose
方法实现的。
我深入研究了一下这个问题。
似乎WorksheetFunction.Transpose
可以转换许多数据类型。转置后的结果可能是Boolean
、Double
或者String
中的任意一种。
使用VBA时需要考虑到这一点。
以下是一些演示此问题的代码:
Option Explicit
Option Base 1
Sub Tester()
Dim v, w, i As Long
v = Array(CBool(-1), CBool(0), CByte(9), CDbl(1234), CDec(1234), _
CInt(1234), CLng(1234), CLngPtr(1234), CSng(1234), _
CCur(123456), #5/1/2015#, "1234")
w = WorksheetFunction.Transpose(v)
For i = 1 To UBound(v)
Debug.Print v(i), TypeName(v(i)), w(i, 1), TypeName(w(i, 1))
Next i
End Sub
debug.print输出
True Boolean True Boolean
False Boolean False Boolean
9 Byte 9 Double
1234 Double 1234 Double
1234 Decimal 1234 Double
1234 Integer 1234 Double
1234 Long 1234 Double
1234 Long 1234 Double
1234 Single 1234 Double
123456 Currency $123,456.00 String
01-May-15 Date 01-05-2015 String
1234 String 1234 String
编辑 WorksheetFunction.Transpose
的另一个问题
Ubound(1D_array) mod 2^16
给出uBound(1D_array) mod 2^16
个元素将返回到转置后的数组中。
您可以在内存中使用 ListBox 进行转置,而无需使用 Transpose,并且数据类型保持不变:
Option Explicit
Option Base 1
Sub Tester2()
Dim v, w, i As Long
v = Array(CBool(-1), CBool(0), CByte(9), CDbl(1234), CDec(1234), _
CInt(1234), CLng(1234), CLngPtr(1234), CSng(1234), _
CCur(123456), #5/1/2015#, "1234")
w = WorksheetFunction.Transpose(v)
For i = 1 To UBound(v)
Debug.Print v(i), TypeName(v(i)), w(i, 1), TypeName(w(i, 1))
Next i
With CreateObject("New:{8BD21D20-EC42-11CE-9E0D-00AA006002F3}")
'Listbox always Base 0
.List = v
w = .List 'Now 2-dim with correct typenames, use .column for transpose Row-column)
End With
For i = 1 To UBound(v)
Debug.Print v(i), TypeName(v(i)), w(i - 1, 0), TypeName(w(i - 1, 0))
Next i
End Sub
Range.Value2
而不是Range.Value
。它会保留底层值。 - shrivallabha.redij