如何为窗体标题栏、系统菜单图标和最小化、最大化和关闭按钮设置自定义光标？

Question

有没有适用于在窗体标题栏、系统菜单图标以及最小化、最大化和关闭按钮上设置自定义光标的Windows API？

我编写了一个函数，用于为给定的控件加载和设置光标：

type

 TFrm_Main = class(TForm)
   ....
 private
  procedure SetCursor_For(AControl: TControl; ACursor_FileName: string;
    Const ACurIndex: Integer);
 ...
 end;
 const
   crOpenCursor = 1;
   crRotateCursor = 2;
   crCursor_Water = 3;

 var
   Frm_Main: TFrm_Main;
 ...
 procedure TFrm_Main.SetCursor_For(AControl: TControl; ACursor_FileName: 
  string; const ACurIndex: Integer);
 begin
   Screen.Cursors[ACurIndex] := Loadcursorfromfile(PWideChar(ACursor_FileName));
   AControl.Cursor := ACurIndex;
 end;

我正在使用以下方式来处理表单：

SetCursor_For(Frm_Main, 'Cursors\Cursor_Rotate.ani', crRotateCursor);

但是我缺少一种设置特定表单部分光标的方法，比如表单标题栏、系统菜单图标以及最小化、最大化和关闭按钮。是否有一种方法可以为这些表单部分设置光标？

- Bravesaw

---

从您的公共数据中，我可以看到您从未对任何答案进行过投票，并且您也从未接受过任何答案来回答您的问题。也许您不知道我的意思，所以请参阅someone-answers。 - Tom Brunberg

Answer 1

处理 WM_SETCURSOR 消息，并测试消息参数的 HitTest 字段是否为以下一种命中测试代码值之一，然后使用 SetCursor 函数设置光标并将返回值 True 赋给消息 Result（Windows API 宏 TRUE 和 FALSE 恰好匹配 Delphi 的 Boolean 类型值，因此您只能在那里进行类型转换）：

• HTCAPTION - 标题栏
• HTSYSMENU - 系统菜单图标
• HTMINBUTTON - 最小化按钮
• HTMAXBUTTON - 最大化按钮
• HTCLOSE - 关闭按钮

例如：

type
  TForm1 = class(TForm)
  private
    procedure WMSetCursor(var Msg: TWMSetCursor); message WM_SETCURSOR;
  end;

implementation

procedure TForm1.WMSetCursor(var Msg: TWMSetCursor);
begin
  case Msg.HitTest of
    HTCAPTION:
    begin
      Msg.Result := LRESULT(True);
      Winapi.Windows.SetCursor(Screen.Cursors[crHandPoint]);
    end;
    HTSYSMENU:
    begin
      Msg.Result := LRESULT(True);
      Winapi.Windows.SetCursor(Screen.Cursors[crHelp]);
    end;
    HTMINBUTTON:
    begin
      Msg.Result := LRESULT(True);
      Winapi.Windows.SetCursor(Screen.Cursors[crUpArrow]);
    end;
    HTMAXBUTTON:
    begin
      Msg.Result := LRESULT(True);
      Winapi.Windows.SetCursor(Screen.Cursors[crSizeAll]);
    end;
    HTCLOSE:
    begin
      Msg.Result := LRESULT(True);
      Winapi.Windows.SetCursor(Screen.Cursors[crNo]);
    end;
  else
    inherited;
  end;
end;

- Victoria