如何在Google Sheets中将数字转换为小时

Question

1950分钟为32.5小时。我该如何在Google Sheets中使用公式计算？

我正在记录完成任务所需的分钟数，需要一种将这些数字转换为Google电子表格中的小时数的方法。

我有一列包含按任务分组的分钟数，每个任务占据1行。这一列的总和需要相加，然后转换为小时。

- DigiKev

Answer 1

这里有一个将分钟转换为小时:分钟的函数：

=if( A1 = 0 ; "" ; concatenate( quotient( A1 ; 60 ) ; ":" ;MOD(A1  ; 60) )) 

62 --> 1:2

- PierreLeroux

---

你知道如何在小时钟前方补0吗，例如1:02？ - Szu

使用TEXT函数来格式化分钟数。=如果(A1=0，""，连接(商(A1，60)，":"，TEXT(MOD(A1,60),"00"))) - Larry Silverman

当分钟总数（A1）小于零但大于-60时会发生什么？使用您的公式，如果A1为-30，则公式将输出0:30而不是-0:30（我知道时间不能是负数，但我正在组合一个电子表格来计算可用带薪休假的数量，并且需要知道该数字是否降至0以下）。下一个评论中的已更正公式： - matthew_360

=IF(AND(A1 < 0, A1 > -60), CONCATENATE("-", QUOTIENT(A1 , 60), ":", TEXT(MOD(ABS(A1), 60), "00")), CONCATENATE(QUOTIENT(A1 , 60), ":", TEXT(MOD(ABS(A1), 60), "00"))) - matthew_360

很抱歉频繁发送此消息，但我意识到所有负时间都无法通过此公式正确输出。原因是(-75 mod 60)实际上是45。因此，-75分钟显示为-1:45。 - matthew_360

Answer 2

使用转换函数将数值转换为不同的度量单位

=CONVERT(A1; "mn"; "hr")

文档

- Michal Zmuda

Answer 3

以下是一个将分钟转换为小时:分钟格式的函数：

=CONVERT(A1,"mn","hr")/24       

其中 A1 是您要转换的区域。

- Vasyl

Answer 4

Pierre的回答大部分是正确的。然而，如果分钟数小于0，它并没有正确地输出时间。如果你需要处理负时间量，请使用以下公式：

=CONCATENATE(IF(AND(A1 < 0, A1 > -60), "-", ""), QUOTIENT(A1, 60), ":", TEXT(MOD(ABS(A1), 60), "00"))

- matthew_360

Answer 5

1. 使用函数=SUM(number1,number2,number3,number4,...)将所有数值相加。 例如：=SUM(A1:A200)会将A1、A2、A3......A200中的所有数字相加。
2. 使用函数=DIVIDE(number1,number2) 将总工时（位于带有=SUM函数的字段中）除以60（1小时有60分钟）。 例如：=DIVIDE(A201,60)。如果您将=SUM函数放在A201字段中，则将该字段的结果除以60。

- Johann Behrens

Answer 6

我对它进行了改进：

---

• 123 转换为 2小时3分钟
• 不显示无关紧要的“0”。
  • 当数字可以被60整除时，不显示“0分钟”，例如将120分钟转换为2小时而不是2小时0分钟。
  • 当数字小于60时，不显示“0小时”，例如将40分钟转换为40分钟而不是0小时40分钟。
• 使用时只需用包含分钟数的单元格编号替换A1即可。

---

=IF (A1=0, "", CONCATENATE ( IF(QUOTIENT(A1,60)=0, "", CONCATENATE (QUOTIENT(A1,60),"h ")  ), IF(MOD(A1,60)=0,"",CONCATENATE (TEXT(MOD(A1,60),0),"min"))))

- ItalicsBold

---

对我来说完美运作。 - Kashif Latif

Answer 7

我会使用以下的函数：

=TEXT(<minute>/60/24,"hh:mm")

（包含此公式的单元格不应格式化为时间值） 并且

=time(0,<minute>,0)

（包含此公式的单元格应格式化为时间值，例如hh:mm）

- Shobeira