第一部分 - 为什么你��“正则表达式不起作用”
你的逻辑有误。如果匹配成功,FINDSTR会将ERRORLEVEL设置为0,如果没有匹配,则设置为1。你的正则表达式正在验证所有字符是否“有效”,但是你的条件将匹配视为不正确的输入。
你的IF语句在一侧使用引号,但在另一侧没有使用引号。你必须保持一致,否则它永远无法评估为TRUE。
在批处理脚本中,百分号文字必须加倍。你的正则表达式有一个百分号文字,应该写成%%
。
你在相同的代码块中使用了%ERRORLEVEL%来设置值,这是行不通的,因为当代码块被解析时,值已经被展开了。
最简单的替代方法是使用if errorlevel 1
,如果ERRORLEVEL>=1,则返回true。
另一个选择是在顶部启用延迟扩展,使用SETLOCAL ENABLEDELAYEDEXPANSION
,然后使用if !errorlevel! neq 0
。但这需要对你的正则表达式中带引号的!
文字进行转义,写成^!
,并将^
文字转义为^^
。
我最喜欢的选项是使用&&
和||
条件运算符,而不是IF。
findstr ... >nul && (match found statements) || (no match statements)
在你的情况下,如果没有匹配,你想采取行动,因此只需要||
运算符。
第二部分 - 为什么你的整个概念不是一个好主意
下面是我一段时间前编写的一个简单批处理计算器程序。它处于无限循环状态,请求输入并显示结果,直到你输入退出命令为止。它支持SET /A支持的所有运算符。
它允许你定义和使用变量在你的表达式中。最近一次计算的结果始终存储在名为#
的变量中。
计算器可以将结果显示为十进制、十六进制或二进制。
默认情况下,它只显示最后一次计算的结果。可以指示它在每次计算后也显示所有变量的值。
您可以输入命令而不是数学计算。所有命令都以“\”开头。
\ Quit (退出)
\V 显示或隐藏变量列表
\D 十进制模式 - 结果以十进制显示
\H 十六进制模式 - 结果以十六进制显示
\B 二进制模式 - 结果以二进制显示
\C X 清除变量X
\C * 清除所有变量
\C X* 清除以X开头的所有变量
如果什么都不输入,则会列出所有当前定义的变量。
清除的变量是未定义的。请注意,未定义的变量具有隐含值0。
以下是代码:
@echo off
setlocal enableDelayedExpansion
for /f "delims==" %%v in ('set') do set %%v=
set __skip=#COMSPEC#PATHEXT#PROMPT#__mode#__str#__skip#__clr###__dispVars#
set __mode=Dec
set __dispVars=0
:top
echo:
set __str=
set /p "__str=%__mode%> "
if "!__str!"=="\" exit /b
if "!__str!"=="" call :dispVar # & call :dispVars & goto :top
if /i "!__str:~0,2!"=="\C" call :clearVars &goto :top
if /i "!__str!"=="\H" (set __mode=Hex) ^
else if /i "!__str!"=="\D" (set __mode=Dec) ^
else if /i "!__str!"=="\B" (set __mode=Bin) ^
else if /i "!__str!"=="\V" (set /a "__dispVars=^!__dispVars") ^
else set /a #=(!__str!)
call :dispVar #
if !__dispVars! gtr 0 call :dispVars
goto :top
:clearVars
for /f "delims=,; " %%v in ("!__str:~2!") do (
set __clr=%%v
if "!__clr:~-1!"=="*" (
set __clr=!__clr:~0,-1!
for /f "delims==" %%x in ('set !__clr!') do (
if "!__skip:#%%x#=!"=="!__skip!" set "%%x="
)
) else set "%%v="
)
call :dispVar #
call :dispVars
exit /b
:dispVars
setlocal
for /f "tokens=1,2 delims==" %%v in ('set') do if "!__skip:#%%v#=!"=="!__skip!" call :dispVar %%v
exit /b
:dispVar Var
setlocal
if !__mode!==Hex call :num2hex %1 disp
if !__mode!==Bin call :num2bin %1 disp
if !__mode!==Dec set /a disp=!%~1!
set var=%~1
if "!var:~0,6!"=="!var!" (
set "var=!var! ----------"
set "var=!var:~0,6!"
)
echo %var% = !disp!
exit /b
:num2hex NumVal RtnVar
setlocal enabledelayedexpansion
set hex=
set /a "dec=%~1"
set "map=0123456789ABCDEF"
for /l %%n in (1,1,8) do (
set /a "d=dec&15,dec>>=4"
for %%d in (!d!) do set "hex=!map:~%%d,1!!hex!"
)
(endlocal & rem return values
set %~2=%hex%
exit /b
)
exit /b
:num2bin NumVal RtnVar
setlocal enabledelayedexpansion
set bin=
set /a "dec=%~1"
for /l %%n in (1,1,32) do (
set /a "d=dec&1,dec>>=1"
set "bin=!d!!bin!"
)
(endlocal & rem return values
set %~2=%bin%
exit /b
)
exit /b
以下是一次短期会话的结果:
D:\test>calculate.bat
Dec> 2*3
# ---- = 6
Dec> a=#+1
# ---- = 7
Dec>
# ---- = 7
a ---- = 7
Dec> b=(a+=5)*2
# ---- = 24
Dec> \v
# ---- = 24
a ---- = 12
b ---- = 24
Dec> c=b/3
# ---- = 8
a ---- = 12
b ---- = 24
c ---- = 8
Dec> \h
# ---- = 00000008
a ---- = 0000000C
b ---- = 00000018
c ---- = 00000008
Hex> \b
# ---- = 00000000000000000000000000001000
a ---- = 00000000000000000000000000001100
b ---- = 00000000000000000000000000011000
c ---- = 00000000000000000000000000001000
Bin> \
D:\test>
for /f“delims =”%%a在('powershell%*')中执行echo %%a
- SachaDee