在XSLT中获取最后一个字符出现后的子字符串

Question

我有一个在XML文件中的字符串，看起来像这样:

M:Namespace.Class.Method(Something a, Something b)

句点（.）的数量是任意的，这意味着它可以只有2个，就像这个例子一样，但也可以更多。

我想使用XSLT从最后一个“.”字符得到这个字符串的子字符串，这样我就只剩下:

Method(Something a, Something b)

我无法使用标准的substring/substring-after函数实现此目标。

有没有简单的方法可以做到这一点？

- lysergic-acid

---

这是一个重复的问题，类似于https://dev59.com/lkXRa4cB1Zd3GeqPoAHU？ - Marc Stober

Answer 1

在XSLT 1.0中，您需要使用递归模板，例如：

  <xsl:template name="substring-after-last">
    <xsl:param name="string" />
    <xsl:param name="delimiter" />
    <xsl:choose>
      <xsl:when test="contains($string, $delimiter)">
        <xsl:call-template name="substring-after-last">
          <xsl:with-param name="string"
            select="substring-after($string, $delimiter)" />
          <xsl:with-param name="delimiter" select="$delimiter" />
        </xsl:call-template>
      </xsl:when>
      <xsl:otherwise><xsl:value-of 
                  select="$string" /></xsl:otherwise>
    </xsl:choose>
  </xsl:template>

并像这样调用它：

<xsl:call-template name="substring-after-last">
  <xsl:with-param name="string" select="'M:Namespace.Class.Method(Something a, Something b)'" />
  <xsl:with-param name="delimiter" select="'.'" />
</xsl:call-template>

在XSLT 2.0中，您可以使用tokenize()函数，并简单地选择序列中的最后一项：

tokenize('M:Namespace.Class.Method(Something a, Something b)','\.')[last()]

- Mads Hansen

---

谢谢。我怎么知道我正在使用哪个版本的XSLT？我是从C#代码中调用所有这些内容的（使用XslCompiledTransform类）。 - lysergic-acid

不幸的是，.NET本身不支持XSLT 2.0。除非你有Saxon.net、XQSharp或其他2.0引擎，否则你需要使用1.0解决方案。 - Mads Hansen

Answer 2

这里是一个更高效的解决方案 O(N) vs. O(N^2)，适用于已接受的答案:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:template match="text()" name="skipAfterDots">
  <xsl:param name="pTotalString" select="."/>
  <xsl:param name="pTotalLength" select="string-length(.)"/>
  <xsl:param name="pPosition" select="1"/>
  <xsl:param name="pLastFound" select="-1"/>

  <xsl:choose>
    <xsl:when test="$pPosition > $pTotalLength">
      <xsl:value-of select="substring($pTotalString, $pLastFound + 1)"/>
    </xsl:when>
    <xsl:otherwise>
      <xsl:variable name="vIsDot" select=
       "substring($pTotalString, $pPosition, 1) = '.'"/>

      <xsl:call-template name="skipAfterDots">
        <xsl:with-param name="pTotalString" select="$pTotalString"/>
        <xsl:with-param name="pTotalLength" select="$pTotalLength"/>
        <xsl:with-param name="pLastFound" select=
        "$pLastFound * not($vIsDot) + $pPosition * $vIsDot"/>
        <xsl:with-param name="pPosition" select="$pPosition+1"/>
      </xsl:call-template>
    </xsl:otherwise>
  </xsl:choose>
 </xsl:template>
</xsl:stylesheet>

当这个转换应用于以下XML文档时：

<t>M:Namespace.Class.Method(Something a, Something b)</t>

得到了想要的、正确的结果：

Method(Something a, Something b)

解释:

这个解决方案没有包含任何对substring-after()函数的调用。相反，每一步只与字符串的一个字符进行相等性比较。因为最多只有N个字符，这是O(N) -- 线性复杂度。

相反地，被接受的答案在每一步都调用了substring-after()函数。在最坏的情况下可能会有N个点，因此这将是O(N^N) -- 二次复杂度。

注意: 我们做出合理的假设，在这两种解决方案中，定位字符串的第k个字符是O(1)的。

- Dimitre Novatchev

---

虽然这是一条旧评论，但我觉得有必要发表评论：被接受的解决方案也是O(n)。每次调用（一个合理实现的）contains()都会查找前导字符，直到找到一个点。在找到点之后，它已经查看过的每个字符都将被丢弃。因此，它最多只会查看每个字符一次。 - nemetroid

@nemetroid：我指的是<xsl:with-param name="string" select="substring-after($string, $delimiter)"/>。如果字符串中有m个点，字符串长度为n，那么这个算法的时间复杂度是O(m*n)。 - Dimitre Novatchev

没错，你说得对。我没有考虑到 substring-after 需要查找整个（剩余的）字符串。 - nemetroid

@nemetroid：我的解释有误导（提到了contains()而不是substring-after()）。现已修正。 - Dimitre Novatchev

Answer 3

如果您知道字符串中恰好有两个点，则可以尝试以下操作：

<xsl:value-of select="substring-after(substring-after($str, '.'), '.')" /> 

- Igor Korkhov

---

如果字符串中有任意数量的“.”，这种方法将无法工作。例如：Component.Something.Else.Class.Method( ... )。 - lysergic-acid