一个带有'varargs'的函数如何检索堆栈的内容？

Question

一个带有'varargs'的函数如何检索堆栈的内容？

20

通常，在Delphi中，声明具有可变数量参数的函数需要使用“array of const”方法。但是，为了与用C编写的代码兼容，可以在函数声明中添加一个很少人知道的“varargs”指令（我在阅读Rudy优秀的“Pitfalls of convering”文档时学到了这一点）。

例如，可以在C中声明一个函数，如下所示：

void printf(const char *fmt, ...)

在Delphi中，这将变成：

procedure printf(const fmt: PChar); varargs;

我的问题是：当使用“varargs”指令定义方法时，如何获取堆栈的内容？

我希望能够找到一些工具来实现这一点，比如Dephi翻译的va_start()、va_arg()和va_end()函数，但我无法在任何地方找到这些工具。

请帮忙！

附注：请不要偏离关于“为什么”或“const数组”替代方案的讨论——我需要这个来编写Xbox游戏内部函数的类C补丁（有关详细信息，请参见sourceforge上的Delphi Xbox模拟器项目“Dxbx”）。

- PatrickvL

3个回答

2

我发现了this（来自我们认识的一个家伙：））

为了正确地编写这些内容，你需要使用 Delphi 的内置汇编器 BASM，并在汇编语言中编写调用序列。希望你已经有了一个很好的想法，知道该做什么。如果你遇到困难，也许在 .basm 组中发帖子会有所帮助。

- Ulrich Gerhardt

0

Delphi不允许您实现可变参数例程。它仅适用于导入使用此函数的外部cdecl函数。

由于varargs基于cdecl调用约定，因此您基本上需要在Delphi中自己重新实现它，使用汇编和/或各种指针操作。

- Michael Madsen

不，只有在调用者将零作为最后一个参数传递时，参数列表才以零结尾。您引用的页面也是这么说的。printf函数不需要有零来终止列表，因为它可以根据格式字符串计算出有多少个参数。 - Rob Kennedy

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- Barry Kelly · Accepted Answer

好的，我看到你问题中的说明是需要在Delphi中实现C导入。在这种情况下，您需要自己实现varargs。

所需的基本知识是关于x86上的C调用约定：栈向下增长，C从右到左推送参数。因此，在最后一个声明的参数的大小被递增后，指向它的指针将指向尾部参数列表。然后，只需读取参数并适当地递增指针的大小即可进一步深入堆栈。在32位模式下，x86堆栈通常是4字节对齐的，这也意味着字节和单词传递为32位整数。

无论如何，这里是演示程序中的一个辅助记录，展示了如何读取数据。请注意，Delphi似乎以非常奇怪的方式传递Extended类型；但是，您可能不必担心这一点，因为10字节浮点数在C中通常不被广泛使用，甚至在最新的MS C中也没有实现。

{$apptype console}

type  
  TArgPtr = record
  private
    FArgPtr: PByte;
    class function Align(Ptr: Pointer; Align: Integer): Pointer; static;
  public
    constructor Create(LastArg: Pointer; Size: Integer);
    // Read bytes, signed words etc. using Int32
    // Make an unsigned version if necessary.
    function ReadInt32: Integer;
    // Exact floating-point semantics depend on C compiler.
    // Delphi compiler passes Extended as 10-byte float; most C
    // compilers pass all floating-point values as 8-byte floats.
    function ReadDouble: Double;
    function ReadExtended: Extended;
    function ReadPChar: PChar;
    procedure ReadArg(var Arg; Size: Integer);
  end;

constructor TArgPtr.Create(LastArg: Pointer; Size: Integer);
begin
  FArgPtr := LastArg;
  // 32-bit x86 stack is generally 4-byte aligned
  FArgPtr := Align(FArgPtr + Size, 4);
end;

class function TArgPtr.Align(Ptr: Pointer; Align: Integer): Pointer;
begin
  Integer(Result) := (Integer(Ptr) + Align - 1) and not (Align - 1);
end;

function TArgPtr.ReadInt32: Integer;
begin
  ReadArg(Result, SizeOf(Integer));
end;

function TArgPtr.ReadDouble: Double;
begin
  ReadArg(Result, SizeOf(Double));
end;

function TArgPtr.ReadExtended: Extended;
begin
  ReadArg(Result, SizeOf(Extended));
end;

function TArgPtr.ReadPChar: PChar;
begin
  ReadArg(Result, SizeOf(PChar));
end;

procedure TArgPtr.ReadArg(var Arg; Size: Integer);
begin
  Move(FArgPtr^, Arg, Size);
  FArgPtr := Align(FArgPtr + Size, 4);
end;

procedure Dump(const types: string); cdecl;
var
  ap: TArgPtr;
  cp: PChar;
begin
  cp := PChar(types);
  ap := TArgPtr.Create(@types, SizeOf(string));
  while True do
  begin
    case cp^ of
      #0: 
      begin
        Writeln;
        Exit;
      end;

      'i': Write(ap.ReadInt32, ' ');
      'd': Write(ap.ReadDouble, ' ');
      'e': Write(ap.ReadExtended, ' ');
      's': Write(ap.ReadPChar, ' ');
    else
      Writeln('Unknown format');
      Exit;
    end;
    Inc(cp);
  end;
end;

type
  PDump = procedure(const types: string) cdecl varargs;
var
  MyDump: PDump;

function AsDouble(e: Extended): Double;
begin
  Result := e;
end;

function AsSingle(e: Extended): Single;
begin
  Result := e;
end;

procedure Go;
begin
  MyDump := @Dump;

  MyDump('iii', 10, 20, 30);
  MyDump('sss', 'foo', 'bar', 'baz');

  // Looks like Delphi passes Extended in byte-aligned
  // stack offset, very strange; thus this doesn't work.
  MyDump('e', 2.0);
  // These two are more reliable.
  MyDump('d', AsDouble(2));
  // Singles passed as 8-byte floats.
  MyDump('d', AsSingle(2));
end;

begin
  Go;
end.