使用Indy进行HTTP Post/上传简历

Question

使用Indy进行HTTP Post/上传简历

3

我正在尝试使用indy（HTTP Post）恢复上传，代码如下（使用Delphi 2010，Indy 10.4736）：

 IdHttp.Head('http://localhost/_tests/resume/large-file.bin');
 ByteRange           := IdHttp.Response.ContentLength + 1;

 // Attach the file to post/upload
 Stream              := TIdMultipartFormDataStream.Create;
 with Stream.AddFile('upload_file', 'D:\large-file.bin', 'application/octet-stream') do
 begin
      HeaderCharset  := 'utf-8';
      HeaderEncoding := '8';
 end;    // with

 with IdHTTP do
 begin
      IOHandler.LargeStream           := True;

      with Request do
      begin
           ContentRangeStart          := ByteRange;
           ContentRangeEnd            := (Stream.Size - ByteRange);
           ContentLength              := ContentRangeEnd;
           ContentRangeInstanceLength := ContentLength;
      end;    // with

      Post('http://localhost/_tests/resume/t1.php', Stream);
 end;    // with

但上传简历不起作用 :(

我查看了Indy的代码，似乎在IdIOHandler.pas中的这个函数：

TIdIOHandler.Write()

总是处理完整的流/文件（因为参数ASize：TIdStreamSize似乎总是为0，根据代码意味着发送完整的文件/流）。

这会阻止indy恢复上传。

我的问题是：有没有可能避免发送完整的文件？

设置内容范围没有改变任何东西。我还调整了indy的代码（修改了3行），使indy遵守内容范围/流位置，但它有错误，并且indy最终始终挂起在IdStackWindows.pas中，因为无限超时。

- TheDude

你应该使用 PUT。 - OnTheFly

这是Remy Lebeau关于Put的评论。 - TheDude

不知道，他可能在谈论PHP4。但是是的，你的需求与POST不兼容。 - OnTheFly

恢复文件与“PUT”不兼容。我说过了，“POST”只是任意数据。接收脚本决定如何处理数据，因此理论上它可以用于恢复。但实际上很少这样做。 - Remy Lebeau

1个回答

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- Remy Lebeau · Accepted Answer

正如我在你之前的问题中告诉过你的那样，你需要发布一个包含剩余文件数据的TStream以进行上传。不要使用TIdMultipartFormDataStream.AddFile()，因为那会发送整个文件。相反，请使用TIdMultipartFormDataStream.AddFormField()的TStream重载版本。

TIdHTTP并不设计支持ContentRange...属性。大多数Request属性仅设置相应的HTTP头，它们并不影响数据。这就是为什么你的编辑破坏了它的原因。

试试这个:

IdHttp.Head('http://localhost/_tests/resume/large-file.bin');
FileSize := IdHttp.Response.ContentLength;

FileStrm := TFileStream.Create('D:\large-file.bin', fmOpenRead or fmShareDenyWrite);
try
  if FileSize < FileStrm.Size then
  begin
    FileStrm.Position := FileSize;

    Stream := TIdMultipartFormDataStream.Create;
    try
      with Stream.AddFormField('upload_file', 'application/octet-stream', '', FileStrm, 'large-file.bin') do
      begin
        HeaderCharset  := 'utf-8';
        HeaderEncoding := '8';
      end;

      with IdHTTP do
      begin
        with Request do
        begin
          ContentRangeStart := FileSize + 1;
          ContentRangeEnd   := FileStrm.Size;
        end;

        Post('http://localhost/_tests/resume/t1.php', Stream);
      end;
    finally
      Stream.Free;
    end;
  end;
finally
  FileStrm.Free;
end;

话虽如此，这是对 HTTP 和 multipart/form-data 的滥用。首先，ContentRange 值放错了地方。你把它们应用到整个请求中，这是错误的。它们需要应用在 FormField 上，但 TIdMultipartFormDataStream 目前不支持这样做。其次，multipart/form-data 并不是设计用来这样使用的。它适用于从头上传文件，但不适用于恢复中断的上传。你真的应该停止使用 TIdMultipartFormDataStream，直接像我之前建议的那样将文件数据直接传递给 TIdHTTP.Post()。

FileStrm := TFileStream.Create('D:\large-file.bin', fmOpenRead or fmShareDenyWrite);
try
  IdHTTP.Post('http://localhost/_tests/upload.php?name=large-file.bin', FileStrm);
finally
  FileStrm.Free;
end;

.

IdHTTP.Head('http://localhost/_tests/files/large-file.bin');
FileSize := IdHTTP.Response.ContentLength;

FileStrm := TFileStream.Create('D:\large-file.bin', fmOpenRead or fmShareDenyWrite);
try
  if FileSize < FileStrm.Size then
  begin
    FileStrm.Position := FileSize;
    IdHTTP.Post('http://localhost/_tests/resume.php?name=large-file.bin', FileStrm);
  end;
finally
  FileStrm.Free;
end;

我之前已经解释过如何在PHP中访问原始的POST数据。