在我看来，使用.select的人通常是像我一样通过录制宏并修改代码来学习VBA的人，他们没有意识到.select和随后的selection只是一个不必要的中间代理。

可以通过直接使用已经存在的对象来避免使用.select，就像许多人已经发布的那样，这允许各种间接引用，比如以复杂的方式计算i和j，然后编辑cell(i,j)等。

否则，.select本身并没有什么明显的问题，你很容易找到这个的用途。例如，我有一个电子表格，我在里面填写日期，激活执行某些神奇操作的宏，然后将其以可接受的格式导出到另一个工作表，但是这需要对相邻单元格进行一些最终的手动（不可预测）输入。这时，就需要使用.select来节省鼠标移动和点击的时间了。

如何避免复制粘贴？

面对现实吧：录制宏时，这种情况经常发生：

Range("X1").Select
Selection.Copy
Range("Y9").Select
Selection.Paste

虽然这个人只想要的东西是：

Range("Y9").Value = Range("X1").Value

因此，我建议使用以下简单的方法来代替在VBA宏中使用复制粘贴：

Destination_Range.Value = Source_Range.Value

我注意到这些答案中没有提到 .Offset 属性。它也可以用来避免在操作某些单元格时使用 Select 操作，特别是与所选单元格有关的情况（如 OP 在 ActiveCell 中提到的）。
以下是几个示例：
我还假设 ActiveCell 是 J4。 ActiveCell.Offset(2,0).Value = 12 - 这将把距离 activecell （即 J6）两行下方的单元格的值更改为 12。 - 如果是 -2，则会将值 12 放在两行上面的 J2 中。 ActiveCell.Offset(0,1).Copy ActiveCell.Offset(,2) - 这将把右侧一列的单元格（k4）复制到距离 activecell 两列的单元格（L4）中。 - 注意，偏移参数中可以省略 0。 - 因此：ActiveCell.Offset(,2) 和 ActiveCell.Offset(0,2) 是相同的。 - 与前面的示例类似，-1 将使单元格向左移动一列（i4）。
这并不意味着它们比上面的选项更好，但肯定比使用 select 好。请注意，在工作表中应避免使用 EXCEL 函数 Offset，因为它是一个挥发性函数。

永远不要使用Select或Activesheet的主要原因是因为大多数人在运行您的宏时至少会有另外几个工作簿打开（有时可能有数十个）。如果他们在您的表格上单击并在您的宏运行时单击其他打开的某些书，则“Activesheet”更改，未经限定的“Select”命令的目标工作簿也会更改。
最好的情况是，您的宏将崩溃，最坏的情况是您可能会在错误的工作簿中写入值或更改单元格，而无法进行“撤消”。
我有一个简单的黄金法则：添加名为“ wb”和“ ws”的变量，用于工作簿对象和工作表对象，并始终使用它们来引用我的宏簿。如果我需要引用多个工作簿或多个工作表，则添加更多变量。
例如：

Dim wb as Workbook
Dim ws as Worksheet
Set wb = ThisWorkBook
Set ws = wb.sheets("Output")

"Set wb = ThisWorkbook"命令是非常重要的。"ThisWorkbook"在Excel中是一个特殊的值，它表示你的VBA代码当前正在运行的工作簿。这是设置工作簿变量的一个非常有用的快捷方式。

在你的子程序顶部完成这个操作之后，使用它们非常简单，只需要在任何你会使用"Selection"的地方使用它们即可:

所以，要将"Output"工作表中的单元格"A1"的值更改为"Hello"，不需要写成：

Sheets("Output").Activate
ActiveSheet.Range("A1").Select
Selection.Value = "Hello"

我们现在可以这样做：

ws.Range("A1").Value = "Hello"

新的代码不仅更可靠，如果用户在处理多个电子表格时还不太可能崩溃；而且编写起来更短、更快、更容易。

另外一个好处是，如果你总是将变量命名为"wb"和"ws"，那么你可以从一个工作簿复制和粘贴代码到另一个工作簿，通常只需要进行最少的修改就可以运行。

通过使用.Parent功能，此示例演示如何仅设置一个myRng引用即可动态访问整个环境而无需使用.Select、.Activate、.Activecell、.ActiveWorkbook、.ActiveSheet等方法。（没有通用的.Child功能。）

Sub ShowParents()
    Dim myRng As Range
    Set myRng = ActiveCell
    Debug.Print myRng.Address                    ' An address of the selected cell
    Debug.Print myRng.Parent.name                ' The name of sheet, where MyRng is in
    Debug.Print myRng.Parent.Parent.name         ' The name of workbook, where MyRng is in
    Debug.Print myRng.Parent.Parent.Parent.name  ' The name of application, where MyRng is in

    ' You may use this feature to set reference to these objects
    Dim mySh  As Worksheet
    Dim myWbk As Workbook
    Dim myApp As Application

    Set mySh = myRng.Parent
    Set myWbk = myRng.Parent.Parent
    Set myApp = myRng.Parent.Parent.Parent
    Debug.Print mySh.name, mySh.Cells(10, 1).Value
    Debug.Print myWbk.name, myWbk.Sheets.Count
    Debug.Print myApp.name, myApp.Workbooks.Count

    ' You may use dynamically addressing
    With myRng
        .Copy

        ' Pastes in D1 on sheet 2 in the same workbook, where the copied cell is
        .Parent.Parent.Sheets(2).Range("D1").PasteSpecial xlValues

        ' Or myWbk.Sheets(2).Range("D1").PasteSpecial xlValues

        ' We may dynamically call active application too
        .Parent.Parent.Parent.CutCopyMode = False

        ' Or myApp.CutCopyMode = False
    End With
End Sub