柯里化函数Erlang

Question

我正在尝试使用Erlang重新做我的Haskell作业，其中一个问题是如何使用参数不全的函数列表。

例如：我正在尝试使用这个fold函数，但我不知道如何传递函数，以便它对累加器进行操作。

%%inside my module)
add(X,Y) -> X + Y.

multiply(X,Y) -> X*Y.

之后在命令行中使用以下命令：

lists:foldl(fun(Function,Accumulator) -> Function(Accumulator) end, 3, [add(3),multiply(5)]).

- Kelsey Abreu

Answer 1

在Erlang中，您必须调用函数并传递它所需的所有参数。但是，您可以通过创建一个仅接收您需要的参数并正确调用函数的匿名函数来轻松避免此问题。如果您需要一个只需要一个参数X并调用函数add(3, X)的函数，您可以创建一个类似于以下方式的匿名函数：

在Erlang中，您必须调用函数并传递它所需的所有参数。但是，您可以通过创建一个仅接收您需要的参数并正确调用函数的匿名函数来轻松避免此问题。如果您需要一个只需要一个参数X并调用函数add(3, X)的函数，您可以创建一个类似于以下方式的匿名函数：

fun (X) -> add(3, X) end

这是你任务的一个例子：

lists:foldl(fun (Function, Accumulator) -> Function(Accumulator) end, 3,
    [fun (X) -> add(3, X) end, fun (X) -> multiply(5, X) end]).

- Danil Onishchenko

Answer 2

在原生Erlang中，没有任何形式的部分求值来满足您的要求。您将不得不创建自己的函数来完成。然而，如果您使用Erlando Monad Library，则可以使用模式匹配来实现。它的原理是Erlang编译器允许在编译代码时操作AST，因此您可以完成这样酷炫的操作。

- Zachary K

Answer 3

可以相对容易地编写一个部分应用函数，类似于erlang:apply/3的调用方式。它不像支持柯里化的语言那样优雅。

-module(partial).

-export([apply/4]).

apply(Module, Name, Arity, Args) when length(Args) < Arity ->
    Left = Arity - length(Args),
    fun(Args1) when length(Args1) < Left ->
            fun(Args2) ->
                apply(Module, Name, Arity, Args2 ++ Args1 ++ Args)
            end;
       (Args1) when length(Args1) > Left ->
            erlang:error(badarg);
       (Args1) ->
            erlang:apply(Module, Name, Args1 ++ Args)
    end;
apply(_, _, Arity, Args) when length(Args) > Arity ->
    erlang:error(badarg);
apply(Module, Name, _, Args) ->
    erlang:apply(Module, Name, Args).

- Jan Henry Nystrom

Answer 4

-module(f).
-export([curry/1]).

curry(AnonymousFun) ->
    {arity, Arity} =
        erlang:fun_info(AnonymousFun, arity),

    do_curry(AnonymousFun, Arity, [[], [], []]).

do_curry(Fun, 0, [Fronts, Middle, Ends] = X) ->
    % Fronts ++ Middle ++ ")" ++ Ends;
    [F, M, E] =
        lists:map(fun(L) -> string:join(L, "") end, X),
    Fstring =
        F ++ "Run(" ++ string:trim(M, trailing, ",") ++ ")" ++ E,

    {ok, Tokens, _} =
        erl_scan:string(Fstring ++ "."),
    {ok, Parsed} =
        erl_parse:parse_exprs(Tokens),

    FunBinding =
        erl_eval:add_binding(
          'Run',
          Fun,
          erl_eval:new_bindings()
        ),
    {value ,CurriedFun, _} =
        erl_eval:exprs(Parsed, FunBinding),

    CurriedFun;

do_curry(Fun, Arity, [Fronts, Middle, Ends]) ->
    VarName = [64 + Arity],
    NewFronts = ["fun(" ++ VarName ++ ") -> " | Fronts] ,
    NewMiddle = [VarName ++ ","|Middle],
    NewEnds = [" end"|Ends],
    do_curry(Fun, Arity-1, [NewFronts, NewMiddle, NewEnds]).

使用方法（从shell输出中剔除噪声）：

72> c("./f") % If `f.erl` is in the current dir that is.

73> F = f:curry(fun(A,B,C) -> A + B + C end).

74> F(1).
75> G = F(1).
76> G(2).
77> H = G(2).
78> H(3).
6

79> I = (F(1))(2).
80> I(3).
6

82> F2 = mtest:curry(fun erlang:'++'/2).  

83> F2("lofa").

84> (F2("lofa"))("miez").
"lofamiez"

85> ((f:curry(fun lists:map/2))((f:curry(fun filename:join/2))("dir")))(["a_file", "b_file"]).
["dir/a_file","dir/b_file"]

有用的资源：

• http://erlang.org/pipermail/erlang-questions/2005-April/015279.html（链接1：http://erlang.org/pipermail/erlang-questions/2005-April/015279.html）
• https://grantwinney.com/how-to-evaluate-a-string-of-code-in-erlang-at-runtime/（链接2：https://grantwinney.com/how-to-evaluate-a-string-of-code-in-erlang-at-runtime/）
• Convert erlang terms to string, or decode erlang binary（转换 Erlang 术语为字符串，或解码 Erlang 二进制）
• Erlang trying to evaluate a string（Erlang 尝试评估一个字符串）
• Knowing the number of parameters of a passed function (erlang)（了解传递函数的参数数量（erlang））
• https://erlang.org/doc/man/erl_eval.html（链接6：https://erlang.org/doc/man/erl_eval.html）

- toraritte

Answer 5

lists:foldl(
    fun(Function,Accumulator) -> Function(Accumulator) end, 
    3, 
    [
        fun(X) -> modname:add(3, X) end, 
        fun(X) -> modname:multiply(5, X) end
    ]
).

- 7stud

---

这意味着在Erlang中没有部分函数应用（也没有柯里化），对吗？因为你使用了lambda函数，而在Haskell中我们可以有一个部分应用的函数列表：[(+)1,(-)2,(*)3]。或者它仍然与部分函数应用相同吗？ - ichistmeinname