如何在Windows XP中获取主音量？

Question

如何在Windows XP中获取主音量？

5

在Windows XP中，使用Delphi，如何获取主音量？

我知道可以使用keybd_event(VK_VOLUME_UP, 1, 0, 0);和keybd_event(VK_VOLUME_DOWN, 1, 0, 0);来设置音量的增减，但我不知道如何获取实际的音量值。

- eKek0

这个问题与Delphi无关，只涉及Windows API。这个链接可能会有所帮助：http://blogs.msdn.com/b/alejacma/archive/2010/01/13/how-to-set-sound-volume-programmatically.aspx - Andreas Rejbrand

我不是说一定要用Delphi，而是想知道如何在Delphi中实现这个功能。 - eKek0

那个链接涉及波形音量，而不是主音量。 - eKek0

这是在Windows Vista+中的操作方法：http://blogs.msdn.com/b/larryosterman/archive/2007/03/06/how-do-i-change-the-master-volume-in-windows-vista.aspx - Andreas Rejbrand

Windows Vista对设备的概念与XP有所不同。 - eKek0

1个回答

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- Sertac Akyuz · Accepted Answer

下面是对找到的示例代码（Thomas Stutz负责）所做的小修改，该示例设置了麦克风音量。我只是修改了组件类型-将扬声器目标替换为麦克风源，并用mixerGetControlDetails替换了mixerSetControlDetails，当然还把setter变成了getter。在我测试过的几个系统中（XPSp3、XPSp2、W2K、98），它似乎可以工作。函数的返回值是第一个（默认）混音器的扬声器输出-0-65535的值，“ShowMessage”在按钮处理程序中将其转换为百分比。但不要向我询问更多细节，我真的没有使用混音api的经验。相反，请参考这里，虽然这篇文章很老，但对我来说似乎真的非常全面。

function GetSpeakerVolume(var bValue: Word): Boolean;
var                          {0..65535}
  hMix: HMIXER;
  mxlc: MIXERLINECONTROLS;
  mxcd: TMIXERCONTROLDETAILS;
  vol: TMIXERCONTROLDETAILS_UNSIGNED;
  mxc: MIXERCONTROL;
  mxl: TMixerLine;
  intRet: Integer;
  nMixerDevs: Integer;
begin
  Result := False;

  // Check if Mixer is available
  nMixerDevs := mixerGetNumDevs();
  if (nMixerDevs < 1) then
    Exit;

  // open the mixer
  intRet := mixerOpen(@hMix, 0, 0, 0, 0);
  if intRet = MMSYSERR_NOERROR then
  begin
    mxl.dwComponentType := MIXERLINE_COMPONENTTYPE_DST_SPEAKERS;
    mxl.cbStruct := SizeOf(mxl);

    // get line info
    intRet := mixerGetLineInfo(hMix, @mxl, MIXER_GETLINEINFOF_COMPONENTTYPE);

    if intRet = MMSYSERR_NOERROR then
    begin
      ZeroMemory(@mxlc, SizeOf(mxlc));
      mxlc.cbStruct := SizeOf(mxlc);
      mxlc.dwLineID := mxl.dwLineID;
      mxlc.dwControlType := MIXERCONTROL_CONTROLTYPE_VOLUME;
      mxlc.cControls := 1;
      mxlc.cbmxctrl := SizeOf(mxc);

      mxlc.pamxctrl := @mxc;
      intRet := mixerGetLineControls(hMix, @mxlc, MIXER_GETLINECONTROLSF_ONEBYTYPE);

      if intRet = MMSYSERR_NOERROR then
      begin
        ZeroMemory(@mxcd, SizeOf(mxcd));
        mxcd.dwControlID := mxc.dwControlID;
        mxcd.cbStruct := SizeOf(mxcd);
        mxcd.cMultipleItems := 0;
        mxcd.cbDetails := SizeOf(vol);
        mxcd.paDetails := @vol;
        mxcd.cChannels := 1;

        intRet := mixerGetControlDetails(hMix, @mxcd, MIXER_GETCONTROLDETAILSF_VALUE);
        if intRet <> MMSYSERR_NOERROR then
          ShowMessage('GetControlDetails Error')
        else begin
          bValue := vol.dwValue;
          Result := True;
        end;
      end
      else
        ShowMessage('GetLineInfo Error');
    end;
    intRet := mixerClose(hMix);
  end;
end;


procedure TForm1.Button1Click(Sender: TObject);
var
  Vol: Word;
begin
  if GetSpeakerVolume(Vol) then
    ShowMessage(IntToStr(Round(Vol * 100 / 65535)));
end;