如何正确释放OleVariant后面的接口？

Question

我正在尝试找到一种安全/确定的方法来释放封装在OleVariant中的接口。

据我所知，Delphi会在过程结束时释放接口引用，但在我的情况下，我必须提前释放它，因为我需要关闭COM。

procedure Test;
var
  LLibrary: OleVariant;
begin
  CoInitialize(nil);
  try
    LLibrary := Null;
    try
      LLibrary := CreateOleObject(LibraryName);
    finally
      LLibrary := Unassigned; // <-- I would like to release the interface here
    end;
  finally
    CoUninitialize; // <-- Shutdown of COM
  end;
end; // <-- The compiler releases the interface here

我考虑将OleVariant放在一个额外的类实例中，在调用CoUninitialize之前可以释放它。

procedure Test;
var
  Container: TLibraryContainer; // Holds the OleVariant
begin
  CoInitialize(nil);
  try
    Container := TLibraryContainer.Create;
    try
      {...}
    finally
      Container.Free;
    end;
  finally
    CoUninitialize;
  end;
end;

这个解决方案安全吗？还是我忽视了更好的解决方案？

- Jens Mühlenhoff

Answer 1

编译器显然在使用隐式本地接口变量作为从CreateOleObject返回的返回值。这会在程序结束时释放，这对您来说太晚了。

有几种方法可以解决这个问题。首先，您可以明确CreateOleObject返回的IDispatch接口引用。这样可以控制其生命周期。

procedure Test;
var
  intf: IDispatch;
  LLibrary: OleVariant;
begin
  CoInitialize(nil);
  try
    intf := CreateOleObject(LibraryName);
    try
      LLibrary := intf;
    finally
      VarClear(LLibrary);
      intf := nil;
    end;
  finally
    CoUninitialize;
  end;
end;

另一种方法是将调用CreateOleObject的代码移动到一个具有自己作用域的单独程序中。

procedure DoWork;
var
  LLibrary: OleVariant;
begin
  LLibrary := CreateOleObject(LibraryName);
  //do stuff with LLibrary
end;

procedure Test;
begin
  CoInitialize(nil);
  try
    DoWork;
  finally
    CoUninitialize;
  end;
end;

隐式局部引用是在DoWork范围内释放的，因此在运行CoUninitialize之前结束DoWork。

我的建议是使用第二个选项，它更加清晰，并强制编译器代表您完成工作。

- David Heffernan

---

唯一真正的选择是使用次要例程，除非你喜欢计算函数调用并检查生成的汇编代码以确保没有隐藏的本地变量。对于调用你的 DoWork 例程，加1...有关详细信息，请参见我已删除的答案。 - Cosmin Prund

@Cosmin 我同意第二个选项更好。 - David Heffernan

实际上我的真实代码有点复杂，我认为我将不得不使用你的第一个变量，但我会尝试重构代码，以便我可以使用第二个变量。 :) - Jens Mühlenhoff