将包含XML文本的base64编码解码为字符串变量

Question

将包含XML文本的base64编码解码为字符串变量

xmlbinarybase64abap

3

我无法解码一份以base64格式提供的XML文档，字符串变量(lv_string)显示出了无法读取的内容。

示例：

Ü-ÅïÎ#è-´ï®¹ïn÷ëÞ#èMÃÛmõØMôÛm´ë##ë~#ë#½èN»Ü=¶ãÞwà]#ßÍüß#ýØ=õÛm´ï~øë^#ë#µè.#èN¹Ü=¶ïÞ¹ï

以下是代码：

Data: lt_content    Type standard table of x255,
      lv_xstring    Type xstring,
      lv_string     Type string,
      encod         Type Abap_encoding Value 4110.

Select Single xml_dte into @Data(xml_b64)
 From zmmvf_edocdet 
  Where numinterno = '0000000012'.

  IF Sy-subrc Eq 0.

    Call function 'SCMS_BASE64_DECODE_STR'
     Exporting
      Input         = xml_b64
     Importing
      Output        = lv_xstring
     Exceptions
      Failed        = 1
      Others        = 2.

    If Sy-subrc Eq 0.

      Data(lv_len) = xstrlen( lv_xstring ).
      Call function 'SCMS_XSTRING_TO_BINARY'
       Exporting
        buffer        = lv_xstring
       Importing
        output_length = lv_len
       Tables
        binary_tab    = lt_content[].

      Call function 'SCMS_BINARY_TO_STRING'
       Exporting
        input_length = lv_len
*        encoding     = encod
       Importing
        text_buffer  = lv_string
       Tables
        binary_tab   = lt_content[]
       Exceptions
        failed       = 1
        Others       = 2.
    ENDIF.
  ENDIF.

- Ivan Diaz Salas

我刚刚测试了你的代码，通过将“xml_b64”设置为一个以UTF-8编码然后进行base64编码的固定文本，你的代码成功解码了它。因此，来自你的数据库的base64 不包含UTF-8文本。也许它已经包含了垃圾字节。如果你想让我们告诉你，请在这里发布你的base64的前100个字符（尽管这不再是ABAP问题）。 - Sandra Rossi

2个回答

0

一个简短的解决方案，如果我们假设base64字符串包含UTF-8编码的XML，则可以使用类CL_HTTP_UTILITY的方法DECODE_BASE64：

lv_string = cl_http_utility=>if_http_utility~decode_base64( xml_b64 ).

最小、完整和可验证的示例：

（请允许我重复使用 @manuel_b 的好例子）

DATA(xml_b64) = `PGh0bWw+PGhlYWQ+PHRpdGxlPlRpdGxlPC90aXRsZT48L2hlYWQ+`
             && `PGJvZHk+PHA+SGVsbG8gV29ybGQ8L3A+PC9ib2R5PjwvaHRtbD4=`.

DATA(lv_string) = cl_http_utility=>if_http_utility~decode_base64( xml_b64 ).

ASSERT lv_string = `<html><head><title>Title</title></head><body><p>Hello World</p></body></html>`.

- Sandra Rossi

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- manuel_b · Accepted Answer

我以前也遇到过这个问题。您可以使用以下方法

data:
  lv_base64 type string,
  lv_xstring type xstring,
  lv_output type string.

* example base64 string
lv_base64 = 'PGh0bWw+PGhlYWQ+PHRpdGxlPlRpdGxlPC90aXRsZT48L2hlYWQ+PGJvZHk+PHA+SGVsbG8gV29ybGQ8L3A+PC9ib2R5PjwvaHRtbD4='.

* convert base64 to binary (xstring)
call function 'SCMS_BASE64_DECODE_STR'
    exporting
      input  = lv_base64
    importing
      output = lv_xstring
    exceptions
      failed = 1
      others = 2.

* use codepage conversion to convert xstring to string (UTF-8)
* catch possible conversion errors
  try.

      lv_output = cl_abap_codepage=>convert_from( source = lv_xstring ).

    catch cx_parameter_invalid_range .
    catch cx_sy_codepage_converter_init .
    catch cx_sy_conversion_codepage .
    catch cx_parameter_invalid_type .
  endtry.

  write lv_output.

结果是以下输出。

<html><head><title>Title</title></head><body><p>Hello World</p></body></html>

您可以通过添加参数来控制转换，例如：

如果您希望有不同的代码页

如果您想用特殊字符替换不可见字符

如果您想忽略转换错误

lv_output = cl_abap_codepage=>convert_from(
    source      = lv_xstring
    codepage    = <your favourite codepage here>
    replacement = <conversion char for not convertible chars>
    ignore_cerr = <pass 'X' to ignore conversion errors>
).