Delphi 2009 - 获取文件的所有者名称

Question

如何在 Delphi 2009 中获取文件的所有者？

我有一个函数可以获取文件属性，就像这样：

type
  TCustomFileInfo= record
    CompanyName,
    Owner,
    SpecialBuild: string;
    procedure Clear;
  end;

function GetFileInfo(const FileName: string): TCustomFileInfo;
type
  PLandCodepage = ^TLandCodepage;
  TLandCodepage = record
    wLanguage,
    wCodePage: word;
  end;
var
  dummy,
  len: cardinal;
  buf, pntr: pointer;
  lang: string;
begin
  len := GetFileVersionInfoSize(PChar(FileName), dummy);
  if len = 0 then
    RaiseLastOSError;
  GetMem(buf, len);
  try
    if not GetFileVersionInfo(PChar(FileName), 0, len, buf) then
      RaiseLastOSError;

    if not VerQueryValue(buf, '\VarFileInfo\Translation\', pntr, len) then
      RaiseLastOSError;

    lang := Format('%.4x%.4x', [PLandCodepage(pntr)^.wLanguage, PLandCodepage(pntr)^.wCodePage]);

    // Get Company's name, if available...
    if VerQueryValue(buf, PChar('\StringFileInfo\' + lang + '\CompanyName'), pntr, len){ and (@len <> nil)} then
      result.CompanyName := PChar(pntr);
  finally
    FreeMem(buf);
  end;
end;

...这个方法对于CompanyName属性很有效，但我不知道如何获取所有者。

此外，当我尝试使用相同的方法来处理一个没有文件版本号的文件时，GetFileVersionInfoSize无法工作，这是有道理的，因为该文件根本没有版本号。

是否有GetFileVersionInfoSize的替代方法或其他获取文件所有者的方法？我不太熟悉Windows API，所以我真的不知道这是否是实现我想要的内容（获取所有者名称）的正确方法。

- Alisson Reinaldo Silva

---

你需要的是文件系统属性吗？ - David Heffernan

GetFileVersionInfoSize() 返回0并不表示错误，除非 GetLastError() 表示实际发生了错误。即使 GetLastError() 返回0，RaiseLastOSError() 仍然会引发一个 EOSError 异常。 - Remy Lebeau

@DavidHeffernan 我拍了一张照片，不幸的是它是葡萄牙语，但我认为你可以理解：图片 - Alisson Reinaldo Silva

@RemyLebeau 这是一个很好的观点。我所说的“不起作用”是指它像你说的那样返回零，我认为这是没有版本号的文件的预期行为。我想获取一些XML文件的所有者... - Alisson Reinaldo Silva

Answer 1

文件所有权信息不存储在版本资源中，因此不能使用VerQueryValue()访问它。所有权与文件的安全性有关，因此如果您有一个文件名，需要使用GetFileSecurity()或GetNamedSecurityInfo()；如果您有文件的打开句柄，则需要使用GetUserObjectSecurity()。

无论哪种方式，您都需要提供一个SECURITY_INFORMATION值作为输入，以指定要检索的信息类型。在这种情况下，您将使用OWNER_SECURITY_INFORMATION请求文件所有者的SID。如果成功，则可以使用LookupAccountSid()或WMI查找所有者的名称。

- Remy Lebeau

---

在你的回答之后，我搜索了一下GetFileSecurity()的使用示例，并找到了这个样例。我成功获取了用户和域名，感谢你的帮助！ - Alisson Reinaldo Silva

Answer 2

为了补充Remy的回答，这是一个获取文件所有者的示例代码，使用Win32_LogicalFileOwner和Win32_LogicalFileSecuritySetting WMI类。

{$APPTYPE CONSOLE}

{$R *.res}

uses
  SysUtils,
  ActiveX,
  ComObj,
  Variants;


function GetFileOwner(const AFileName : string) : string;
var
  LSWbemLocator, LWMIService, LObjects, LObject : OLEVariant;
  FileName       : string;
  LEnumerator    : IEnumvariant;
  iValue         : LongWord;
begin;
  Result := '';
  LSWbemLocator := CreateOleObject('WbemScripting.SWbemLocator');
  LWMIService   := LSWbemLocator.ConnectServer('localhost', 'root\CIMV2', '', '');

  //Escape the `\` chars in the FileName value because the '\' is a reserved character in WMI.
  FileName        := StringReplace(AFileName, '\', '\\', [rfReplaceAll]);
  LObjects   := LWMIService.ExecQuery(Format('ASSOCIATORS OF {Win32_LogicalFileSecuritySetting="%s"} WHERE AssocClass = Win32_LogicalFileOwner ResultRole = Owner', [FileName]));

  LEnumerator  := IUnknown(LObjects._NewEnum) as IEnumVariant;
  if LEnumerator.Next(1, LObject, iValue) = 0 then
     Result := string(LObject.AccountName);   //
end;

begin
 try
    CoInitialize(nil);
    try
     Writeln(GetFileOwner('C:\Foo.Bar'));
    finally
      CoUninitialize;
    end;
 except
    on E:Exception do
        Writeln(E.Classname, ':', E.Message);
  end;
  Readln;
end.

- RRUZ