将XSLT应用于带有xmlns属性的XML文档

Question

我正在将XSLT样式表应用于以下XML文件：

<top xmlns="http://www.foo.com/bar">
    <elementA />
    <elementB />
    <contents>
        <contentitem>
                <id>3</id>
                <moretags1 />
                <moretags2 />
        </contentitem>
        <contentitem>
                <id>2</id>
                <moretags1 />
                <moretags2 />
        </contentitem>
        <contentitem>
                <id>1</id>
                <moretags1 />
                <moretags2 />
        </contentitem>
    </contents>
</top>

这是我的当前XSLT文件（执行简单的排序）：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:doc="http://www.foo.com/bar">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
<!--                                                -->
 <xsl:strip-space elements="*"/>
<!--                                                -->
  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>
<!--                                                -->
  <xsl:template match="contents">
    <xsl:copy>
      <xsl:apply-templates select="@*"/>
      <xsl:apply-templates select="contentitem">
        <xsl:sort select="id" data-type="number"/>
      </xsl:apply-templates>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>

问题是，我不知道如何在xsl:template和xsl:apply-templates标签中使用“doc:”命名空间前缀。

目前，XML文档被原样复制，因此我认为第一个xsl:template块正在应用。但是，项目未排序，因此我认为问题在于第二个xsl:template。

我应该注意的是，如果我从两个文件中删除xmlns属性，则转换将正常工作。

有什么建议吗？

（问题基于this example）

- Jeremy

Answer 1

你尝试在选择属性中使用doc:命名空间前缀来给元素命名了吗？

<xsl:template match="doc:contents">
  <xsl:copy>
    <xsl:apply-templates select="@*"/>
    <xsl:apply-templates select="doc:contentitem">
      <xsl:sort select="doc:id" data-type="number"/>
    </xsl:apply-templates>
  </xsl:copy>
</xsl:template>

- Olivier 'Ölbaum' Scherler

---

哇，这比我预期的还要简单。原来我在排序标签上缺少了doc:id。谢谢Ölbaum！ - Jeremy