我正在尝试使用批处理文件通过ping确认网络连接。我想要批量运行，然后打印出ping是否成功。问题在于当作为批处理运行时，它总是显示“失败”。以下是代码：
@echo off
cls
ping racer | find "Packets: Sent = 4, Received = 4, Lost = 0 (0% loss),"
if not errorlevel 1 set error=success
if errorlevel 1 set error=failure
cls
echo Result: %error%
pause
'racer' 是我电脑的名称。我正在让电脑对自身进行ping测试，以排除网络连接质量差的可能性。就像我之前说过的，批处理程序总是失败。奇怪的是，如果我将代码复制到命令提示符中，程序就可以正常运行。是否有人知道为什么在命令提示符中可以正常运行而作为批处理却不行呢？ 谢谢。
一种更可靠的ping错误检查方法：
@echo off
set "host=192.168.1.1"
ping -n 1 "%host%" | findstr /r /c:"[0-9] *ms"
if %errorlevel% == 0 (
echo Success.
) else (
echo FAILURE.
)
这个功能通过检查像69 ms或314ms这样的字符串是否被ping打印出来来实现。
(翻译版本的Windows可能会打印带有空格的42 ms，因此我们要检查这种情况。)
原因：
其他提议，例如匹配time=或TTL不够可靠，因为ping IPv6地址不显示TTL（至少在我的Windows 7机器上不显示），而且Windows的翻译版本可能会显示time=的翻译版本。另外，time=可能不仅被翻译，有时还可能是time<，就像time<1ms的情况一样。
echo "Packets: Sent = 4, Received = 4, Lost = 0 (0% loss),"
您会发现%已经被删除了。在批处理文件中，%有特殊含义，因此您需要对其进行转义：
"Packets: Sent = 4, Received = 4, Lost = 0 (0%% loss),"
.. | find "TTL"
另一种不使用任何变量的变体
ping racer -n 1 -w 100>nul || goto :pingerror
...
:pingerror
echo Host down
goto eof
:eof
exit /b
我不确定FIND和设置错误级别之间的交互是什么，但你可以很容易地做到这一点：
@echo off
for /f %%i in ('ping racer ^| find /c "(0%% loss)"') do SET MATCHES=%%i
echo %MATCHES%
0如果ping失败，1如果成功。我让它只寻找"0% loss"（不是具体的4个ping），以便可以自定义ping的次数。FOR技巧仅仅是将命令的输出设置为环境变量的值。是的，ping命令无法返回正确的错误级别。为了检查网络连接和计算机状态，我使用了“net view 计算机名称”命令，然后检查%errorlevel%——简单易行。
net view无法做到这一点。 - Stephanping 命令有一个错误级别输出值。成功为 0，失败为 1。 只需执行以下操作：
C:\>ping 4.2.2.2
Pinging 4.2.2.2 with 32 bytes of data:
Reply from 4.2.2.2: bytes=32 time=28ms TTL=57
Reply from 4.2.2.2: bytes=32 time=29ms TTL=57
Reply from 4.2.2.2: bytes=32 time=30ms TTL=57
Reply from 4.2.2.2: bytes=32 time=29ms TTL=57
Ping statistics for 4.2.2.2:
Packets: Sent = 4, Received = 4, Lost = 0 (0% loss),
Approximate round trip times in milli-seconds:
Minimum = 28ms, Maximum = 30ms, Average = 29ms
C:\>echo %errorlevel%
0
C:\>ping foo.bar
Ping request could not find host foo.bar. Please check the name and try again.
C:\>echo %errorlevel%
1
正如您所看到的，没有必要进行过度编写脚本。
C:\>ping -n 1 172.25.0.1 正在 Ping 172.25.0.1 具有 32 字节的数据: 来自 172.25.1.1 的回复: 目标主机不可达。 172.25.0.1 的 Ping 统计信息: 数据包: 已发送 = 1，已接收 = 1，丢失 = 0 (0% 丢失)， C:\>echo %errorlevel% 0 - jdw首先
>@echo off
>for /f %%i in ('ping racer ^| find /c "(0%% loss)"') do SET MATCHES=%%i
>echo %MATCHES%
不起作用。如果它不失败，它将检测到0％，因为它是0％。 如果它失败了，也不会起作用，因为它将有100％的损失，这意味着它在10后面找到了0％的损失部分 10（0％的损失）
让它检测100％的损失，像这样：
>for /f %%i in ('ping -n 1 -l 1 %pc% ^| find /c "(100%% loss)"') do SET check=%%i
错误级别可能有点混乱，但它的工作效果非常好：
>if '%check%'=='1' goto fail
>if '%check%'=='0' echo %pc% is online.&goto starting
1 表示失败 0 表示成功
在我的脚本中使用链接。 Goto fail 将转到我的脚本中的 :fail，该脚本将向我发送消息，指出 %pc%（用户在开始时输入）处于离线状态，并进行另一次运行。
>:fail
>color 0c
>title %pc% is offline
>echo %pc% is offline
>PING -n 6 127.0.0.1>nul
>goto choice
希望对您有所帮助。
set error=failure
ping racer -n 1 -w 100>nul 2>&1 && set error=success
当然，如果在慢速网络上（例如拨号连接），需要调整-w参数的值（100毫秒可能太短了）。
祝好！
我需要重置wifi连接，因为它出现了问题。这是我的快速解决方案。
@echo off
Rem Microsoft Windows 10 ping test to gateway.
Rem Run batch file from an administrative command prompt.
cls
:starting
Rem Send one ping to the gateway. Write the results to a file.
ping 192.168.1.1 -n 1 > pingtest.txt
Rem Search for unreachable in the file.
c:\windows\system32\findstr.exe "unreachable" pingtest.txt
Rem errorlevel 0 reset the adapter if 1 then wait 10 minutes and test again
if %errorlevel%==1 goto waiting
Rem unreachable was found reset the adapter.
Rem write the date and time the reset was done.
echo Reset date: %date% time: %time% >> resettimes.txt
Rem issue netsh interface show interface to find your adapter's name to reset
Rem my adapter is "wi-fi"
netsh interface set interface "wi-fi" disable
timeout /t 5
netsh interface set interface "wi-fi" enable
:waiting
echo "It is online waiting 10 minutes"
timeout /t 600
goto starting