从外部关闭模态窗体并打开新的模态窗体

Question

从外部关闭模态窗体并打开新的模态窗体

4

在我的主表单中，我有一个按钮，可以打开一个模态Form2（该表单可能会打开其他模态形式）。在打开Form2之前，我设置了一个计时器，该计时器将以编程方式关闭所有活动的模态表单（Form2.Close），并打开一个新的模态Form3。

问题是，当以模态方式打开Form3时，Form2仍然保持（可见），只有当我通过单击X关闭Form3时，Form2才会关闭。

为了重现添加3个表单到项目中添加一个TButton，并在Form1（主表单）上放置一个TTimer。

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Timer1: TTimer;
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
  private
  public
  end;

var
  Form1: TForm1;

implementation

uses Unit2, Unit3;

{$R *.DFM}

procedure TForm1.FormCreate(Sender: TObject);
begin
  Timer1.Enabled := False;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  Timer1.Enabled := True;
  with TForm2.Create(Application) do
  try
    ShowModal;
  finally
    Free;
  end;
end;

procedure CloseActiveModalForms;
var
  I: Integer;
  F: TCustomForm;
  L: TList; // list of modal forms
begin
  L := TList.Create;
  try
    for I := 0 to Screen.CustomFormCount - 1 do
    begin
      F := Screen.CustomForms[I];
      if (fsModal in F.FormState) then
        L.Add(F);
    end;
    for I := 0 to L.Count - 1 do
      TCustomForm(L.Items[I]).Close; // this sets ModalResult := mrCancel
  finally
    L.Free;
  end;
end;

procedure TForm1.Timer1Timer(Sender: TObject);
begin
  Timer1.Enabled := False;
  CloseActiveModalForms; // this should close TForm2 but it does not.

  with TForm3.Create(Application) do // create new Modal TForm3
  try
    ShowModal;
  finally
    Free;
  end; 
end;

end.

为什么Form2没有关闭？为什么在我调用CloseActiveModalForms后，Form2的模态循环没有退出？

- zig

1个回答

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- Disillusioned · Accepted Answer

您的调用栈如下所示：

1 Form1.Button1Click
2 Form2.ShowModal //Local message processing loop until form closes
3 Form1.Timer1Timer //Here you attempt to close the form
                    //but it doesn't actually until ShowModal exits
4 Form3.ShowModal // Another message loop that doesn't return until form closes

基本上，只有在Form3关闭后才能完成Form2的关闭。请注意，ShowModal是一个阻塞调用，用于显示一个窗体。如果你只是展示Form3（即不使用ShowModal），该调用不会阻塞，你将看到随着调用堆栈的解除，Form2可以关闭。

你应该通过延迟展示Form3来解决这个问题，直到Form2关闭。OnFormDestroyEvent应该足够（不幸的是我无法测试它）。

procedure TForm1.ShowForm3(Sender: TObject);
var
  LForm: TForm;
begin
  LForm := TForm3.Create(Application); //as you created it, but nil owner should suffice
  try
    LForm.ShowModal;
  finally
    LForm.Free;
  end; 
end;

procedure TForm1.Timer1Timer(Sender: TObject);
begin
  Timer1.Enabled := False;
  //You will need to figure out how you reference the Form2 instance.
  Form2.OnFormDestroy := ShowForm3;
  CloseActiveModalForms;
  //Form2 will close after you backtrack up the call-stack.
  //When it's destroyed, your event handler will create and show a TForm3 instance.
end;

请注意上述内容只是展示了该概念。根据您的最终目标，您需要设计更加稳健的方法。

然而，我建议过度使用模态表单通常在用户体验方面被认为不友好。