直播视频流网站

Question

直播视频流网站

flashstreamingvideo-streamingliveflash-media-server

3

我们希望开发一个非常有趣的社区门户网站，帮助用户在整个社区中广播他们的实时视频。我一直在查看像ustream.tv、justin.tv这样的网站，并想知道他们使用了什么/如何使用技术来完成这项工作。

在过去的几天里，我一直在进行大量研究，试图找出一些领先公司，例如Ooyala.com、brightcove.com提供服务器/技术，可以在全球范围内无缝地广播视频。我很快就会注册其中任何一家提供商。

所以我的问题是，我的网站应该如何捕捉用户摄像头的实时视频流，将流发送到ooyala/brightcove并进一步广播给其他社区用户。

到目前为止，我已经确定Flash 8 / Flex确实提供了一些从用户摄像头获取流的输入内容。

我想知道你们中是否有人之前做过这个或者能够说明我的方法应该如何。

提前感谢您。

dev-drupal

- user274383

1

认为这应该被标记为Flash和Flash Media Server，而不是Flex或PHP。关注Flash/FMS标签的人可能会提供更多帮助。 - ryanstewart

如果您了解此事，请告知我。我计划推出类似的门户网站。 - gmhk

1个回答

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- Todd Moses · Answer 1

最简单的方法是使用带有Red5 http://osflash.org/red5 的Flash/Flex客户端。

Flash播放器有一种使用视频摄像头的方法，而Red5服务器是一个开源的Flash服务器，可以记录客户端流。

我建议设置Red5并进行测试。它可以满足您的所有需求。只需查看API并开始编写测试应用程序即可。

如何从用户摄像头获取视频：

package {
    import flash.display.Sprite;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.utils.Timer;
    import flash.events.TimerEvent;
    import flash.events.StatusEvent;
    import flash.events.MouseEvent;
    import flash.system.SecurityPanel;
    import flash.system.Security;

    public class Camera_getCameraExample extends Sprite {
        private var myTextField:TextField;
        private var cam:Camera;
        private var t:Timer = new Timer(1000);

        public function Camera_getCameraExample() {
            myTextField = new TextField();
            myTextField.x = 10;
            myTextField.y = 10;
            myTextField.background = true;
            myTextField.selectable = false;
            myTextField.autoSize = TextFieldAutoSize.LEFT;    

            cam = Camera.getCamera();

            if (!cam) {
                myTextField.text = "No camera is installed.";

            } else if (cam.muted) {
                myTextField.text = "To enable the use of the camera,\n"
                                 + "please click on this text field.\n" 
                                 + "When the Flash Player Settings dialog appears,\n"
                                 + "make sure to select the Allow radio button\n" 
                                 + "to grant access to your camera.";

                myTextField.addEventListener(MouseEvent.CLICK, clickHandler);

            }else {
                myTextField.text = "Connecting";
                connectCamera(); 
            }

            addChild(myTextField);

            t.addEventListener(TimerEvent.TIMER, timerHandler);
        }

        private function clickHandler(e:MouseEvent):void {
            Security.showSettings(SecurityPanel.PRIVACY);

            cam.addEventListener(StatusEvent.STATUS, statusHandler);

            myTextField.removeEventListener(MouseEvent.CLICK, clickHandler);
        }

        private function statusHandler(event:StatusEvent):void {

            if (event.code == "Camera.Unmuted") {
                connectCamera(); 
                cam.removeEventListener(StatusEvent.STATUS, statusHandler);
            }
        }

        private function connectCamera():void {
                var vid:Video = new Video(cam.width, cam.height);
                vid.x = 10;
                vid.y = 10;
                vid.attachCamera(cam);
                addChild(vid);    

                t.start();
        }

        private function timerHandler(event:TimerEvent):void {
            myTextField.y = cam.height + 20;
            myTextField.text = "";
            myTextField.appendText("bandwidth: " + cam.bandwidth + "\n");
            myTextField.appendText("currentFPS: " + Math.round(cam.currentFPS) + "\n");
            myTextField.appendText("fps: " + cam.fps + "\n");
            myTextField.appendText("keyFrameInterval: " + cam.keyFrameInterval + "\n");
        }
    }
}

如何将视频发送到Bright Cove

他们有一个API，只需仔细阅读即可。