如何创建一个带有Owner属性的TStringList子类，以便自动释放TStringList？

Question

如何创建一个带有Owner属性的TStringList子类，以便自动释放TStringList？

9

我希望创建一个类似于“TOwnedStringList”（类名是虚构的）的东西，可以按以下方式构建：

sl := TOwnedStringList.Create(Self);
sl.Sorted := True;
sl.Duplicates := dupIgnore; 
sl.Add(...);
// etc...

Self可以是一个表单等，这样所有者将自动释放StringList。我想避免自己调用sl.Free，这可行吗？

- ZigiZ

1个回答

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- David Heffernan · Accepted Answer

这可能会有点混乱。你需要像这样做。

type
  TOwnerComponent = class(TComponent)
  private
    FOwnedObject: TObject;
  public
    constructor Create(Owner: TComponent; OwnedObject: TObject);
    destructor Destroy; override;
  end;

  TOwnedStringList = class(TStringList)
  private
    FOwner: TOwnerComponent;
  public
    constructor Create(Owner: TComponent);
    destructor Destroy; override;
  end;

{ TOwnerComponent }

constructor TOwnerComponent.Create(Owner: TComponent; OwnedObject: TObject);
begin
  inherited Create(Owner);
  FOwnedObject := OwnedObject;
end;

destructor TOwnerComponent.Destroy;
begin
  FOwnedObject.Free;
  inherited;
end;

{ TOwnedStringList }

constructor TOwnedStringList.Create(Owner: TComponent);
begin
  inherited Create;
  if Assigned(Owner) then
    FOwner := TOwnerComponent.Create(Owner, Self);
end;

destructor TOwnedStringList.Destroy;
begin
  if Assigned(FOwner) and not (csDestroying in FOwner.ComponentState) then
  begin
    FOwner.FOwnedObject := nil;
    FOwner.Free;
  end;
  inherited;
end;

基本上，您需要创建一个TOwnerComponent实例，该实例由传递给TOwnedStringList.Create的Owner拥有。当该Owner失效时，它将销毁TOwnerComponent，进而销毁您的字符串列表。

代码可以抵御对字符串列表进行显式Free的调用。