logo标签列表

如何在虚拟模式下自动调整列表视图的列宽？

delphidelphi-xetlistview
15

当我使用 TListView（ViewStyle = vsReport）时，可以通过设置每列的宽度属性中的 LVSCW_AUTOSIZE 或 LVSCW_AUTOSIZE_USEHEADER 值来自动调整列的宽度，现在我开始在虚拟模式下使用 Listview，但是列的宽度不会根据这些值进行修改。因此问题是：当ListView处于虚拟模式时，如何调整列的宽度以适应内容或标题？

4
在虚拟模式下，控件的大小应该基于可见项来确定，因为那是控件所能使用的全部内容。 - David Heffernan
@DavidHeffernan已经怀疑了这样的情况，但是有没有自动调整列宽的功能？还是我必须编写自己的函数？ - Salvador
你需要编写自己的函数，因为常规控件不会要求获取你控件中所有数据，只会获取可见的行。 - David Heffernan
我同意。一种做法是遍历列中的所有字符串，并对每个项目执行Canvas.TextWidth。 - bjaastad_e
关于测量标题宽度，您可以做同样的事情。但是在那里，由于标题项的斜角边缘占用的像素，通常需要添加一些额外的像素才能正确地完成。 - bjaastad_e
1
@Elling，这是唯一的方法。在虚拟模式下，您仅为可见项目查询数据，因此列表视图永远不知道所有项目的标题（这就是LVSCW_AUTOSIZE行为的原因）。至于额外的像素，该值是推测性的（即使微软也没有说明如何计算它们，详见下面我的回答）。 - TLama
3个回答
6
由于虚拟模式下的列表视图不预先知道项目标题（因为它仅请求可见区域的数据），也无法知道最宽的宽度，这就是LVM_SETCOLUMNWIDTH自动大小标志的行为方式。
因此，唯一的方法是编写一个自定义函数，它将查询所有数据，测量所有未来标题的文本宽度，并将列宽设置为最宽的值。
以下示例显示了如何执行此操作。它使用ListView_GetStringWidth宏进行文本宽度计算（似乎这是最自然的方法）。但问题在于文本填充的值。正如文档中所述：
“ ListView_GetStringWidth宏返回指定字符串的精确宽度（以像素为单位）。如果您将返回的字符串宽度用作对ListView_SetColumnWidth宏的调用中的列宽，则该字符串将被截断。要检索可以包含字符串而不将其截断的列宽，必须向返回的字符串宽度添加填充。”
但他们没有提到如何获取填充值（似乎他们不会这样做）。有些人说（例如此处），对于项目填充，使用6 px，对于子项填充，使用12 px就足够了，但它并不是（至少对于Windows 7上的此示例而言）。
///////////////////////////////////////////////////////////////////////////////
/////   List View Column Autosize (Virtual Mode)   ////////////////////////////
///////////////////////////////////////////////////////////////////////////////

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, StdCtrls,
  Forms, Dialogs, StrUtils, ComCtrls, CommCtrl;

type
  TSampleRecord = record
    Column1: string;
    Column2: string;
    Column3: string;
  end;
  TSampleArray = array [0..49] of TSampleRecord;

type
  TForm1 = class(TForm)
    Button1: TButton;
    ListView1: TListView;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    SampleArray: TSampleArray;
    procedure AutoResizeColumn(const AListView: TListView;
      const AColumn: Integer);
    procedure OnListViewData(Sender: TObject; Item: TListItem);
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

///////////////////////////////////////////////////////////////////////////////
/////   TForm1.AutoResizeColumn - auto-size column   //////////////////////////
///////////////////////////////////////////////////////////////////////////////

// AListView - list view object instance
// AColumn - index of the column to be auto-sized

procedure TForm1.AutoResizeColumn(const AListView: TListView;
  const AColumn: Integer);
var
  S: string;
  I: Integer;
  MaxWidth: Integer;
  ItemWidth: Integer;
begin
  // set the destination column width to the column's caption width
  // later on we'll check if we have a wider item
  MaxWidth := ListView_GetStringWidth(AListView.Handle,
    PChar(AListView.Columns.Items[AColumn].Caption));
  // iterate through all data items and check if their captions are
  // wider than the currently widest item if so then store that value
  for I := 0 to High(SampleArray) do
  begin
    case AColumn of
      0: S := SampleArray[I].Column1;
      1: S := SampleArray[I].Column2;
      2: S := SampleArray[I].Column3;
    end;
    ItemWidth := ListView_GetStringWidth(AListView.Handle, PChar(S));
    if MaxWidth < ItemWidth then
      MaxWidth := ItemWidth;
  end;
  // here is hard to say what value to use for padding to prevent the
  // string to be truncated; I've found the suggestions to use 6 px
  // for item caption padding and 12 px for subitem caption padding,
  // but a few quick tests confirmed me to use at least 7 px for items
  // and 14 px for subitems
  if AColumn = 0 then
    MaxWidth := MaxWidth + 7
  else
    MaxWidth := MaxWidth + 14;
  // and here we set the column width with caption padding included
  AListView.Columns.Items[AColumn].Width := MaxWidth;
