Delphi接口和类变量类型

Question

Delphi接口和类变量类型

3

我了解到接口是一种良好的方法来解耦代码。Nick Hodges在此方面写了一章节，阅读后我编写了以下代码：

//interfaces
type
 ILocalization = interface
  ['{1D144BCE-7D79-4672-8FB5-235422F712EE}']
  function localize(const aWordId: string): string;
 end;

type
 IActions = interface
  ['{31E8B24F-0B17-41BC-A9E4-F93A8E7F6ECF}']
  procedure addWord(const aIndex, aWord: string);
  procedure removeWord(const aIndex: string);
 end;

//implementation
type
 TLocalization = class sealed (TInterfacedObject, ILocalization, IActions)
  private
   FTranslationList: TDictionary<string, string>;
  public
   constructor Create;
   destructor Destroy; override;
   //interface implementations
   function localize(const aWordId: string): string;
   procedure addWord(const aIndex, aWord: string);
   procedure removeWord(const aIndex: string);
 end;

我计划使用这个类来本地化（翻译）我的Delphi安卓应用程序。

当我要创建一个该类的实例时，我会执行以下操作。

var
 Italiano: TLocalization;
begin
 Italiano := TLocalization.Create;
end;

既然 TLocalization 应该已经继承了 AddRef 和 Release 方法，所以我不会在 finally 中使用它们，但如果 Italiano 是一个类类型而不是接口类型，这是否仍然发生？

我的意思是：

Italiano: TLocalization -> 在这里我可以使用所有的方法
Italiano: ILocalization -> 在这里我只能使用 localize 函数

考虑到（如我之前所说），TLocalization 继承 AddRef 和 Release 方法，如果我理解正确，我就不需要释放它。尽管如此，对于 ILocalization，它还有其他好处吗？我不明白以上两种情况的区别是什么。

- Raffaele Rossi

1个回答

网页内容由stack overflow 提供, 点击上面的

可以查看英文原文，
原文链接

- David Heffernan · Accepted Answer

var
  Italiano: TLocalization;
begin
  Italiano := TLocalization.Create;
  // do stuff
end;

这将使您陷入混合不同生命周期模型的风险中。目前代码中，AddRef未被调用，因此引用计数为0。因此，您将泄漏此对象。

所以您可能需要更改代码：

var
  Italiano: TLocalization;
begin
  Italiano := TLocalization.Create;
  try
    // do stuff
  finally
    Italiano.Free;
  end;
end;

现在你没有泄漏了。

太好了。但是如果您确实引用了呢？

var
  Italiano: TLocalization;
  Localization: ILocalization;
begin
  Italiano := TLocalization.Create;
  try
    Localization := Italiano as ILocalization;
    // do stuff
  finally
    Italiano.Free;
  end;
end;

现在当你给 Localization 赋值时，会调用 AddRef。这样引用计数就变成了 1。当 Localization 超出作用域，会调用 Release，引用计数就回归到 0，并销毁实例。不幸的是，你也显式地销毁了它。对象需要被准确地销毁一次。

最干净、最简单的方法是：不要混合使用不同的生命周期模型。如果你用引用计数管理生命周期，就只用这个方法。确保在创建对象时总是获取一个引用，并让编译器生成引用计数代码来管理生命周期。

确保遵循此规则的一种方法是通过接口引用访问对象。像这样：

var
  Italiano: ILocalization;
begin
  Italiano := TLocalization.Create;
  // do stuff
end;