将OCaml代码转换为F#

Question

将OCaml代码转换为F#

5

我正在将一些OCaml代码转换为F#，在使用递归函数解决OCaml中的let...and...问题时遇到了困难。

let matches s = let chars = explode s in fun c -> mem c chars
let space = matches " \t\n\r"
and punctuiation = matches "() [] {},"
and symbolic = matches "~'!@#$%^&*-+=|\\:;<>.?/"
and numeric = matches "0123456789"
and alphanumeric = matches "abcdefghijklmopqrstuvwxyz_'ABCDEFGHIJKLMNOPQRSTUVWXYZ"

我希望您能在这两种方法中使用它：

let rec lexwhile prop inp = match inp with
c::cs when prop c -> let tok,rest = lexwhile prop cs in c+tok,rest
|_->"",inp

let rec lex inp = 
match snd(lexwhile space inp)with
[]->[]
|c::cs ->let prop = if alphanumeric(c) then alphanumeric
                    else if symbolic(c) then symbolic
                    else fun c ->false in
                    let toktl,rest = lexwhile prop cs in
                    (c+toktl)::lex rest

有人知道我该如何更改它以便我可以使用它吗？

- Hagi

2个回答

3

您只需要写：

let explode s = [for c in s -> string c]
let matches str strc = 
    let eStr = explode str
    List.contains strc eStr 
let space = matches " \t\n\r"
let punctuation = matches "() [] {},"
let symbolic = matches "~'!@#$%^&*-+=|\\:;<>.?/"
let numeric = matches "0123456789"
let alphanumeric = matches "abcdefghijklmopqrstuvwxyz_'ABCDEFGHIJKLMNOPQRSTUVWXYZ"

F#通常使用轻量级而不是冗长的语法，因此通常不需要使用in、begin和end关键字。有关差异的详细信息，请参见：https://msdn.microsoft.com/en-us/library/dd233199.aspx。

个人而言，我可能会将所有这些string -> bool函数重构为活动模式，例如：

let (|Alphanumeric|_|) str =
    match matches "abcdefghijklmopqrstuvwxyz_'ABCDEFGHIJKLMNOPQRSTUVWXYZ" str with
    |true -> Some str
    |false -> None

let (|Symbolic|_|) str =
    match matches "~'!@#$%^&*-+=|\\:;<>.?/" str with
    |true -> Some str
    |false -> None

然后你可以进行模式匹配，例如：

match c with
|Alphanumeric _ -> // alphanumeric case
|Symbolic _ -> // symbolic case
|_ -> // other cases

- TheInnerLight

谢谢，我用了这些关键字因为它们有效，但是模式匹配看起来不错。 - Hagi

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- Guy Coder · Accepted Answer

看起来你正在尝试翻译 "实用逻辑与自动推理手册"

你是否看到：现在有该书代码的F#版本可用！感谢Eric Taucher、Jack Pappas和Anh-Dung Phan。

你需要查看intro.fs

// pg. 17 
// ------------------------------------------------------------------------- // 
// Lexical analysis.                                                         // 
// ------------------------------------------------------------------------- // 


let matches s =  
    let chars =  
        explode s  
    fun c -> mem c chars 

let space = matches " \t\n\r"  

let punctuation = matches "()[]{}," 

let symbolic = matches "~`!@#$%^&*-+=|\\:;<>.?/" 

let numeric = matches "0123456789" 

let alphanumeric = matches "abcdefghijklmnopqrstuvwxyz_'ABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789" 

let rec lexwhile prop inp = 
    match inp with 
    | c :: cs when prop c -> 
        let tok, rest = lexwhile prop cs 
        c + tok, rest 
    | _ -> "", inp 

let rec lex inp = 
    match snd <| lexwhile space inp with 
    | [] -> [] 
    | c :: cs -> 
        let prop = 
            if alphanumeric c then alphanumeric 
            else if symbolic c then symbolic 
            else fun c -> false 
        let toktl, rest = lexwhile prop cs 
        (c + toktl) :: lex rest

在翻译过程中，我曾在此处提出许多与编程有关的问题，并在前面加上了将OCaml转换为F#：。如果您查看评论，您会看到我们三个人是如何一起合作完成这个项目的。