如何在Android Studio Bumblebee中添加插件

Question

我想将dagger-hilt插件添加到项目中。

 classpath 'com.google.dagger:hilt-android-gradle-plugin:2.40.5'

https://developer.android.com/studio/preview/features#settings-gradle

plugins {
    id 'com.android.application' version '7.1.0-beta02' apply false
    id 'com.android.library' version '7.1.0-beta02' apply false
    id 'org.jetbrains.kotlin.android' version '1.5.30' apply false
}

task clean(type: Delete) {
  delete rootProject.buildDir
}

pluginManagement {
  repositories {
    gradlePluginPortal()
    google()
    mavenCentral()
  }
}

dependencyResolutionManagement {
  repositoriesMode.set(RepositoriesMode.FAIL_ON_PROJECT_REPOS)
  repositories {
    google()
    mavenCentral()
  }
}
rootProject.name = 'GradleManagedDeviceTestingNew'
include ':app'

- Vixb

Answer 1

在Bumblebee中使用classpath的正确方法如下：

在plugins之前使用buildscript，并将您的classpath加入到dependencies块中即可。

buildscript {
    dependencies {
        classpath("com.google.dagger:hilt-android-gradle-plugin:2.40.5")
    }
}


plugins {
    id 'com.android.application' version '7.1.0-rc01' apply false
    id 'com.android.library' version '7.1.0-rc01' apply false
    id 'org.jetbrains.kotlin.android' version '1.5.30' apply false
}



task clean(type: Delete) {
    delete rootProject.buildDir
}

- Nitin Prakash

---

谢谢，它可以运行了，我刚试过！ - Stefan

非常感谢，它运行得非常好。 - Desilio Neto

Answer 2

您应该在settings.gradle 中添加如下的 resolutionStrategy。

pluginManagement {
    repositories {
        gradlePluginPortal()
        google()
        mavenCentral()
    }

    resolutionStrategy {
        eachPlugin {
            if (requested.id.id == 'dagger.hilt.android.plugin') {
                useModule("com.google.dagger:hilt-android-gradle-plugin:2.40.5")
            }
        }
    }
}

接下来，将hilt插件添加到模块级别的build.gradle文件中，如下所示，它已经正确更新。

plugins{
  *****
  id 'dagger.hilt.android.plugin'
}

- Mr.Sanchez

---

谢谢。你是对的！ - Vixb

Answer 3

在 AS BumbleBee 中创建新项目时，顶级 gradle 文件中缺少依赖项块。

为了解决添加类路径依赖项的问题，您应该在 buildscript 块中添加以下块。

 dependencies {
        classpath "com.google.dagger:hilt-android-gradle-plugin:2.40.5"

    }

- Astro

Answer 4

在顶层的 gradle 文件的 plugins 部分添加以下 id：

id 'com.google.dagger.hilt.android' version '2.42' apply false

感谢这个stackoverflow答案

- Luis Ángel Berríos