logo标签列表

如何在CMake项目中包含qwt？

cmakeqwt
3

这个问题 提供了一个（据说）有效的FindQwt.cmake文件。是否有官方版本的文件？我不想只是复制粘贴代码。

其次，这是我的debian包的内容。为什么它不包含任何头文件呢？

$ dpkg -L libqwt-qt5-dev
/.
/usr
/usr/lib
/usr/lib/x86_64-linux-gnu
/usr/lib/x86_64-linux-gnu/qt5
/usr/lib/x86_64-linux-gnu/qt5/mkspecs
/usr/lib/x86_64-linux-gnu/qt5/mkspecs/features
/usr/lib/x86_64-linux-gnu/qt5/mkspecs/features/qwt.prf
/usr/lib/x86_64-linux-gnu/qt5/mkspecs/features/qwtconfig.pri
/usr/lib/x86_64-linux-gnu/qt5/mkspecs/features/qwtfunctions.pri
/usr/lib/x86_64-linux-gnu/qt5/mkspecs/features/qwtmathml.prf
/usr/lib/x86_64-linux-gnu/qt5/plugins
/usr/lib/x86_64-linux-gnu/qt5/plugins/designer
/usr/lib/x86_64-linux-gnu/qt5/plugins/designer/libqwt_designer_plugin.so
/usr/share
/usr/share/doc
/usr/share/doc/libqwt-qt5-dev
/usr/share/doc/libqwt-qt5-dev/changelog.Debian.gz
/usr/share/doc/libqwt-qt5-dev/changelog.gz
/usr/share/doc/libqwt-qt5-dev/copyright
/usr/lib/libqwt-qt5.so
1
其次，这是我的Debian软件包的内容。为什么它不包含任何头文件呢？它依赖于libqwt-headers软件包，该软件包包含头文件。 - Tsyvarev
@Tsyvarev 谢谢，跟随斯拉夫。这种分离的原因是什么？ - Vorac
1
我不知道原因。我猜想libqwt-headers是一个包含libqwt头文件的历史名称，这就是为什么另一个包libqwt-qt5-dev被引入，用于收集不仅头文件，还包括插件、mkspecs（不知道是什么）和库的软链接。 - Tsyvarev
1个回答
2
很遗憾，官方没有提供 FindQwt.cmake，Qwt 也没有提供 QwtConfig.cmake。CMake 不支持 qmake 的配置功能，也不能读取其 mkspecs (.prf) 文件。
不过，从 https://gitlab.kitware.com/cmake/community/-/wikis/contrib/modules/FindQwt 获取的脚本看起来不错，对我很有用。
# Qt Widgets for Technical Applications
# available at http://www.http://qwt.sourceforge.net/
#
# The module defines the following variables:
#  Qwt_FOUND - the system has Qwt
#  QWT_INCLUDE_DIR - where to find qwt_plot.h
#  QWT_INCLUDE_DIRS - qwt includes
#  QWT_LIBRARY - where to find the Qwt library
#  QWT_LIBRARIES - aditional libraries
#  QWT_VERSION_STRING - version (ex. 5.2.1)
#
# It also defines this imported target:
#  Qwt::Qwt

#=============================================================================
# Copyright 2010-2013, Julien Schueller
# Copyright 2018-2020, Rolf Eike Beer
# All rights reserved.
# 
# Redistribution and use in source and binary forms, with or without
# modification, are permitted provided that the following conditions are met: 
# 
# 1. Redistributions of source code must retain the above copyright notice, this
#    list of conditions and the following disclaimer. 
# 2. Redistributions in binary form must reproduce the above copyright notice,
#    this list of conditions and the following disclaimer in the documentation
#    and/or other materials provided with the distribution. 
#
# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
# ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
# WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
# DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR
# ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
# (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
# LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
# ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
# SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

# The views and conclusions contained in the software and documentation are those
# of the authors and should not be interpreted as representing official policies, 
# either expressed or implied, of the FreeBSD Project.
#=============================================================================

if (Qt5Gui_FOUND)
  get_target_property(QT_INCLUDE_DIR Qt5::Gui INTERFACE_INCLUDE_DIRECTORIES)
endif ()

find_path ( QWT_INCLUDE_DIR
  NAMES qwt_plot.h
  HINTS ${QT_INCLUDE_DIR}
  PATH_SUFFIXES qwt qwt-qt5 qwt6
)

set ( QWT_INCLUDE_DIRS ${QWT_INCLUDE_DIR} )

# version
set ( _VERSION_FILE ${QWT_INCLUDE_DIR}/qwt_global.h )
if ( EXISTS ${_VERSION_FILE} )
  file ( STRINGS ${_VERSION_FILE} _VERSION_LINE REGEX "define[ ]+QWT_VERSION_STR" )
  if ( _VERSION_LINE )
    string ( REGEX REPLACE ".*define[ ]+QWT_VERSION_STR[ ]+\"([^\"]*)\".*" "\\1" QWT_VERSION_STRING "${_VERSION_LINE}" )
  endif ()
endif ()
unset ( _VERSION_FILE )

find_library ( QWT_LIBRARY
  NAMES qwt qwt-qt5
  HINTS ${QT_LIBRARY_DIR}
)

set ( QWT_LIBRARIES ${QWT_LIBRARY} )

include ( FindPackageHandleStandardArgs )
find_package_handle_standard_args( Qwt REQUIRED_VARS QWT_LIBRARY QWT_INCLUDE_DIR VERSION_VAR QWT_VERSION_STRING )

if (Qwt_FOUND AND NOT TARGET Qwt::Qwt)
  add_library(Qwt::Qwt UNKNOWN IMPORTED)
  set_target_properties(Qwt::Qwt PROPERTIES
                        INTERFACE_INCLUDE_DIRECTORIES "${QWT_INCLUDE_DIRS}"
                        IMPORTED_LOCATION "${QWT_LIBRARIES}")
endif ()

mark_as_advanced (
  QWT_LIBRARY
  QWT_INCLUDE_DIR
)

编辑： 警告：这可能会返回错误的Qwt库！如果您同时安装了Qt 4和Qt 5版本，则它将返回Qt 4版本，即使您使用的是Qt 5。这将导致您的应用程序链接到Qt 4和Qt 5，从而立即崩溃。

网页内容由stack overflow 提供, 点击上面的
可以查看英文原文，
原文链接