logo标签列表

Visual Studio 窗口管理器

.netvisual-studioadd-in
3

是否有适用于Visual Studio 2008的窗口管理器，类似于这个。我真的很喜欢它，这是我在Visual Studio 2005中使用的全部内容，并在某个地方看到它应该可以在Visual Studio 2008中工作，但实际上却不行。我已经在许多安装了Visual Studio 2008的电脑上尝试过，但它无法记住任何设置。我真的很喜欢能够快速轻松地更改窗口布局。现在我只能手动导入和导出设置，但这不是一个即时的过程。

我需要做什么才能让它工作？

4个回答
2
1
以下的宏可能能给你带来帮助。我曾经针对你提到的WindowManager进行重新编译，使其能够在Visual Studio 2008上正常运行，但我发现它仍有点不稳定。此外，我不使用WindowManager中的“自动应用布局”功能，所以这些宏对我来说非常适用，可以方便地在双屏工作和只使用笔记本电脑工作之间进行切换。
Sub DualMonitorConfiguration_Save()
    SaveWindowConfiguration("Dual Monitor Layout")
End Sub

Sub DualMonitorConfiguration_Load()
    LoadWindowConfiguration("Dual Monitor Layout")
End Sub

Sub LaptopOnlyConfiguration_Save()
    SaveWindowConfiguration("Laptop Only Layout")
End Sub

Sub LaptopOnlyConfiguration_Load()
    LoadWindowConfiguration("Laptop Only Layout")
End Sub

Private Sub SaveWindowConfiguration(ByVal configName As String)
    Dim selectedConfig As WindowConfiguration
    selectedConfig = FindWindowConfiguration(configName)
    If selectedConfig Is Nothing Then
        selectedConfig = DTE.WindowConfigurations.Add(configName)
    End If

    selectedConfig.Update()
    DTE.StatusBar.Text = "Window configuration saved: " & configName
End Sub

Sub LoadWindowConfiguration(ByVal configName As String)
    Dim selectedConfig As WindowConfiguration
    selectedConfig = FindWindowConfiguration(configName)
    If selectedConfig Is Nothing Then
        MsgBox("Window Configuration """ & configName & """ not found.")
    Else
        selectedConfig.Apply()
        DTE.StatusBar.Text = "Window configuration applied: " & configName
    End If
End Sub

Private Function FindWindowConfiguration(ByVal name As String) As WindowConfiguration
    Dim selectedLayout As WindowConfiguration

    For Each config As WindowConfiguration In DTE.WindowConfigurations
        If config.Name = name Then
            Return config
        End If
    Next

    Return Nothing
End Function
你好，看起来你只调用了保存方法？ - Lasse V. Karlsen
1

你应该在 CodePlex 上联系 RW。他声称已经将其在 Visual Studio 2008 中运行成功。查看this item。

1

您的问题已经在您提问的同一页上得到了回答 :-)

仅供记录：

为了让它在2008年工作，需要向WindowManager2005.AddIn文件中添加一个新的 HostApplication元素。该文件通常位于“%APPDATA%\ Microsoft \ MSEnvShared \ Addins”中。 更改新元素中的版本为9.0（VS 2008），它应该可以在2008和2005中工作。

<HostApplication>
  <Name>Microsoft Visual Studio</Name>
  <Version>9.0</Version>
</HostApplication>
网页内容由stack overflow 提供, 点击上面的
可以查看英文原文，
原文链接