end;

///////////////////////////////////////////////////////////////////////////////
/////   TForm1.FormCreate - setup the list view and fill custom data   ////////
///////////////////////////////////////////////////////////////////////////////

procedure TForm1.FormCreate(Sender: TObject);
var
  I: Integer;
begin
  ListView1.ViewStyle := vsReport;
  ListView1.Columns.Add.Caption := 'Column 1';
  ListView1.Columns.Add.Caption := 'Column 2';
  ListView1.Columns.Add.Caption := 'Column 3';
  ListView1.OwnerData := True;
  ListView1.OnData := OnListViewData;
  ListView1.Items.Count := High(SampleArray);

  for I := 0 to High(SampleArray) do
  begin
    SampleArray[I].Column1 := 'Cell [0, ' + IntToStr(I) + '] ' +
      DupeString('x', I);
    SampleArray[I].Column2 := 'Cell [1, ' + IntToStr(I) + '] ' +
      DupeString('x', High(SampleArray) - I);
    SampleArray[I].Column3 := '';
  end;
end;

///////////////////////////////////////////////////////////////////////////////
/////   TForm1.FormCreate - custom handler for OnData event   /////////////////
///////////////////////////////////////////////////////////////////////////////

procedure TForm1.OnListViewData(Sender: TObject; Item: TListItem);
begin
  Item.Caption := SampleArray[Item.Index].Column1;
  Item.SubItems.Add(SampleArray[Item.Index].Column2);
  Item.SubItems.Add(SampleArray[Item.Index].Column3);
end;

///////////////////////////////////////////////////////////////////////////////
/////   TForm1.Button1Click - auto-resize all 3 columns   /////////////////////
///////////////////////////////////////////////////////////////////////////////

procedure TForm1.Button1Click(Sender: TObject);
begin
  AutoResizeColumn(ListView1, 0);
  AutoResizeColumn(ListView1, 1);
  AutoResizeColumn(ListView1, 2);
end;

end.
GetThemeData 是什么？如果启用了主题，找到填充值可能会很方便，但仍然需要注意。 - TLama
我认为在这里真正需要的是根据可见虚拟集合进行实时自动扩展和/或自动缩短。 - Paul-Sebastian Manole
3
Consider this 帮助函数单元, 由RRUZ编写。
帮助函数摘录：
procedure AutoResizeColumn(const Column:TListColumn;const Mode:Integer=LVSCW_AUTOSIZE_BESTFIT);
procedure AutoResizeColumns(const Columns : Array of TListColumn;const Mode:Integer=LVSCW_AUTOSIZE_BESTFIT);
procedure AutoResizeListView(const ListView : TListView;const Mode:Integer=LVSCW_AUTOSIZE_BESTFIT);

Mode (参数) 可以是:

  • LVSCW_AUTOSIZE_BESTFIT
  • LVSCW_AUTOSIZE
  • LVSCW_AUTOSIZE_USEHEADER

我希望它能为您的需求提供一个良好的起点。

这正是我设置列宽的方式，但仅适用于ListView不处于虚拟模式时。 - Salvador
0

这里有另一个可能的解决方案，可以避免列过窄。但是，它需要一些有关于您需要显示的数据的知识，因此不是通用解决方案。

使用最长/最宽的数据项构建ListViewItem。切换到非虚拟模式，仅添加此最大的ListViewItem。根据最大项自动调整列宽，然后删除最大项，并切换回虚拟模式。例如：

// build a ListViewItem with longest data items
string[] items = new string[2];
items[0] = "999999"; // number
items[1] = "99:59:59.999"; // time hh:mm:ss.ttt
ListViewItem lviMax = new ListViewItem (items);
lv.VirtualMode = false; // switch to non-virtual mode
lv.Items.Clear (); // empty the row/line collection
lv.Visible = false; // so user doesnt see the fake values
lv.Items.Add (lviMax); // add line(s) with longest possible data items
lv.AutoResizeColumns (ColumnHeaderAutoResizeStyle.ColumnContent); // adjust column width
lv.AutoResizeColumns (ColumnHeaderAutoResizeStyle.HeaderSize); // adjust column width
lv.Items.Clear (); // empty row/line collection
lv.Visible = true;
lv.VirtualMode = true; // switch back to virtual mode

根据您的样本格式值，某些列现在可能有点太宽了，但至少不会有任何列太窄了。
网页内容由stack overflow 提供, 点击上面的
可以查看英文原文，
原文链接