使用AES输出块大小

Question

我正在尝试使用Racket的加密库，使用16字节的密钥加密16字节的数据块。我期望得到一个16字节的输出块，但实际上我得到了32字节的输出块。当输入块为15字节时，输出块为16位。

#lang racket

(require (planet vyzo/crypto))

(bytes-length (encrypt cipher:aes-128-ecb
                       (string->bytes/latin-1 "0123456789ABCDEF") ; 16-byte key
                       (make-bytes 16) ; IV
                       (string->bytes/latin-1 "0123456789ABCDEF"))) ; 16-byte data
; -> 32

(bytes-length (encrypt cipher:aes-128-ecb
                       (string->bytes/latin-1 "0123456789ABCDEF") ; 16-byte key
                       (make-bytes 16)
                       (string->bytes/latin-1 "0123456789ABCDE"))) ; 15-byte data
; -> 16

我哪里做错了吗？这是由于填充引起的吗？

注意：我知道ECB模式存在问题，我的目标是实现CBC模式。

- Clement J.

Answer 1

您说得对，这是由于填充造成的。不幸的是，vyzo/crypto lib 的API不允许您轻松禁用填充（这是正确的，见下文警告）。

如何禁用填充

然而，根据这个Racket用户邮件列表上的线程，您可以像这样禁用填充：

#lang racket

(require (planet vyzo/crypto) (planet vyzo/crypto/util))

(define (cipher-encrypt-unpadded type key iv)
  (lambda (ptext)
    (let ((octx (cipher-encrypt type key iv #:padding #f)))
      (bytes-append (cipher-update! octx ptext)
                    (cipher-final! octx)))))

(define (cipher-decrypt-unpadded type key iv)
  (lambda (ctext)
    (let ((ictx (cipher-decrypt type key iv #:padding #f)))
      (bytes-append (cipher-update! ictx ctext)
                    (cipher-final! ictx)))))

; bytes-> bytes
; convenience function for encryption
(define enc-aes-128-ecb-unpadded 
   (cipher-encrypt-unpadded cipher:aes-128-ecb 
                            (string->bytes/latin-1 "0123456789ABCDEF"); 16-byte key
                            (make-bytes 16)))

; bytes -> bytes
; convenience function for decryption       
(define dec-aes-128-ecb-unpadded 
   (cipher-decrypt-unpadded cipher:aes-128-ecb 
                            (string->bytes/latin-1 "0123456789ABCDEF"); 16-byte key
                            (make-bytes 16)))

(define message (string->bytes/latin-1 "0123456789ABCDEF")) ; 16-byte data

(bytes-length (enc-aes-128-ecb-unpadded message))
; -> 16


(dec-aes-128-ecb-unpadded (enc-aes-128-ecb-unpadded message))
; -> #"0123456789ABCDEF"

这在我的设备上运行良好。而且，切换到CBC模式很简单。 注意事项 当禁用填充时，您的消息必须具有块大小的倍数长度。对于AES128，它是16字节的完全倍数。否则，该函数将失败。

(enc-aes-128-ecb-unpadded (string->bytes/latin-1 "too short!"))
EVP_CipherFinal_ex: libcrypto error: data not multiple of block length [digital envelope routines:EVP_EncryptFinal_ex:101183626] 

- djf

Answer 2

看起来所有的输入都被填充到下一个块边界。这意味着16字节的输入将被填充到32字节的下一个边界。如果所有的输入都是精确的块大小，那么可以关闭填充。如果输入可能在块的中间结束，则必须保留填充。

如果您将使用CBC模式，则还需要考虑身份验证。如果确实需要，则HMAC可能是最容易入门的选项。

- rossum