将Excel工作表导出到Access表(.accdb)

Question

我在Excel中有一个宏，与一个工作表上的命令按钮绑定。当单击时，我试图将工作表“FeedSamples”的数据导出到名为“ImportedData”的Access数据库表中。

有人能帮助我吗？我已经尝试了多个网络示例，但没有成功。这是我目前拥有的内容，但一直收到“运行时错误'3343'：无法识别数据库格式'filePath\FeedSampleResults.accdb”。

Dim db As Database
Dim rs As Recordset
Dim r As Long
Set db = OpenDatabase("filePath\FeedSampleResults.accdb")
Set rs = db.OpenRecordset("ImportedData", dbOpenTable)
r = 2
Do While Len(Worksheets("FeedSamples").Range("A" & r).Formula) > 0
    With rs
        .AddNew
        .Fields("REPTNO") = Worksheets("FeedSamples").Range("B" & r).value
        .Update
    End With
    r = r + 1
Loop
rs.Close
Set rs = Nothing
db.Close
Set db = Nothing

完成这个任务后，我需要编写代码将访问表中的数据导出到dBase文件。

- Analytic Lunatic

Answer 1

以下是使用ADO的代码。您需要在Data Source中设置访问数据库的完整路径。

Sub ExcelToAccessAdo()

    Dim cn As ADODB.Connection, rs As ADODB.Recordset, row As Long
    Set cn = New ADODB.Connection
    cn.Open "Provider=Microsoft.ACE.OLEDB.12.0; " & _
            "Data Source=filePath\FeedSampleResults.accdb;"

    ' open a recordset
    Set rs = New ADODB.Recordset
    rs.Open "ImportedData", cn, adOpenKeyset, adLockOptimistic, adCmdTable

    row = 3    ' the start row in the worksheet
    Do While Not IsEmpty(Worksheets("FeedSamples").Range("A" & row))

        With rs
            .AddNew    ' create a new record
            .Fields("REPTNO") = Worksheets("FeedSamples").Range("A" & row).Value
            .Update
        End With
        row = row + 1
    Loop

    rs.Close
    Set rs = Nothing
    cn.Close
    Set cn = Nothing

End Sub

- Santosh