尝试使用cmake交叉编译qt应用程序时出现链接问题

Question

我目前正在将我的Qt应用程序的构建系统从qmake切换到cmake。在尝试使用MinGW（静态Qt构建）交叉编译Windows时，我遇到了一个无法解释的奇怪问题：

CMakeLists.txt：

project(noble)

cmake_minimum_required(VERSION 2.8.5)

set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_SOURCE_DIR}/cmake/Modules/")

find_package(Boost COMPONENTS program_options thread REQUIRED)
find_package(Qt4 REQUIRED QtCore QtGui)
find_package(BLAS REQUIRED)
find_package(LAPACK REQUIRED)
find_package(Armadillo)
find_package(Qwt6 REQUIRED)

set(EXECUTABLE_OUTPUT_PATH ${PROJECT_BINARY_DIR})
set(LIBRARY_OUTPUT_PATH ${PROJECT_BINARY_DIR})

include(${QT_USE_FILE})

set(LIBRARIES
    ${Qwt6_Qt4_LIBRARY}
    ${QT_QTCORE_LIBRARY}
    ${QT_QTGUI_LIBRARY}
    ${Boost_LIBRARIES}
    ${BLAS_LIBRARIES}
    ${LAPACK_LIBRARIES}
    )

set(DEFINITIONS
    ${QT_DEFINITIONS}
    ${BLAS_LINKER_FLAGS}
    ${LAPACK_LINKER_FLAGS}
    -DBOOST_THREAD_USE_LIB
    )

add_subdirectory(src)
add_subdirectory(plugins)

src/CMakeLists.txt:

set(CMAKE_INCLUDE_CURRENT_DIR ON)

set(noble_SOURCES
    #file names...
    )

set(noble_HEADERS
    #file names...
    )

set(noble_FORMS
    #file names...
    )

QT4_WRAP_UI(noble_FORMS_HEADERS ${noble_FORMS})
QT4_WRAP_CPP(noble_HEADERS_MOC ${noble_HEADERS})

include_directories(
    ${Boost_INCLUDE_DIRS}
    ${ARMADILLO_INCLUDE_DIRS}
    ${Qwt6_INCLUDE_DIR}
    )

add_definitions(${DEFINITIONS})

add_executable(noble
    ${noble_SOURCES}
    ${noble_HEADERS_MOC}
    ${noble_FORMS_HEADERS}
    )

target_link_libraries(noble 
    ${LIBRARIES}
    -lQtGui -lQtCore
    -ljpeg -lpng -ltiff -lmng -lz -limm32 -llcms -lwinmm
    -fopenmp
    )

我现在试图摆脱手动设置编译器标志的问题。如果我省略-lQtGui -lQtCore，就会得到一堆未定义的引用，比如：

