Flush-to-zero in gfortran

Question

有没有办法在gfortran中强制将下溢刷为零？

我无法相信这是有人第一次问这个问题，但我在任何地方都找不到相关信息。如果这是重复的，请原谅。

- bob.sacamento

---

请使用通用的 [tag:fortran]，因为没有多少人关注特定版本，而且您的问题根本不涉及Fortran版本。 - Vladimir F Героям слава

这里有关于该主题的一些讨论：https://gcc.gnu.org/bugzilla/show_bug.cgi?id=36821 - agentp

Answer 1

您可以使用支持Fortran 2003 IEEE模块的最新版本的gfortran来实现此操作。标准定义了两种下溢模式——渐进和突变。 突变是您想要的模式，它将下溢设置为0并发出下溢浮点异常信号。 您可以使用函数ieee_support_underflow_control(X)测试控制下溢模式是否受支持，该函数测试X的实际类型下溢控制是否受支持，并在受支持时返回逻辑真值。 如果受支持，则可以call ieee_set_underflow_mode(.false.)以设置突变下溢模式。

下面是一个测试程序，您可以使用它来测试默认实数类型的下溢控制支持：

program test
  use, intrinsic :: ieee_arithmetic
  use, intrinsic :: iso_fortran_env, only: compiler_version, compiler_options
  implicit none
  logical :: underflow_support, gradual, underflow
  real :: fptest
  integer :: i

  print '(4a)',  'This file was compiled by ', &
       compiler_version(), ' using the options ', &
       compiler_options()
  fptest = 0.0
  underflow_support = ieee_support_underflow_control(fptest)
  if (underflow_support) then
     print *,'Underflow control supported for the default real kind'
  else
     stop 'no underflow control support'
  end if

  call ieee_set_underflow_mode(.false.)
  call ieee_get_underflow_mode(gradual)
  if (.not.gradual) then 
     print *,'Able to set abrupt underflow mode'
  else
     stop 'error setting underflow mode'
  end if

  fptest = 2e-36
  do i=1,50 ! 50 iterations max
     fptest = fptest * 0.5
     print '(e15.10)',fptest
     call ieee_get_flag(ieee_underflow,underflow)
     if (underflow) print *,'Underflow exception signaling'
     if (fptest == 0.0) exit
  end do

end program test

使用 gfortran 5.2.0 版本，该程序输出：

This file was compiled by GCC version 5.2.0 using the options -mtune=generic -march=x86-64 -fno-unsafe-math-optimizations -frounding-math -fsignaling-nans
 Underflow control supported for the default real kind
 Able to set abrubpt underflow mode
.1000000036E-35
.5000000180E-36
.2500000090E-36
.1250000045E-36
.6250000225E-37
.3125000112E-37
.1562500056E-37
.0000000000E+00
 Underflow exception signaling

编译器选项标志-fno-unsafe-math-optimizations -frounding-math -fsignaling-nans建议在使用IEEE模块时始终使用，以确保遵守标准。

- casey

Answer 2

一种"清零"的简单方法是使用gfortran的-funsafe-math-optimizations选项：

允许可能违反IEEE或ISO标准的数学优化

或者用其他话来说：

此模式启用了充分利用任意重组和转换的优化，但不保证准确性。 它也不会尝试保留零的符号。

例如，small.f：

      program test
        real r
        r=1e-40
        print *,'r on next line'
        print *,r
      end program

如果没有任何标志，非零的非规格化（小）数将被显示，而不会出错：

$ gfortran -g small.f
$ ./a.out
 r on next line
   9.99994610E-41

当尝试打印该值时，陷入非规格化数会导致崩溃，需要对其进行处理：

$ gfortran -g -ffpe-trap=denorm small.f
$ ./a.out
 r on next line

Program received signal SIGFPE: Floating-point exception - erroneous arithmetic operation.

Backtrace for this error:
#0  0x2aaaab05c26f in ???
#1  0x2aaaaac61aed in get_float_string
        at ../../../libgfortran/io/write_float.def:1064
#2  0x2aaaaac6423d in list_formatted_write_scalar
        at ../../../libgfortran/io/write.c:1889
#3  0x4008f1 in test
        at /path/to/small.f:5
#4  0x400941 in main
        at /path/to/small.f:6
Floating point exception

同时添加了一个标志，将其刷新为零：

$ gfortran -g -ffpe-trap=denorm -funsafe-math-optimizations small.f
$ ./a.out
 r on next line
   0.00000000

- Mike T