logo标签列表

使用XSLT跳过节点

xml
6

在处理XML文件时，跳过节点是否可能？例如：假设我有以下XML代码：

<mycase desc="">
  <caseid> id_1234 </caseid>
  <serid ref=""/>    
  ......
  ......
  ......  
</mycase>

我希望把它变成这个样子：

<mycase desc="" caseid="id_1234">
 .....
 .....
</mycase>

目前我正在做这个：

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:stylesheet version="2.0" exclude-result-prefixes="xs xdt err fn"
            xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
            xmlns:xs="http://www.w3.org/2001/XMLSchema"
            xmlns:fn="http://www.w3.org/2005/xpath-functions"
            xmlns:xdt="http://www.w3.org/2005/xpath-datatypes"
            xmlns:err="http://www.w3.org/2005/xqt-errors">

          <xsl:output method="xml" indent="yes"/>
          <xsl:template match="/">
            <xsl:apply-templates/> 
          </xsl:template>

         <xsl:template match="mycase">          
            <xsl:element name="mycase">
               <xsl:attribute name="desc"/>
               <xsl:attribute name="caseid">
                 <xsl:value-of select="caseid"/>
               </xsl:attribute>
              <xsl:apply-templates/>
            </xsl:element>
         </xsl:template>
         ......
         ......

虽然<xsl:apply-templates/>可以创建我想要的内容，但它会处理所有节点。我希望跳过完全不处理caseid和serid。对于其他节点也是如此，因为它们在新的XML结构中将不可用。

那么我该如何使用XSLT跳过不想处理的节点呢？

3个回答
8
您可以使用空模板来抑制输入文档中某些节点的输出：
<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="mycase">
    <mycase caseid="{caseid}">
      <xsl:apply-templates select="@*|node()"/>
    </mycase>
  </xsl:template>

  <xsl:template match="caseid|serid"/>

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>
4
也许最简单的方法是添加一个与caseid匹配的模板，并使其不执行任何操作，如下所示：
<xsl:template match="caseid"/>

通过将以下内容添加到您现有的XSL中，将忽略caseid元素。
另一种解决方案是仅对名称不匹配caseid的元素使用xsl:apply-elements，即：
 <xsl:template match="mycase">          
        <xsl:element name="mycase">
           <xsl:attribute name="desc"/>
           <xsl:attribute name="caseid">
             <xsl:value-of select="caseid"/>
           </xsl:attribute>
          <xsl:apply-templates select="*[name() != 'caseid']"/>
        </xsl:element>
 </xsl:template>

希望这能帮到你，祝好运！
4

使用<xsl:apply-templates select="mycase"/>代替<xsl:apply-templates />

基本上，您需要对特定节点集应用模板。在您的情况下，只需应用于“mycase”节点。

网页内容由stack overflow 提供, 点击上面的
可以查看英文原文，
原文链接