如何在VBA中创建数据透视表

Question

我正在尝试创建一个数据透视表，但是出现了“无效的过程调用或参数”错误。

ActiveWorkbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:="rng", Version:=xlPivotTableVersion14).CreatePivotTable TableDestination:="rngB", TableName:="pvtReportA_B", DefaultVersion:=xlPivotTableVersion14

• rng（源）是由大约20列和几千行组成的范围。
• rngB（目标）是位于不同工作表中的单个单元格。

有人可以指点我错在哪里吗？

编辑：

我的错误，我应该将rngData用作源而不是rng。

    Set rng = wsA.Range("C14")
    Set rngData = Range(rng, rng.End(xlToRight))
    Set rngData = Range(rng, rng.End(xlDown))
    Set rngB = wsB.Range("C8")

    ActiveWorkbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:=rngData, Version:=xlPivotTableVersion14).CreatePivotTable TableDestination:=rngB, TableName:="pvtReportA_B", DefaultVersion:=xlPivotTableVersion14

这会很好地呈现数据透视表框架。

- aSystemOverload

---

您可以使用一行代码设置数据范围： Set rngData = range(wsA.Range("C14"),wsA.Range("C14").end(xlToRight).end(xlDown)) - Rafa Barragan

Answer 1

在此情况下，我使用了错误的范围对象，导致Excel出现问题。

Set rng = wsA.Range("C14")
Set rngData = Range(rng, rng.End(xlToRight))
Set rngData = Range(rng, rng.End(xlDown))
Set rngB = wsB.Range("C8")

ActiveWorkbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:=rngData, Version:=xlPivotTableVersion14).CreatePivotTable TableDestination:=rngB, TableName:="pvtReportA_B", DefaultVersion:=xlPivotTableVersion14

- aSystemOverload

---

在代码的第三行应该使用'rngData'而不是'rng'。 - amg

Answer 2

在Excel 2010中创建数据透视表，可以使用并调整以下代码模板：

Sub newPVT()
    Dim PTCache As PivotCache
    Dim PT As PivotTable

    'Create the Cache
    Set PTCache = ActiveWorkbook.PivotCaches.Create(SourceType:=xlDatabase, _
        SourceData:=Range("Dynamic_Field_Summary"))

    'Select the destination sheet
    Sheets("Field Summary").Select

    'Create the Pivot table
    Set PT = ActiveSheet.PivotTables.Add(PivotCache:=PTCache, _
        TableDestination:=Range("P1"), TableName:="Pivot1")

    ActiveWorkbook.ShowPivotTableFieldList = True

    'Adding fields
    With PT
        With .PivotFields("Enterprise")
            .Orientation = xlColumnField
            .Position = 1
        End With

        With .PivotFields("Field")
            .Orientation = xlRowField
            .Position = 1
        End With

        With .PivotFields("Planted Acres")
            .Orientation = xlDataField
            .Position = 1
            .Caption = " Planted Acres"
            .Function = xlSum
        End With

        With .PivotFields("Harvested Acres")
            .Orientation = xlDataField
            .Position = 2
            .Caption = " Harvested Acres"
            .Function = xlSum
        End With

        With .PivotFields("lbs")
            .Orientation = xlDataField
            .Position = 3
            .Caption = " lbs"
            .Function = xlSum
        End With

        'Adjusting some settings
        .RowGrand = False
        .DisplayFieldCaptions = False
        .HasAutoFormat = False

        'Improving the layout
        .TableStyle2 = "PivotStyleMedium9"
        .ShowTableStyleRowStripes = True
        .ShowTableStyleColumnStripes = True

    End With

    With ActiveSheet
        'Adjusting columns width
        .Columns("P:V").ColumnWidth = 16
        .Range("Q2:V2").HorizontalAlignment = xlCenter
    End With

    ActiveWorkbook.ShowPivotTableFieldList = False
End Sub

我在这里找到了它。

在这个页面上，您还可以找到代码的每个部分的含义，例如在这里有解释。 我认为这也是一个很好的代码，用于创建Excel 2007或其他版本的VBA宏。

- Nicolaesse