VB6转换为VB.Net的问题-名称“Forms”未声明

Question

当将VB6代码转换为VB.NET时，我遇到了几个问题。在这里，我将处理其中一个问题。

原始的VB6代码是：

Public Sub dynForm(sFormName As String, loadingForm As Form, Optional resizeMe As Boolean = True)
On Error GoTo ErrHandler
    'Used to dynamically open a form based on its name.

    Dim oForm As Form

    'Add a Form to the collection
    Set oForm = Forms.Add(sFormName)

    'Load the Form
    Load oForm
    If resizeMe Then
        setFrmSize oForm
    End If
    centerForm oForm
    'Show The Form
    oForm.Show 1, loadingForm

    If oForm Is Nothing Then Exit Sub
    Set oForm = Nothing

    Exit Sub
ErrHandler:

    logError Err.Description & vbCrLf & "sFrm:" & sFormName & " not found!",       Err.Number, "common.dynForm", ErrorMsg
End Sub

转换过程将产生以下结果（我已经缩短了转换注释，这些注释指向不再有效的链接）：

    Public Sub dynForm(ByRef sFormName As String, ByRef loadingForm As System.Windows.Forms.Form, Optional ByRef resizeMe As Boolean = True)
    On Error GoTo ErrHandler
    'Used to dynamically open a form based on its name.

    Dim oForm As System.Windows.Forms.Form

    'Add a Form to the collection
    'UPGRADE_ISSUE: Forms method Forms.Add was not upgraded. 
    oForm = Forms.Add(sFormName)


    'Load the Form
    'UPGRADE_ISSUE: Load statement is not supported. 
    Load(oForm)
    If resizeMe Then
        setFrmSize(oForm)
    End If
    centerForm(oForm)
    'Show The Form
    VB6.ShowForm(oForm, 1, loadingForm)

    If oForm Is Nothing Then Exit Sub
    'UPGRADE_NOTE: Object oForm may not be destroyed until it is garbage collected. 
    oForm = Nothing

    Exit Sub
ErrHandler: 

    logError(Err.Description & vbCrLf & "sFrm:" & sFormName & " not found!", Err.Number, "common.dynForm", ErrorType.ErrorMsg)
    End Sub

以下错误已返回：
名称“Forms”未声明。 名称“Load”未声明。

我只是注释了Load语句。但是将表单添加到集合中证明是一个更难解决的问题。

我尝试了几个变化：

    oForm = System.Windows.Forms.Form.Add(sFormName)

返回错误：'Add' 不是 'System.Windows.Forms.Form' 的成员

    oForm = System.Windows.Forms.Form.AddOwnedForm(sFormName)

返回错误：对非共享成员的引用需要对象引用。

    oForm = My.Forms.Add(sFormName)

返回错误：'Add' 不是 'RSC_Reports.My.MyProject.MyForms' 的成员。

我该如何将作为参数传递的表单名称添加到集合中？

- user3272576

---

你需要为此创建一个FormsCollection类。请查看此链接 --> http://support.microsoft.com/kb/308537 - abhi

你根本不需要 Forms 集合。 - SLaks

你的转换器在许多情况下使用了 ByRef，而应该使用 ByVal。 - Joel Coehoorn

Answer 1

VB6代码使用类名创建一个新的表单实例。在VB.Net中，可以使用反射来完成这个任务。

请尝试使用此代码从这里，并进行修改以使其不区分大小写。

Imports System 
Imports System.Windows.Forms 
Imports System.Reflection 

Public Class ObjectFinder 

Public Shared Function CreateObjectInstance(ByVal objectName As String) As Object 
  ' Creates and returns an instance of any object in the assembly by its type name. 

  Dim obj As Object 

  Try 

    If objectName.LastIndexOf(".") = -1 Then 
      'Appends the root namespace if not specified. 

      objectName = [Assembly].GetEntryAssembly.GetName.Name & "." & objectName 

    End If 

    obj = [Assembly].GetEntryAssembly.CreateInstance(objectName, True) 

  Catch ex As Exception 

    obj = Nothing 

  End Try 

  Return obj 

End Function 

Public Shared Function CreateForm(ByVal formName As String) As Form
  ' Return the instance of the form by specifying its name.
  Return DirectCast(CreateObjectInstance(formName), Form)
EndFunction

然后替换你的行。

oForm = Forms.Add(sFormName) 

使用这行代码

oForm = ObjectFinder.CreateForm(sFormName)

- MarkJ

---

@Zac 谢谢你的编辑！它让我意识到我忘记从原始源代码中复制部分代码。我现在已经将缺失的 CreateForm 程序复制到我的答案中，并将代码更改为调用 CreateForm。 - MarkJ

@MarkJ提供的代码是正确的，但我仍然通过CreateInstance调用返回了Nothing值。只有一个参数的CreateInstance区分大小写；我不得不使用 CreateInstance（objectName，True），这样可以激活不区分大小写的功能，因为我使用了错误的驼峰拼写形式作为表单名称。 - Zac

我开始自己纠正你的代码，但是我取消了所有操作，因为区分大小写的版本更加精确：我不知道如果有两个名称相同但大小写不同的表单会发生什么情况（实际上我甚至不知道这是否可能）。无论如何，GG。 - Zac