/home/mjung/Programme/mingw-cross-env-2.21/usr/lib/gcc/i686-pc-mingw32/4.6.0/../../../../i686-pc-mingw32/lib/libQtGui.a(qapplication.o):qapplication.cpp:(.text+0x2340): undefined reference to `QBasicTimer::stop()'

如果保留这些标志，程序可以正常编译。现在奇怪的是：cmake的g++调用带有-lQtGui -lQtCore标志。

/home/mjung/Programme/mingw-cross-env-2.21/usr/bin/i686-pc-mingw32-g++
-Wl,--whole-archive
CMakeFiles/noble.dir/objects.a
-Wl,--no-whole-archive
-o ../noble.exe
-Wl,--out-implib,../libnoble.dll.a
-Wl,--major-image-version,0,--minor-image-version,0
/home/mjung/Programme/windows_builds/usr/lib/libqwt.a
-Wl,-Bstatic
-lQtCore -lQtGui
-lboost_program_options-mt
-lboost_thread-mt
-Wl,-Bdynamic
/home/mjung/Programme/windows_builds/usr/lib/libblas.a
/home/mjung/Programme/windows_builds/usr/lib/liblapack.a
/home/mjung/Programme/windows_builds/usr/lib/libblas.a
-lQtGui -lQtCore
-ljpeg -lpng -ltiff -lmng -lz -limm32 -llcms -lwinmm
-fopenmp
/home/mjung/Programme/windows_builds/usr/lib/liblapack.a
-lQtGui -lQtCore
-ljpeg -lpng -ltiff -lmng -lz -limm32 -llcms -lwinmm
-lkernel32 -luser32 -lgdi32 -lwinspool -lshell32 -lole32 -loleaut32 -luuid -lcomdlg32 -ladvapi32

使用cmake的g++调用，不需要 -lQtGui -lQtCore 标志：

/home/mjung/Programme/mingw-cross-env-2.21/usr/bin/i686-pc-mingw32-g++
-Wl,--whole-archive
CMakeFiles/noble.dir/objects.a
-Wl,--no-whole-archive
-o ../noble.exe
-Wl,--out-implib,../libnoble.dll.a
-Wl,--major-image-version,0,--minor-image-version,0
/home/mjung/Programme/windows_builds/usr/lib/libqwt.a
-Wl,-Bstatic
-lQtCore -lQtGui
-lboost_program_options-mt
-lboost_thread-mt
-Wl,-Bdynamic
/home/mjung/Programme/windows_builds/usr/lib/libblas.a
/home/mjung/Programme/windows_builds/usr/lib/liblapack.a
/home/mjung/Programme/windows_builds/usr/lib/libblas.a

-ljpeg -lpng -ltiff -lmng -lz -limm32 -llcms -lwinmm
-fopenmp
/home/mjung/Programme/windows_builds/usr/lib/liblapack.a

-ljpeg -lpng -ltiff -lmng -lz -limm32 -llcms -lwinmm
-lkernel32 -luser32 -lgdi32 -lwinspool -lshell32 -lole32 -loleaut32 -luuid -lcomdlg32 -ladvapi32

即使我没有手动设置编译器标志，FindQt4.cmake脚本仍会自动设置它们。但这似乎还不够。我绝对不明白，如果标志只被自动设置一次或者被我手动添加了三次，为什么会有区别。这是否与标志的顺序有关呢？

你有任何想法吗？任何帮助都将不胜感激。

---

更新： 没事了...

我只是改变了库的顺序从...

set(LIBRARIES
    ${Qwt6_Qt4_LIBRARY}
    ${QT_QTCORE_LIBRARY}
    ${QT_QTGUI_LIBRARY}
    ${Boost_LIBRARIES}
    ${BLAS_LIBRARIES}
    ${LAPACK_LIBRARIES}
    )

为了

set(LIBRARIES
    ${Qwt6_Qt4_LIBRARY}
    ${QT_QTGUI_LIBRARY}
    ${QT_QTCORE_LIBRARY}
    ${Boost_LIBRARIES}
    ${BLAS_LIBRARIES}
    ${LAPACK_LIBRARIES}
    )

我不太理解为什么要这样做，但现在它可以工作了...

附注：如果我的声望足够，我本可以把这个作为答案发布的。

- AbuBakr

---

http://meta.stackexchange.com/questions/86185/minimum-reputation-for-answering-your-own-question-should-be-higher-than-what-is - BЈовић

更改库的顺序可能意味着QT_QTGUI_LIBRARY依赖于QT_QTCORE_LIBRARY。 - A. K.

Answer 1

许多架构在链接时只对库列表进行一次遍历。也就是说，如果您有一个未定义的符号，则后面的库必须定义它。链接器不会“向后”搜索库列表以解析符号。

在这种情况下，QtGui 依赖于 QtCore。因此，在链接列表中 QtGui 后面必须出现 QtCore。

最简单的方法是使用 ${QT_LIBRARIES} cmake 变量，当您执行 FIND_PACKAGE(Qt4...) 时，它会被自动定义。它按正确的顺序包含了所有相关的 Qt 库。 FindQt4 CMake 文档

- mtdarland