理解uboot.lds

Question

我正在尝试了解在基于PowerPC MPC8313处理器的板上如何移植uboot。在此过程中，我遇到了名为uboot.lds的链接器脚本文件。

我需要理解这个文件。我的意思是要理解所提到的内容的重要性以及在uboot包中实际地址的定义位置。

例如，在SECTIONS中，我可以在哪里找到以下信息的重要性：

/* Read-only sections, merged into text segment: */
. = + SIZEOF_HEADERS;
.interp : { *(.interp) }
.hash          : { *(.hash)  }
.dynsym        : { *(.dynsym)  }
.dynstr        : { *(.dynstr)  }
.rel.text      : { *(.rel.text)  }
.rela.text     : { *(.rela.text)  }
.rel.data      : { *(.rel.data)  }
.rela.data     : { *(.rela.data)  }
.rel.rodata    : { *(.rel.rodata)  }
.rela.rodata   : { *(.rela.rodata)  }
.rel.got       : { *(.rel.got)  }
.rela.got      : { *(.rela.got)  }
.rel.ctors     : { *(.rel.ctors) }
.rela.ctors    : { *(.rela.ctors) }
.rel.dtors     : { *(.rel.dtors) }
.rela.dtors    : { *(.rela.dtors) }
.rel.bss       : { *(.rel.bss)  }
.rela.bss      : { *(.rela.bss)  }
.rel.plt       : { *(.rel.plt)  }
.rela.plt      : { *(.rela.plt)  }
.init          : { *(.init) }
.plt : { *(.plt) }
.text      :
{
  cpu/mpc83xx/start.o (.text)
  *(.text)
  *(.fixup)
  *(.got1)
  . = ALIGN(16);
  *(.rodata)
  *(.rodata1)
  *(.rodata.str1.4)
  *(.eh_frame)
}
.fini      : { *(.fini)    } =0
.ctors     : { *(.ctors)   }
.dtors     : { *(.dtors)   }

/* Read-write section, merged into data segment: */
. = (. + 0x0FFF) & 0xFFFFF000;
_erotext = .;
PROVIDE (erotext = .);
.reloc   :
{
  *(.got)
  _GOT2_TABLE_ = .;
  *(.got2)
  _FIXUP_TABLE_ = .;
  *(.fixup)
}
__got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
__fixup_entries = (. - _FIXUP_TABLE_) >> 2;

.data    :
{
  *(.data)
  *(.data1)
  *(.sdata)
  *(.sdata2)
  *(.dynamic)
  CONSTRUCTORS
}
_edata  =  .;
PROVIDE (edata = .);

. = .;
__u_boot_cmd_start = .;
.u_boot_cmd : { *(.u_boot_cmd) }
__u_boot_cmd_end = .;


. = .;
__start___ex_table = .;
__ex_table : { *(__ex_table) }
__stop___ex_table = .;

. = ALIGN(4096);
__init_begin = .;
.text.init : { *(.text.init) }
.data.init : { *(.data.init) }
. = ALIGN(4096);
__init_end = .;

__bss_start = .;
.bss       :
{
 *(.sbss) *(.scommon)
 *(.dynbss)
 *(.bss)
 *(COMMON)
}
_end = . ;
PROVIDE (end = .);
}

在哪里查找这些信息，如何识别需要在lds文件中进行的更改？

请确认或至少提供一些指针以阅读该信息，谢谢。

敬礼， Vijay

- Vijay

Answer 1

在移植u-boot时，可以使用cpu目录下的u-boot.lds文件而不是board目录下的文件。换句话说，可能没有必要移植此文件。但如果需要，以下是概述。

您可以在LD文档中找到大量信息。

通常情况下，LD脚本允许您覆盖GCC工具链运行时将东西放置在内存中的默认位置。编译应用程序时，源代码将被处理并创建包含机器码的目标代码文件。在链接期间，各个目标文件将合并为一个文件（例如ELF可执行文件），并在文件上放置一个标题，告诉操作系统每个目标文件应放置在内存中的位置，以便在需要时找到（全局变量、函数调用等）。

如果要将代码放置在无法预测编译器/链接器的特定位置，则需要自定义脚本。有很多原因要这样做，如我将尝试列出的内容。

1. 如果RAM稀疏，常量可能放置在只读内存中
2. 如果可用，经常访问的内存可能需要放置在更快的RAM中
3. 某些数据可能需要对齐于特定边界（例如64K）
4. 某些代码（.TEXT）应该放置在复位向量中，以便在复位时执行
5. 中断服务程序(ISR)代码向量也是如此

除此之外，这也可以成为在链接时方便获取内存指针的一种方法。例如，__init_begin被定义为一个符号，其具有作为*.text.init编译的任何代码的内存地址。现在，您可以通过将程序计数器设置为__init_begin的值来调用该内存，而无需配置完整的C环境。

编译器文档+u-boot Makefiles应解释编译器何时生成每种类型的对象文件（例如.txt、.data、.bss、.fini、.ctors等）。

- CodePoet