创建自定义组件样式的正确方法

Question

我有一个带有自己样式文件的组件，如何才能在不修改默认设置的情况下将其与 Delphi 提供的已定义样式合并？

我可以将默认样式嵌入到我的组件中，该嵌入样式是否可以继承其父控件的大部分样式？

我感觉我缺少一个描述困难的链接。 我的应用程序具有 TStyleBook，默认情况下加载“dark.style”。 我的组件有自己的“MyComponent.style”文件。 TStyleBook 可以加载“dark.style”或“MyComponent.style”，但不能同时加载两个样式。 如果每次在应用程序中使用组件时都需要加载单独的样式文件，这似乎不是很合适。它会使组件的可移植性受到影响。

我可以编辑自己的“MyDark.style”并将MyComponent添加到其中，但这也不太合适，因为这会出现与 Embarcadero 所做更改保持同步的问题。

希望我已经清楚地解释了这个问题。

- Martin

Answer 1

感谢Ray Konopka在CodeRage上的精彩演讲，让我找到了回答这些问题的正确方法。

问题1：我能将默认样式嵌入组件中吗？

是的，您可以将要与组件一起分发的默认样式嵌入到RT_RCDATA类型的资源中。然后只需将该资源包含到源代码中即可：

{$R *.res}

注意：如果您先在布局编辑器中创建了外部对象（TLayout），则需要将其从资源中移除。然后重写GetStyleObject方法以从资源中加载样式。

function TLFButton.GetStyleObject: TControl;
var
  S: TResourceStream;
  obj: TLayout;
const
  Style = 'LFButtonStyle';
begin
  result := inherited GetStyleObject;
  if FStyleLookup = 'cornerbuttonstyle' then
  begin
    if FindResource(HInstance, PChar(Style), RT_RCDATA) <> 0 then
    begin
      S := TResourceStream.Create(HInstance, Style, RT_RCDATA);
      try
        obj := TLayout(TStyleManager.LoadFromResource(HInstance, Style, RT_RCDATA));
        //obj := TLayout( CreateObjectFromStream(nil, S) ); << XE2 version
        Result.AddObject(obj);
        Exit;
      finally
        S.Free;
      end;
    end;
  end;
end;

问题2：如何将其与默认样式合并。

在我的情况下，我的组件的基础是TCornerButton。我修剪了我的.style文件，使它只包含我想要的额外代码。在这种情况下，是一个小三角形来指示下拉按钮和一条线来分割按钮：

object TLayout
  Align = alRight
  Position.Point = '(76,0)'
  Locked = True
  Width = 15.000000000000000000
  Height = 24.000000000000000000
  object TPath
    StyleName = 'dropdownbutton'
    Align = alCenter
    Position.Point = '(4,9)'
    Width = 8.000000000000000000
    Height = 5.000000000000000000
    HitTest = False
    Fill.Color = claBlack
    Stroke.Kind = bkNone
    Data.Path = {
      04000000000000000000000000000000010000000000803F0000000001000000
      0000003F0000803F030000000000000000000000}
  end
  object TLine
    StyleName = 'dropdownsplit'
    Align = alLeft
    Width = 1.000000000000000000
    Height = 24.000000000000000000
    HitTest = False
    LineType = ltLeft
  end
end

我以完全相同的方式将其放入资源。

在我的构造函数中，我设置了StyleLookup为“cornerbuttonstyle”

constructor TLFButton.Create(AOwner: TComponent);
begin
  FStyleLookup := 'cornerbuttonstyle';
  FDropDownButton := false;
  inherited;
end;

我随后更改了GetStyleObject，以便它加载新内容并将其添加到现有样式中。

function TLFButton.GetStyleObject: TControl;
var
  S: TResourceStream;
  obj: TLayout;
const
  Style = 'LFButtonStyle';
begin
  result := inherited GetStyleObject;
  if FStyleLookup = 'cornerbuttonstyle' then
  begin
    if FindRCData(HInstance, Style) then
    begin
      S := TResourceStream.Create(HInstance, Style, RT_RCDATA);
      try
        obj := TLayout( CreateObjectFromStream(nil, S) );
        Result.AddObject(obj);
        Exit;
      finally
        S.Free;
      end;
    end;
  end;
end;

我希望这能帮助到其他人。我发现在这方面获得信息真是太难了。

马丁

- Martin

---

非常有帮助。谢谢！ - Nix

Answer 2

用法：MergeStyle('MyComponent.Style', StyleBook1);

procedure MergeStyle(const aFilename: string; aStyleBook: TStyleBook);
var
  sb: TStyleBook;
  I: Integer;
begin
  sb := TStyleBook.Create(nil);
  try
    sb.FileName := aFilename;

    for I := 0 to sb.Root.ChildrenCount - 1 do
      // Prevent duplicates
      if aStyleBook.Root.FindStyleResource(sb.Root.Children[I].StyleName) = nil then
        aStyleBook.Root.AddObject(sb.Root.Children[I].Clone(aStyleBook.Root));

    aStyleBook.UpdateScenes;
  finally
    sb.Free;
  end;
end;

- Arjen van der Spek