这是一个示例,可以从三个线程中添加list1和list2中的值。
每次将值放入列表中时,都会触发一个事件,并且处理此事件的线程会提取列表中的最后一个值并清除事件标志。
在事件标志被清除之前,不能向列表中放入新值。
中间线程对新值进行中间存储,以避免阻塞第一个线程。
所有事件都可以等待,因此使CPU处于轻松状态。
这些列表是线程安全的。
program Project62;
{$APPTYPE CONSOLE}
uses
System.SysUtils,
System.Classes,
System.SyncObjs,
System.Generics.Collections;
Type
TMyThread1 = Class(TThread)
private
fMySyncAddList : TSimpleEvent;
fMyList : TThreadList<Integer>;
fAddVal : Integer;
public
Constructor Create(ASyncAddList: TSimpleEvent; AList: TThreadList<Integer>);
procedure Execute; override;
End;
TMyThread2 = Class(TThread)
private
fMySyncAddList1,fMySyncAddList2 : TSimpleEvent;
fMyList1,fMyList2 : TThreadList<Integer>;
fAddVal : Integer;
public
Constructor Create(ASyncAddList1,ASyncAddList2: TSimpleEvent; AList1,AList2 : TThreadList<Integer>);
procedure Execute; override;
End;
TMyThread3 = Class(TThread)
private
fMySyncAddList2 : TSimpleEvent;
fMyList2 : TThreadList<Integer>;
fAddVal : Integer;
public
Constructor Create(ASyncAddList2: TSimpleEvent; AList2 : TThreadList<Integer>);
procedure Execute; override;
End;
constructor TMyThread1.Create( ASyncAddList : TSimpleEvent; AList: TThreadList<Integer>);
begin
Inherited Create(false);
fMySyncAddList := AsyncAddList;
fMyList := AList;
end;
procedure TMyThread1.Execute;
var
stateAcknowledged : boolean;
begin
stateAcknowledged := true;
while (not Terminated) do
begin
if stateAcknowledged then
begin
fAddVal := Random(100);
fMyList.Add(fAddVal);
fMySyncAddList.SetEvent;
stateAcknowledged := false;
Sleep(1000);
end
else begin
stateAcknowledged := (fMySyncAddList.WaitFor(100) <> wrSignaled);
end;
end;
end;
constructor TMyThread2.Create(ASyncAddList1, ASyncAddList2: TSimpleEvent;
AList1, AList2: TThreadList<Integer>);
begin
Inherited Create(false);
fMySyncAddList1 := AsyncAddList1;
fMySyncAddList2 := AsyncAddList2;
fMyList1 := AList1;
fMyList2 := AList2;
end;
procedure TMyThread2.Execute;
var
wr : TWaitResult;
list : TList<Integer>;
pulled : Boolean;
begin
pulled := false;
while (not Terminated) do
begin
if pulled then
begin
wr := fMySyncAddList2.WaitFor(0);
if (wr <> wrSignaled) then
begin
fMyList2.Add(fAddVal);
fMySyncAddList2.SetEvent;
pulled := false;
end
else Sleep(100);
end
else begin
wr := fMySyncAddList1.WaitFor(INFINITE);
if Terminated then
Exit;
if (wr = wrSignaled) then
begin
list := fMyList1.LockList;
try
fAddVal := list.Last;
finally
fMyList1.UnlockList;
end;
pulled := true;
fMySyncAddList1.ResetEvent;
end;
end;
end;
end;
constructor TMyThread3.Create(ASyncAddList2: TSimpleEvent;
AList2: TThreadList<Integer>);
begin
Inherited Create(false);
fMySyncAddList2 := AsyncAddList2;
fMyList2 := AList2;
end;
procedure TMyThread3.Execute;
var
wr : TWaitResult;
list : TList<Integer>;
begin
while not Terminated do
begin
wr := fMySyncAddList2.WaitFor(INFINITE);
if Terminated then
Exit;
if (wr = wrSignaled) then
begin
list := fMyList2.LockList;
try
fAddVal := list.Last;
finally
fMyList2.UnlockList;
end;
fMySyncAddList2.ResetEvent;
end;
end;
end;
var
list1,list2 : TThreadList<Integer>;
syncList1,syncList2 : TSimpleEvent;
thread1 : TMyThread1;
thread2 : TMyThread2;
thread3 : TMyThread3;
begin
list1 := TThreadList<Integer>.Create;
list2 := TThreadList<Integer>.Create;
syncList1 := TSimpleEvent.Create(Nil,True,False,'',false);
syncList2 := TSimpleEvent.Create(Nil,True,False,'',false);
thread3 := TMyThread3.Create(syncList2,list2);
thread2 := TMyThread2.Create(syncList1,syncList2,list1,list2);
thread1 := TMyThread1.Create(syncList1,list1);
Try
WriteLn('Press [Enter] key to stop.');
ReadLn;
Finally
thread3.Terminate;
syncList2.SetEvent;
thread3.Free;
thread2.Terminate;
syncList1.SetEvent;
thread2.Free;
thread1.Free;
syncList1.Free;
syncList2.Free;
list1.Free;
list2.Free;
End;
end.
添加了一个示例,其中两个TThreadedQueue
在线程之间传递信息。线程保留整数的内部列表。正如@DavidHeffernan指出的那样,代码要简单得多。
program Project63;
{$APPTYPE CONSOLE}
uses
System.SysUtils,
System.Classes,
System.SyncObjs,
System.Generics.Collections;
Type
TMyThread1 = Class(TThread)
private
fMyList : TList<Integer>;
fMyQueue : TThreadedQueue<Integer>;
fAddVal : Integer;
public
Constructor Create(AQueue : TThreadedQueue<Integer>);
procedure Execute; override;
End;
TMyThread2 = Class(TThread)
private
fMyList1,fMyList2 : TList<Integer>;
fMyQueue1,fMyQueue2 : TThreadedQueue<Integer>;
fAddVal : Integer;
public
Constructor Create(AQueue1,AQueue2: TThreadedQueue<Integer>);
procedure Execute; override;
End;
TMyThread3 = Class(TThread)
private
fMyList : TList<Integer>;
fMyQueue : TThreadedQueue<Integer>;
fAddVal : Integer;
public
Constructor Create(AQueue : TThreadedQueue<Integer>);
procedure Execute; override;
End;
constructor TMyThread1.Create( AQueue : TThreadedQueue<Integer>);
begin
Inherited Create(false);
fMyQueue:= AQueue;
fMyList := TList<Integer>.Create;
end;
procedure TMyThread1.Execute;
begin
while (not Terminated) do
begin
Sleep(1000);
fAddVal := Random(100);
fMyList.Add(fAddVal);
fMyQueue.PushItem(fAddVal);
end;
fMyList.Free;
end;
constructor TMyThread2.Create(AQueue1,AQueue2: TThreadedQueue<Integer>);
begin
Inherited Create(false);
fMyQueue1 := AQueue1;
fMyQueue2 := AQueue2;
fMyList1 := TList<Integer>.Create;
fMyList2 := TList<Integer>.Create;
end;
procedure TMyThread2.Execute;
var
queueSize : Integer;
begin
while (not Terminated) do
begin
if (fMyQueue1.PopItem(queueSize,fAddVal) = wrSignaled) and
(not Terminated) then
begin
fMyList1.Add(fAddVal);
fMyQueue2.PushItem(fAddVal);
fMyList2.Add(fAddVal);
end;
end;
fMyList1.Free;
fMyList2.Free;
end;
constructor TMyThread3.Create(AQueue : TThreadedQueue<Integer>);
begin
Inherited Create(false);
fMyQueue := AQueue;
fMyList := TList<Integer>.Create;
end;
procedure TMyThread3.Execute;
var
queueSize : Integer;
begin
while not Terminated do
begin
if (fMyQueue.PopItem(queueSize,fAddVal) = wrSignaled) and
(not Terminated) then
begin
fMyList.Add(fAddVal);
end;
end;
fMyList.Free;
end;
var
queue1,queue2 : TThreadedQueue<Integer>;
thread1 : TMyThread1;
thread2 : TMyThread2;
thread3 : TMyThread3;
begin
queue1 := TThreadedQueue<Integer>.Create;
queue2 := TThreadedQueue<Integer>.Create;
thread3 := TMyThread3.Create(queue2);
thread2 := TMyThread2.Create(queue1,queue2);
thread1 := TMyThread1.Create(queue1);
Try
WriteLn('Press [Enter] key to stop.');
ReadLn;
Finally
thread3.Terminate;
queue2.PushItem(0);
thread3.Free;
thread2.Terminate;
queue1.PushItem(0);
thread2.Free;
thread1.Free;
queue1.Free;
queue2.Free;
End;
end.