Tetris游戏中，使用向量还是Java数组？

Question

我正在尝试使用Clojure创建类似俄罗斯方块的游戏，但在决定游戏场地的数据结构时遇到了一些问题。我想将游戏场地定义为可变网格。单个块也是网格，但不需要是可变的。

我的第一次尝试是将网格定义为向量的向量。例如，S块看起来像这样：

:s-block {
    :grids [
      [ [ 0 1 1 ]
        [ 1 1 0 ] ]

      [ [ 1 0 ]
        [ 1 1 ]
        [ 0 1 ] ] ]
}

但对于简单的迭代和绘图（请参见下面的代码），这似乎相当棘手。

为了使网格可变，我的初始想法是将每一行作为引用。但是，我无法真正弄清楚如何更改行中特定单元格的值。一个选择是将每个单独的单元格作为引用而不是每行。但这感觉像一种不干净的方法。

我现在考虑使用Java数组。Clojure的aget和aset函数可能会变得简单得多。

然而，在陷入更深的困境之前，我想询问您的想法/见解。您如何推荐实现可变的二维网格？也可以分享其他替代方法。

源代码当前状态：Tetris.clj (rev452) 更新 在您的建议和自己的摆弄后，我想出了以下内容：

(defstruct grid :width :height)

(defn create-grid [w h initial-value]
  (struct-map grid
    :width  w
    :height h
    :data   (ref (vec (repeat (* w h) initial-value)))))

(defn create-grid-with-data [w h gdata]
  (struct-map grid
    :width w
    :height h
    :data (ref gdata)))

(defn get-grid [g x y]
  (let [gdata (g :data)
        idx   (+ x (* (g :width) y)) ]
    (gdata idx)))

(defn set-grid [g x y value]
  (let [data  (deref (g :data))
        idx   (+ x (* (g :width) y)) ]
    (dosync (alter (g :data) (fn [_] (assoc data idx value))))))

(defn get-grid-rows [g]
  (partition (g :width) (deref (g :data))))

我喜欢它是因为它是一个更通用的解决方案。如果它完全错误，或者可以改进，请随便说。

- StackedCrooked

---

虽然不是你问题的确切答案，但你可能想看一下http://github.com/ztellman/penumbra/blob/master/test/example/game/tetris.clj，这是一个在Clojure中实现的俄罗斯方块游戏，而且没有使用可变网格。 - Nils Wloka

Answer 1

每个单元格都使用引用并不一定是一个坏主意。将所有网格突变放入dosync中，Clojure应该确保每个多单元格更新都是原子性的。（我不知道您是否计划同时在网格上运行多个线程，但这种方式是安全的。）

下面我使用哈希映射作为网格中每个单元格的值，因为您可能希望它不仅仅是一个布尔占用/未占用；也许您想存储颜色信息或其他东西。虽然我保留了定义块的符号。

（目前，此版本的indexed适用于最新版的Clojure。在旧版本中，您可以在clojure.contrib中找到indexed。）

(def indexed (partial map-indexed vector))

(defn make-grid [x y]
  (let [f #(vec (repeatedly %1 %2))
        r #(ref {:occupied? false})]
    (f y #(f x r))))

(defn draw-block [grid x y block]
  (dosync
   (doseq [[i row] (indexed block)
           [j square] (indexed row)]
     (alter (get-in grid [(+ y i) (+ x j)])
            assoc :occupied? (= 1 square)))))

(defn print-grid [grid]
  (doseq [row grid]
    (doseq [cell row]
      (print (if (cell :occupied?) "X" ".")))
    (println)))

(def *grid* (make-grid 5 5))

user> (draw-block *grid* 2 1 [[1 1 0] 
                              [0 1 1]])
nil
user> (print-grid *grid*)
.....
..XX.
...XX
.....
.....
nil

Java数组可能看起来更简单，但它们不是线程安全的，大多数操作seqs的好Clojure函数最终都会将其转换为非数组。改变一堆数组和对象绝对不是惯用的Clojure写法。Java数组通常用于与Java库进行交互。

- Brian Carper

Answer 2

如何使用向量的向量（与您最初的方法相同），存储在单个Atom中（或者如果您需要协调并发更新游戏场和其他内容，可能是Ref...对于俄罗斯方块游戏来说不太可能），以便与update-in一起使用？（如果您正在使用Clojure的最新快照（1.1之后），您可以考虑使用vector-of构建您的向量。有关详细信息，请参见(doc vector-of)。）

示例代码：

(def field (atom (vec (doall (for [_ (range 10)] (vec (repeat 10 false)))))))

(defn set-occupied! [x y]
  (swap! field #(update-in % [x y] (constantly true))))

(defn set-unoccupied! [x y]
  (swap! field #(update-in % [x y] (constantly false))))

(defn toggle-occupied! [x y]
  (swap! field #(update-in % [x y] not)))

实际上，以上只是为了说明如何操作游戏板。然而，这种方法的真正好处在于您不需要在核心逻辑中使用那些具有破坏性（副作用）的函数。相反，您可以将其编写为一堆纯函数，这些函数接受当前游戏场地的状态，可能还要加上表示玩家输入（或缺乏输入）的内容。

最终，您只需要将其包装在一些Java互操作代码中，以将其插入到GUI中，但这将与您的核心逻辑完全解耦。总的来说，这应该会在没有显著性能成本的情况下提供更愉悦的整体体验（我的意思是，您的游戏场地可能有多大，更新会变得多么复杂...？）。

- Michał Marczyk

---

我不完全理解，但它运行得很好 :) （我看到set-occupied用一个总是返回true的函数替换了网格单元格的内容，但我仍在努力弄清楚update-in结构实际上是如何工作的。）无论如何，非常感谢！ - StackedCrooked

很高兴能帮忙。:-) 实际上，set-occupied! 函数会用 (constantly true) 对给定网格单元的内容进行替换（这就是 update-in 的作用；它与统一更新模型中的 swap!、alter 等函数有些相似）。你也可以使用 #(assoc-in % [x y] true) 进行简单的替换（我想这可能更有意义）。对我来说，toggle-occupied! 函数似乎是最有趣且潜在有用的函数，而且最好使用 update-in 来编写。（哦，还有一个 get-in 函数用于提取数据。） - Michał Marczyk

Answer 3

我认为使用向量的向量完全没有问题。由于您每秒只需要进行少量更新，因此我认为将整个游戏场地设为不可变状态不会有任何副作用。

当然，您需要构建一些辅助函数来管理这个数据结构，但以下是一些基本函数，可以帮助您入门：

(defn make-row [w]
  (vec (for [x (range w)] 0)))

(defn make-grid [w h]
  (vec (for [y (range h)] (make-row w))))

(defn gget [grid x y]
  ((grid y) x))

(defn gset [grid x y v]
  (assoc grid y (assoc (grid y) x v)))

你可以使用这些或类似的东西来实现你需要的其他所有功能。

- mikera

---

我可能会将整个棋盘状态包装在一个 ref 中。如果您需要协调任何事务/同时访问游戏状态的线程，例如显示渲染循环或得分计算等，这将非常有用。 - mikera