如何在VBA中获取列名？

Question

我创建了一个模块，通过存储过程从SQL数据库中读取数据并获取所有所需数据，但我需要所有列名/标头。 我不能硬编码名称，因为我正在将数据行转换为存储过程中的列。

下面是我编写的代码：

ConnStr = "PROVIDER=SQLOLEDB.1;"
ConnStr = ConnStr & "DATA SOURCE=" & dataSrc & "; INITIAL CATALOG=" & iCatalog & "; "
ConnStr = ConnStr & "User ID = " & dbUserId & "; Password = " & dbPassword

On Error GoTo ErrHandler

DBConn.Open ConnStr

' Create a recordset object.
Dim rsCounter As ADODB.Recordset
Set rsCounter = New ADODB.Recordset
Dim startDate As String, endDate As String, query As String

query = "Exec ReadCntrs 0, '12/01/2011', '12/30/2011'"

With rsCounter
    ' Assign the Connection object.
    .ActiveConnection = DBConn

    .Open query
    ' Copy the records into cell A1 on Sheet1.
    Sheet1.Range("A1").CopyFromRecordset rsCounter

    ' Tidy up
    .Close
End With

DBConn.Close
Set rsCounter = Nothing
Set DBConn = Nothing

ExitHere:
    On Error Resume Next
    DBConn.Close: Set DBConn = Nothing
    Err.Clear
    Exit Sub

ErrHandler:
    MsgBox Err.Number & Err.Description, vbExclamation
    Resume ExitHere

End Sub

- Safran Ali

Answer 1

With rsCounter
    ' Assign the Connection object.
    .ActiveConnection = DBConn

    .Open query

    ' Write the column names into cell A1 on Sheet1.
    Dim counter As Long
    For counter = 0 To rsCounter.Fields.Count - 1
      Sheet1.Range("A1").Offset(, counter).Value = rsCounter.Fields(counter).Name
    Next

    ' Copy the records into cell A2 on Sheet1.
    Sheet1.Range("A2").CopyFromRecordset rsCounter

    ' Tidy up
    .Close
End With

- onedaywhen

Answer 2

rsCounter.Fields(i).Name表示访问字段名称，其中i是代表字段编号的整数。

编辑 - 此外，要获取字段总数，您将使用rsCounter.Fields.Count。

- transistor1