Perl的隐藏特性是什么？

引用单词操作符是我最喜欢的操作符之一。比较如下：

my @list = ('abc', 'def', 'ghi', 'jkl');

和

my @list = qw(abc def ghi jkl);

Perl相比SQL来说，更加清爽易读。另一个非常好的特点是允许在最后一个元素后面加逗号，这一点在写SQL时则很难做到。

print 1, 2, 3, ;

看起来很奇怪，但如果你以另一种方式缩进代码，就不会了：

print
    results_of_foo(),
    results_of_xyzzy(),
    results_of_quux(),
    ;

在函数调用中添加一个额外的参数不需要你再调整之前或之后的逗号。单行变化不会影响上下文的其他行。

这使得使用可变参数函数非常愉快。这也许是Perl最被低估的特性之一。

可以直接解析粘贴到数据块(DATA)中的数据。无需保存到测试文件中才能在程序中打开或类似操作。例如：

my @lines = <DATA>;
for (@lines) {
    print if /bad/;
}

__DATA__
some good data
some bad data
more good data 
more good data 

污点检测。启用污点检测后，如果尝试将污点数据（大致上是来自程序外部的数据）传递给不安全的函数（例如打开文件、运行外部命令等），Perl 将会停止执行（或者使用 -t 警告）。当编写 setuid 脚本、CGI 或任何脚本拥有比提供数据的人更高权限时，这非常有帮助。

神奇的跳转。 goto &sub 进行了优化的尾调用。

调试器。

use strict 和 use warnings。这些可以避免一堆拼写错误。

二进制的"x"是重复操作符：

print '-' x 80;     # print row of dashes

它也适用于列表：

print for (1, 4, 9) x 3; # print 149149149

新增块操作

我认为，扩展语言并创建伪块操作的能力是其中之一。

1. 您先声明一个子程序原型，指出它首先采用代码引用：

sub do_stuff_with_a_hash (&\%) {
    my ( $block_of_code, $hash_ref ) = @_;
    while ( my ( $k, $v ) = each %$hash_ref ) { 
        $block_of_code->( $k, $v );
    }
}

2. 你可以在body中这样调用它

use Data::Dumper;

do_stuff_with_a_hash {
    local $Data::Dumper::Terse = 1;
    my ( $k, $v ) = @_;
    say qq(Hey, the key   is "$k"!);
    say sprintf qq(Hey, the value is "%v"!), Dumper( $v );

} %stuff_for
;

(Data::Dumper::Dumper是另一个半隐藏的宝石。)注意到在代码块前面不需要sub关键字，也不需要哈希前面的逗号。最后看起来像这样：map {} @list

源代码过滤器

还有源代码过滤器，使用该功能可以让Perl将代码传递给你以便进行操作。不管是源代码过滤器还是块操作，都不建议在家中尝试。

我曾经用源代码过滤器做了一些很酷的东西，例如创建了一个非常简单的语言来检查时间，使得可以使用简短的Perl一行代码进行一些决策:

perl -MLib::DB -MLib::TL -e 'run_expensive_database_delete() if $hour_of_day < AM_7';

Lib::TL 将扫描变量和常量，创建它们并根据需要进行替换。

再次强调，源代码过滤器可能会很混乱，但功能强大。但是它们可能会导致调试器出现非常糟糕的问题，即使警告信息也可能打印在错误的行号上。我停止使用 Damian 的 Switch ，因为调试器失去了告诉我实际位置的所有能力。但我发现通过修改小段代码并将其保留在同一行上，可以最小化这种影响。

信号挂钩（Signal Hooks）

这通常已经足够了，但并不是那么明显。下面是一个利用旧处理程序的 die 处理程序示例：

my $old_die_handler = $SIG{__DIE__};
$SIG{__DIE__}       
    = sub { say q(Hey! I'm DYIN' over here!); goto &$old_die_handler; }
    ;

这意味着每当代码中的其他模块想要停止时，它们必须来找你（除非有人在 $SIG{__DIE__} 上进行破坏性覆盖）。而且你可以被通知有人认为某些事情是错误的。

当然，如果你只想清理一些东西，你也可以使用 END { } 块。

overload::constant

您可以在包括您的模块的包中检查特定类型的文字。例如，如果您在 import 子例程中使用此功能：

overload::constant 
    integer => sub { 
        my $lit = shift;
        return $lit > 2_000_000_000 ? Math::BigInt->new( $lit ) : $lit 
    };

如果这样做，意味着调用包中大于20亿的所有整数都将被更改为 Math::BigInt 对象（参见overload::constant）。

分组的整数字面量

顺便说一下，Perl允许您将大数字分成三位一组，并仍然获得可解析的整数。注意上面的 2_000_000_000 表示20亿。

基于 Perl 5 中 "-n" 和 "-p" 开关的实现方式，您可以编写一个包含 }{ 的看似不正确的程序：

ls |perl -lne 'print $_; }{ print "$. Files"'

这将被内部转换为以下代码：

LINE: while (defined($_ = <ARGV>)) {
    print $_; }{ print "$. Files";
}

这是一篇元回答，但Perl Tips存档包含了许多有关使用Perl做技巧的有趣技巧。以前技巧的归档在线浏览，并可通过邮件列表或Atom Feed进行订阅。

我最喜欢的一些技巧包括使用PAR构建可执行文件，使用autodie自动抛出异常，以及在Perl 5.10中使用switch和smart-match结构。

披露：我是Perl Tips的作者之一和维护者，所以我显然非常推崇它们。;)

map - 不仅因为它可以使代码更具表现力，而且它激发了我对“函数式编程”进一步阅读的冲动。

让我们从易入难，先介绍一下太空船运算符。

$a = 5 <=> 7;  # $a is set to -1
$a = 7 <=> 5;  # $a is set to 1
$a = 6 <=> 6;  # $a is set to 0

我会选择在Perl正则表达式中的 (?{}) 和 (??{}) 组。第一个组执行Perl代码，忽略返回值；第二个组执行代码，并使用返回值作为正则表达式。