动态数组的困惑

Question

动态数组的困惑

3

好的，我正在使用以下代码来读取和显示文本文件到一个HTA（HTML应用程序）中，它通过循环遍历文件夹（Notes）中存在的所有文本文件。我已经解析了换行符，并从显示中删除了文件扩展名。

我想要做的是构建两个数组，一个用于文件名，一个用于文本文件内容，以便在脚本的其他部分中按需要输出它们。

我知道我需要一个动态数组，在循环中它需要扩展intsize，只是我不确定如何实现，特别是因为它可能是一个二维数组，以将文件名和其内容放在一起。这是代码：

Set objFSO = CreateObject("Scripting.FileSystemObject")
objStartFolder = "Notes\"

Set objFolder = objFSO.GetFolder(objStartFolder)

Set colFiles = objFolder.Files
   For Each objFile in colFiles
   If UCase(objFSO.GetExtensionName(objFile.name)) = "TXT" Then

        Files = objStartFolder & objFile.name
        Set objReadFile = objFSO.OpenTextFile(Files, 1)

        strExt = Left(objFile.name, Len(objFile.name)-4)
        strNote = Replace(objReadFile.ReadAll, vbCRLF, "<br>")

    objReadFile.Close

        document.write strExt & "<br><br>"
        document.write strNote & "<br><br>"

    else
    document.write ="File was empty"

    End If
Next

- Ctrlaltdenied

1

或者使用字典。 - 404

1

@eurotrash 为了性能考虑，建议使用数组而不是COM对象。 - user692942

1个回答

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- user692942 · Accepted Answer

你应该可以使用二维数组来轻松完成这个任务。

因为你事先知道文件的数量，所以不需要使用`Preserve`来动态地调整数组大小，只需声明一个动态数组，然后使用`ReDim`来设置初始维度即可。

Dim data()

...

Dim index
ReDim data(1, colFiles.Count - 1)

For Each objFile in colFiles
  ...
  data(0, index) = objFile.Name
  data(1, index) = strNote
  index = index + 1
Next
Erase data

更新：

因为上述代码如何适应他们的示例不清楚，所以 OP 希望提供一个完整的示例，因此下面是示例：

^{... 表示省略的现有代码以强调添加内容}

Option Explicit

Dim objFSO, objFolder, colFiles, objFile, objReadFile
Dim objStartFolder, Files, strExt, strNote

Set objFSO = CreateObject("Scripting.FileSystemObject")
objStartFolder = "Notes\"

Set objFolder = objFSO.GetFolder(objStartFolder)

Dim data(), index

Set colFiles = objFolder.Files
'No need for preserve as we have the Count from the colFiles File Collection.
ReDim data(1, colFiles.Count - 1)

For Each objFile in colFiles
  If UCase(objFSO.GetExtensionName(objFile.name)) = "TXT" Then
    Files = objStartFolder & objFile.name
    Set objReadFile = objFSO.OpenTextFile(Files, 1)

    strExt = Left(objFile.name, Len(objFile.name)-4)
    strNote = Replace(objReadFile.ReadAll, vbCRLF, "<br>")

    objReadFile.Close
    'Release resources
    Set objReadFile = Nothing

    document.write strExt & "<br><br>"
    document.write strNote & "<br><br>"
    
    'Populate the array
    data(0, index) = objFile.Name
    data(1, index) = strNote
    index = index + 1    
  Else
    document.write ="File was empty"
  End If
Next
'Release resources
Erase data
Set colFiles = Nothing
Set objFolder = Nothing
Set objFSO = Nothing

^{此代码未经测试}

我已经用一个示例进行了测试，您可以使用CScript进行调用

Option Explicit
Dim fs, folder, files, file
Dim i, r, c

Set fs = CreateObject("Scripting.FileSystemObject")

Set folder = fs.GetFolder("C:\")
Set files = folder.Files

Dim data()

ReDim data(1, files.Count -1)

For Each file In files
  data(0, i) = file.Name
  data(1, i) = file.Path
  i = i + 1
Next

For r = LBound(data, 2) To UBound(data, 2)
  For c = LBound(data, 1) To UBound(data, 1)
    WScript.Echo "data(" & c & ", " & r & ") = " & data(c, r)
  Next
Next
Erase data
Set files = Nothing
Set folder = Nothing
Set fs = Nothing

使用命令行运行此代码，使用cscript.exe而不是wscript.exe, 否则会出现很多弹窗。