CROSS APPLY在运行总计时速度太慢 - TSQL

Question

由于使用CROSS APPLY，我的代码运行速度太慢，请看下面的代码。

我该如何去除CROSS APPLY并添加其他能更快运行的内容？ 请注意，我正在使用SQL Server 2008 R2。

;WITH MyCTE AS
(
   SELECT 
      R.NetWinCURRENCYValue AS NetWin
     ,dD.[Date]             AS TheDay
   FROM   
      dimPlayer AS P
   JOIN 
      dbo.factRevenue AS R ON P.playerKey = R.playerKey
   JOIN 
      dbo.vw_Date AS dD ON Dd.dateKey = R.dateKey
   WHERE    
      P.CustomerID   = 12345)
SELECT 
     A.TheDay               AS [Date]
    ,ISNULL(A.NetWin, 0)    AS NetWin
    ,rt.runningTotal        AS CumulativeNetWin
FROM MyCTE AS A
CROSS APPLY (SELECT SUM(NetWin) AS runningTotal 
                  FROM MyCTE WHERE TheDay <= A.TheDay) AS rt
ORDER BY A.TheDay

- Etienne

---

请查看此答案 - https://dev59.com/-XRA5IYBdhLWcg3wsgHq#13744550 - Roman Pekar

你尝试过使用LEFT JOIN吗？ - Adriaan Stander

Answer 1

在这里https://dev59.com/-XRA5IYBdhLWcg3wsgHq#13744550建议使用递归CTE。

;WITH MyCTE AS
(
    SELECT 

           R.NetWinCURRENCYValue AS NetWin
          ,dD.[Date]             AS TheDay
          ,ROW_NUMBER() OVER (ORDER BY dD.[Date]) AS RN

    FROM   dimPlayer             AS P

        JOIN dbo.factRevenue     AS R   ON P.playerKey = R.playerKey
        JOIN dbo.vw_Date         AS dD  ON Dd.dateKey = R.dateKey

    WHERE    P.CustomerID   = 12345

)

, MyCTERec AS
(
    SELECT  C.TheDay               AS [Date]
           ,ISNULL(C.NetWin, 0)    AS NetWin
           ,ISNULL(C.NetWin, 0)    AS CumulativeNetWin
           ,C.RN

    FROM MyCTE AS C
    WHERE C.RN = 1

    UNION ALL

    SELECT  C.TheDay               AS [Date]
           ,ISNULL(C.NetWin, 0)    AS NetWin
           ,P.CumulativeNetWin + ISNULL(C.NetWin, 0)    AS CumulativeNetWin
           ,C.RN

    FROM MyCTERec P
    INNER JOIN MyCTE AS C ON C.RN = P.RN + 1
)

SELECT * 
    FROM MyCTERec 
    ORDER BY RN
    OPTION (MAXRECURSION 0)

请注意，如果您的1个记录== 1天，则此查询将起作用！如果一天内有多个记录，则结果将与其他查询不同。

- xanatos

---

在某些情况下，一天内会有多个记录，那么应该如何处理？ - Etienne

@Etienne 那么你不能使用这个解决方案（否则每条记录的总数将不同...但也许可以...在10.00时累计为10美元，在11.00时累计为20美元...） - xanatos

Answer 2

CREATE TABLE #temp (NetWin money, TheDay datetime)
insert into #temp 
SELECT 
      R.NetWinCURRENCYValue AS NetWin
     ,dD.[Date]             AS TheDay
   FROM   
      dimPlayer AS P
   JOIN 
      dbo.factRevenue AS R ON P.playerKey = R.playerKey
   JOIN 
      dbo.vw_Date AS dD ON Dd.dateKey = R.dateKey
   WHERE    
      P.CustomerID   = 12345;

SELECT 
     A.TheDay               AS [Date]
    ,ISNULL(A.NetWin, 0)    AS NetWin
    ,SUM(B.NetWin)          AS CumulativeNetWin
FROM #temp AS A 
JOIN #temp AS B 
  ON A.TheDay >= B.TheDay
GROUP BY A.TheDay, ISNULL(A.NetWin, 0);

- paparazzo

---

如果它给出了正确的答案，那么就实现CTE。创建一个临时表而不是CTE。CTE只是语法，因此实际上会被评估。如果您需要样例，请让我知道。 - paparazzo

不知道谁给你投了反对票，但我给你投了赞成票并批准了答案，感谢你的帮助！ - Etienne

很可能CTE很耗费资源，会被多次评估。 - paparazzo

Answer 3

正如我此前所说，如果您想要快速计算，请将其放入具有顺序主键的临时表中，然后计算滚动总计：

create table #Temp (
    ID bigint identity(1, 1) primary key,
    [Date] date,
    NetWin decimal(29, 10)
)

insert into #Temp ([Date], NetWin)
select
    dD.[Date],
    sum(R.NetWinCURRENCYValue) as NetWin,
from dbo.dimPlayer as P
    inner join dbo.factRevenue as R on P.playerKey = R.playerKey
    inner join dbo.vw_Date as dD on Dd.dateKey = R.dateKey
where P.CustomerID = 12345
group by dD.[Date]
order by dD.[Date]

;with cte as (
    select T.ID, T.[Date], T.NetWin, T.NetWin as CumulativeNetWin
    from #Temp as T
    where T.ID = 1

    union all

    select T.ID, T.[Date], T.NetWin, T.NetWin + C.CumulativeNetWin as CumulativeNetWin
from cte as C
    inner join #Temp as T on T.ID = C.ID + 1
)
select C.[Date], C.NetWin, C.CumulativeNetWin
from cte as C
order by C.[Date]

我假设您的输入中可能有重复的日期，但是不希望在输出中出现重复，因此在将数据放入表格之前对其进行了分组。

- Roman Pekar